1 #
   2 # Copyright (c) 2011, 2019, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ###############################################################################
  27 # Check which variant of the JDK that we want to build.
  28 # Currently we have:
  29 #    normal:   standard edition
  30 # but the custom make system may add other variants
  31 #
  32 # Effectively the JDK variant gives a name to a specific set of
  33 # modules to compile into the JDK.
  34 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],
  35 [
  36   # Deprecated in JDK 12
  37   BASIC_DEPRECATED_ARG_WITH([jdk-variant])
  38 ])
  39 
  40 ###############################################################################
  41 # Set the debug level
  42 #    release: no debug information, all optimizations, no asserts.
  43 #    optimized: no debug information, all optimizations, no asserts, HotSpot target is 'optimized'.
  44 #    fastdebug: debug information (-g), all optimizations, all asserts
  45 #    slowdebug: debug information (-g), no optimizations, all asserts
  46 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],
  47 [
  48   DEBUG_LEVEL="release"
  49   AC_MSG_CHECKING([which debug level to use])
  50   AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],
  51       [set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],
  52       [
  53         ENABLE_DEBUG="${enableval}"
  54         DEBUG_LEVEL="fastdebug"
  55       ], [ENABLE_DEBUG="no"])
  56 
  57   AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],
  58       [set the debug level (release, fastdebug, slowdebug, optimized) @<:@release@:>@])],
  59       [
  60         DEBUG_LEVEL="${withval}"
  61         if test "x$ENABLE_DEBUG" = xyes; then
  62           AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])
  63         fi
  64       ])
  65   AC_MSG_RESULT([$DEBUG_LEVEL])
  66 
  67   if test "x$DEBUG_LEVEL" != xrelease && \
  68       test "x$DEBUG_LEVEL" != xoptimized && \
  69       test "x$DEBUG_LEVEL" != xfastdebug && \
  70       test "x$DEBUG_LEVEL" != xslowdebug; then
  71     AC_MSG_ERROR([Allowed debug levels are: release, fastdebug, slowdebug and optimized])
  72   fi
  73 
  74   # Translate DEBUG_LEVEL to debug level used by Hotspot
  75   HOTSPOT_DEBUG_LEVEL="$DEBUG_LEVEL"
  76   if test "x$DEBUG_LEVEL" = xrelease; then
  77     HOTSPOT_DEBUG_LEVEL="product"
  78   elif test "x$DEBUG_LEVEL" = xslowdebug; then
  79     HOTSPOT_DEBUG_LEVEL="debug"
  80   fi
  81 
  82   if test "x$DEBUG_LEVEL" = xoptimized; then
  83     # The debug level 'optimized' is a little special because it is currently only
  84     # applicable to the HotSpot build where it means to build a completely
  85     # optimized version of the VM without any debugging code (like for the
  86     # 'release' debug level which is called 'product' in the HotSpot build) but
  87     # with the exception that it can contain additional code which is otherwise
  88     # protected by '#ifndef PRODUCT' macros. These 'optimized' builds are used to
  89     # test new and/or experimental features which are not intended for customer
  90     # shipment. Because these new features need to be tested and benchmarked in
  91     # real world scenarios, we want to build the containing JDK at the 'release'
  92     # debug level.
  93     DEBUG_LEVEL="release"
  94   fi
  95 
  96   AC_SUBST(HOTSPOT_DEBUG_LEVEL)
  97   AC_SUBST(DEBUG_LEVEL)
  98 ])
  99 
 100 ###############################################################################
 101 #
 102 # Should we build only OpenJDK even if closed sources are present?
 103 #
 104 AC_DEFUN_ONCE([JDKOPT_SETUP_OPEN_OR_CUSTOM],
 105 [
 106   AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],
 107       [suppress building custom source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])
 108 
 109   AC_MSG_CHECKING([if custom source is suppressed (openjdk-only)])
 110   AC_MSG_RESULT([$enable_openjdk_only])
 111   if test "x$enable_openjdk_only" = "xyes"; then
 112     SUPPRESS_CUSTOM_EXTENSIONS="true"
 113   elif test "x$enable_openjdk_only" = "xno"; then
 114     SUPPRESS_CUSTOM_EXTENSIONS="false"
 115   else
 116     AC_MSG_ERROR([Invalid value for --enable-openjdk-only: $enable_openjdk_only])
 117   fi
 118 ])
 119 
 120 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],
 121 [
 122   # Should we build a JDK without a graphical UI?
 123   AC_MSG_CHECKING([headless only])
 124   AC_ARG_ENABLE([headless-only], [AS_HELP_STRING([--enable-headless-only],
 125       [only build headless (no GUI) support @<:@disabled@:>@])])
 126 
 127   if test "x$enable_headless_only" = "xyes"; then
 128     ENABLE_HEADLESS_ONLY="true"
 129     AC_MSG_RESULT([yes])
 130   elif test "x$enable_headless_only" = "xno"; then
 131     ENABLE_HEADLESS_ONLY="false"
 132     AC_MSG_RESULT([no])
 133   elif test "x$enable_headless_only" = "x"; then
 134     ENABLE_HEADLESS_ONLY="false"
 135     AC_MSG_RESULT([no])
 136   else
 137     AC_MSG_ERROR([--enable-headless-only can only take yes or no])
 138   fi
 139 
 140   AC_SUBST(ENABLE_HEADLESS_ONLY)
 141 
 142   # Should we build the complete docs, or just a lightweight version?
 143   AC_ARG_ENABLE([full-docs], [AS_HELP_STRING([--enable-full-docs],
 144       [build complete documentation @<:@enabled if all tools found@:>@])])
 145 
 146   # Verify dependencies
 147   AC_MSG_CHECKING([for graphviz dot])
 148   if test "x$DOT" != "x"; then
 149     AC_MSG_RESULT([yes])
 150   else
 151     AC_MSG_RESULT([no, cannot generate full docs])
 152     FULL_DOCS_DEP_MISSING=true
 153   fi
 154 
 155   AC_MSG_CHECKING([for pandoc])
 156   if test "x$PANDOC" != "x"; then
 157     AC_MSG_RESULT([yes])
 158   else
 159     AC_MSG_RESULT([no, cannot generate full docs])
 160     FULL_DOCS_DEP_MISSING=true
 161   fi
 162 
 163   AC_MSG_CHECKING([full docs])
 164   if test "x$enable_full_docs" = xyes; then
 165     if test "x$FULL_DOCS_DEP_MISSING" = "xtrue"; then
 166       AC_MSG_RESULT([no, missing dependencies])
 167       HELP_MSG_MISSING_DEPENDENCY([dot])
 168       AC_MSG_ERROR([Cannot enable full docs with missing dependencies. See above. $HELP_MSG])
 169     else
 170       ENABLE_FULL_DOCS=true
 171       AC_MSG_RESULT([yes, forced])
 172     fi
 173   elif test "x$enable_full_docs" = xno; then
 174     ENABLE_FULL_DOCS=false
 175     AC_MSG_RESULT([no, forced])
 176   elif test "x$enable_full_docs" = x; then
 177     # Check for prerequisites
 178     if test "x$FULL_DOCS_DEP_MISSING" = xtrue; then
 179       ENABLE_FULL_DOCS=false
 180       AC_MSG_RESULT([no, missing dependencies])
 181     else
 182       ENABLE_FULL_DOCS=true
 183       AC_MSG_RESULT([yes, dependencies present])
 184     fi
 185   else
 186     AC_MSG_ERROR([--enable-full-docs can only take yes or no])
 187   fi
 188 
 189   AC_SUBST(ENABLE_FULL_DOCS)
 190 
 191   # Choose cacerts source file
 192   AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],
 193       [specify alternative cacerts file])])
 194   AC_MSG_CHECKING([for cacerts file])
 195   if test "x$with_cacerts_file" == x; then
 196     AC_MSG_RESULT([default])
 197   else
 198     CACERTS_FILE=$with_cacerts_file
 199     if test ! -f "$CACERTS_FILE"; then
 200       AC_MSG_RESULT([fail])
 201       AC_MSG_ERROR([Specified cacerts file "$CACERTS_FILE" does not exist])
 202     fi
 203     AC_MSG_RESULT([$CACERTS_FILE])
 204   fi
 205   AC_SUBST(CACERTS_FILE)
 206 
 207   # Enable or disable unlimited crypto
 208   AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--disable-unlimited-crypto],
 209       [Disable unlimited crypto policy @<:@enabled@:>@])],,
 210       [enable_unlimited_crypto=yes])
 211   if test "x$enable_unlimited_crypto" = "xyes"; then
 212     UNLIMITED_CRYPTO=true
 213   else
 214     UNLIMITED_CRYPTO=false
 215   fi
 216   AC_SUBST(UNLIMITED_CRYPTO)
 217 
 218   # Should we build the serviceability agent (SA)?
 219   INCLUDE_SA=true
 220   if HOTSPOT_CHECK_JVM_VARIANT(zero); then
 221     INCLUDE_SA=false
 222   fi
 223   if test "x$OPENJDK_TARGET_OS" = xaix ; then
 224     INCLUDE_SA=false
 225   fi
 226   if test "x$OPENJDK_TARGET_CPU" = xs390x ; then
 227     INCLUDE_SA=false
 228   fi
 229   AC_SUBST(INCLUDE_SA)
 230 
 231   # Compress jars
 232   COMPRESS_JARS=false
 233 
 234   AC_SUBST(COMPRESS_JARS)
 235 
 236   # Setup default copyright year. Mostly overridden when building close to a new year.
 237   AC_ARG_WITH(copyright-year, [AS_HELP_STRING([--with-copyright-year],
 238       [Set copyright year value for build @<:@current year@:>@])])
 239   if test "x$with_copyright_year" = xyes; then
 240     AC_MSG_ERROR([Copyright year must have a value])
 241   elif test "x$with_copyright_year" != x; then
 242     COPYRIGHT_YEAR="$with_copyright_year"
 243   else
 244     COPYRIGHT_YEAR=`$DATE +'%Y'`
 245   fi
 246   AC_SUBST(COPYRIGHT_YEAR)
 247 
 248   # Override default library path
 249   AC_ARG_WITH([jni-libpath], [AS_HELP_STRING([--with-jni-libpath],
 250       [override default JNI library search path])])
 251   AC_MSG_CHECKING([for jni library path])
 252   if test "x${with_jni_libpath}" = "x" || test "x${with_jni_libpath}" = "xno"; then
 253     AC_MSG_RESULT([default])
 254   elif test "x${with_jni_libpath}" = "xyes"; then
 255     AC_MSG_RESULT([invalid])
 256     AC_MSG_ERROR([The --with-jni-libpath option requires an argument.])
 257   else
 258     HOTSPOT_OVERRIDE_LIBPATH=${with_jni_libpath}
 259     if test "x$OPENJDK_TARGET_OS" != "xlinux" &&
 260          test "x$OPENJDK_TARGET_OS" != "xbsd" &&
 261          test "x$OPENJDK_TARGET_OS" != "xaix"; then
 262       AC_MSG_RESULT([fail])
 263       AC_MSG_ERROR([Overriding JNI library path is supported only on Linux, BSD and AIX.])
 264     fi
 265     AC_MSG_RESULT(${HOTSPOT_OVERRIDE_LIBPATH})
 266   fi
 267   AC_SUBST(HOTSPOT_OVERRIDE_LIBPATH)
 268 
 269 ])
 270 
 271 ###############################################################################
 272 #
 273 # Enable or disable the elliptic curve crypto implementation
 274 #
 275 AC_DEFUN_ONCE([JDKOPT_DETECT_INTREE_EC],
 276 [
 277   AC_MSG_CHECKING([if elliptic curve crypto implementation is present])
 278 
 279   if test -d "${TOPDIR}/src/jdk.crypto.ec/share/native/libsunec/impl"; then
 280     ENABLE_INTREE_EC=true
 281     AC_MSG_RESULT([yes])
 282   else
 283     ENABLE_INTREE_EC=false
 284     AC_MSG_RESULT([no])
 285   fi
 286 
 287   AC_SUBST(ENABLE_INTREE_EC)
 288 ])
 289 
 290 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],
 291 [
 292   #
 293   # NATIVE_DEBUG_SYMBOLS
 294   # This must be done after the toolchain is setup, since we're looking at objcopy.
 295   #
 296   AC_MSG_CHECKING([what type of native debug symbols to use])
 297   AC_ARG_WITH([native-debug-symbols],
 298       [AS_HELP_STRING([--with-native-debug-symbols],
 299       [set the native debug symbol configuration (none, internal, external, zipped) @<:@varying@:>@])],
 300       [
 301         if test "x$OPENJDK_TARGET_OS" = xaix; then
 302           if test "x$withval" = xexternal || test "x$withval" = xzipped; then
 303             AC_MSG_ERROR([AIX only supports the parameters 'none' and 'internal' for --with-native-debug-symbols])
 304           fi
 305         fi
 306       ],
 307       [
 308         if test "x$OPENJDK_TARGET_OS" = xaix; then
 309           # AIX doesn't support 'external' so use 'internal' as default
 310           with_native_debug_symbols="internal"
 311         else
 312           if test "x$STATIC_BUILD" = xtrue; then
 313             with_native_debug_symbols="none"
 314           else
 315             with_native_debug_symbols="external"
 316           fi
 317         fi
 318       ])
 319   NATIVE_DEBUG_SYMBOLS=$with_native_debug_symbols
 320   AC_MSG_RESULT([$NATIVE_DEBUG_SYMBOLS])
 321 
 322   if test "x$NATIVE_DEBUG_SYMBOLS" = xzipped; then
 323 
 324     if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
 325       if test "x$OBJCOPY" = x; then
 326         # enabling of enable-debug-symbols and can't find objcopy
 327         # this is an error
 328         AC_MSG_ERROR([Unable to find objcopy, cannot enable native debug symbols])
 329       fi
 330     fi
 331 
 332     COMPILE_WITH_DEBUG_SYMBOLS=true
 333     COPY_DEBUG_SYMBOLS=true
 334     ZIP_EXTERNAL_DEBUG_SYMBOLS=true
 335   elif test "x$NATIVE_DEBUG_SYMBOLS" = xnone; then
 336     COMPILE_WITH_DEBUG_SYMBOLS=false
 337     COPY_DEBUG_SYMBOLS=false
 338     ZIP_EXTERNAL_DEBUG_SYMBOLS=false
 339   elif test "x$NATIVE_DEBUG_SYMBOLS" = xinternal; then
 340     COMPILE_WITH_DEBUG_SYMBOLS=true
 341     COPY_DEBUG_SYMBOLS=false
 342     ZIP_EXTERNAL_DEBUG_SYMBOLS=false
 343   elif test "x$NATIVE_DEBUG_SYMBOLS" = xexternal; then
 344 
 345     if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
 346       if test "x$OBJCOPY" = x; then
 347         # enabling of enable-debug-symbols and can't find objcopy
 348         # this is an error
 349         AC_MSG_ERROR([Unable to find objcopy, cannot enable native debug symbols])
 350       fi
 351     fi
 352 
 353     COMPILE_WITH_DEBUG_SYMBOLS=true
 354     COPY_DEBUG_SYMBOLS=true
 355     ZIP_EXTERNAL_DEBUG_SYMBOLS=false
 356   else
 357     AC_MSG_ERROR([Allowed native debug symbols are: none, internal, external, zipped])
 358   fi
 359 
 360   AC_SUBST(COMPILE_WITH_DEBUG_SYMBOLS)
 361   AC_SUBST(COPY_DEBUG_SYMBOLS)
 362   AC_SUBST(ZIP_EXTERNAL_DEBUG_SYMBOLS)
 363 ])
 364 
 365 ################################################################################
 366 #
 367 # Native and Java code coverage
 368 #
 369 AC_DEFUN_ONCE([JDKOPT_SETUP_CODE_COVERAGE],
 370 [
 371   AC_ARG_ENABLE(native-coverage, [AS_HELP_STRING([--enable-native-coverage],
 372       [enable native compilation with code coverage data@<:@disabled@:>@])])
 373   GCOV_ENABLED="false"
 374   if test "x$enable_native_coverage" = "xyes"; then
 375     case $TOOLCHAIN_TYPE in
 376       gcc | clang)
 377         AC_MSG_CHECKING([if native coverage is enabled])
 378         AC_MSG_RESULT([yes])
 379         GCOV_CFLAGS="-fprofile-arcs -ftest-coverage -fno-inline"
 380         GCOV_LDFLAGS="-fprofile-arcs"
 381         JVM_CFLAGS="$JVM_CFLAGS $GCOV_CFLAGS"
 382         JVM_LDFLAGS="$JVM_LDFLAGS $GCOV_LDFLAGS"
 383         CFLAGS_JDKLIB="$CFLAGS_JDKLIB $GCOV_CFLAGS"
 384         CFLAGS_JDKEXE="$CFLAGS_JDKEXE $GCOV_CFLAGS"
 385         CXXFLAGS_JDKLIB="$CXXFLAGS_JDKLIB $GCOV_CFLAGS"
 386         CXXFLAGS_JDKEXE="$CXXFLAGS_JDKEXE $GCOV_CFLAGS"
 387         LDFLAGS_JDKLIB="$LDFLAGS_JDKLIB $GCOV_LDFLAGS"
 388         LDFLAGS_JDKEXE="$LDFLAGS_JDKEXE $GCOV_LDFLAGS"
 389         GCOV_ENABLED="true"
 390         ;;
 391       *)
 392         AC_MSG_ERROR([--enable-native-coverage only works with toolchain type gcc or clang])
 393         ;;
 394     esac
 395   elif test "x$enable_native_coverage" = "xno"; then
 396     AC_MSG_CHECKING([if native coverage is enabled])
 397     AC_MSG_RESULT([no])
 398   elif test "x$enable_native_coverage" != "x"; then
 399     AC_MSG_ERROR([--enable-native-coverage can only be assigned "yes" or "no"])
 400   fi
 401   AC_SUBST(GCOV_ENABLED)
 402 
 403   AC_ARG_WITH(jcov, [AS_HELP_STRING([--with-jcov],
 404       [jcov library location])])
 405   AC_ARG_WITH(jcov-input-jdk, [AS_HELP_STRING([--with-jcov-input-jdk],
 406       [jdk image to instrument])])
 407   AC_ARG_WITH(jcov-filters, [AS_HELP_STRING([--with-jcov-filters],
 408       [filters to limit code for jcov instrumentation and report generation])])
 409   JCOV_HOME=
 410   JCOV_INPUT_JDK=
 411   JCOV_ENABLED=
 412   JCOV_FILTERS=
 413   if test "x$with_jcov" = "x" ; then
 414     JCOV_ENABLED="false"
 415   else
 416     JCOV_HOME="$with_jcov"
 417     if test ! -f "$JCOV_HOME/lib/jcov.jar"; then
 418       AC_MSG_RESULT([fail])
 419       AC_MSG_ERROR([Invalid JCov bundle: "$JCOV_HOME/lib/jcov.jar" does not exist])
 420     fi
 421     JCOV_ENABLED="true"
 422     BASIC_FIXUP_PATH(JCOV_HOME)
 423     if test "x$with_jcov_input_jdk" != "x" ; then
 424       JCOV_INPUT_JDK="$with_jcov_input_jdk"
 425       if test ! -f "$JCOV_INPUT_JDK/bin/java$EXE_SUFFIX"; then
 426         AC_MSG_RESULT([fail])
 427         AC_MSG_ERROR([Invalid JDK bundle: "$JCOV_INPUT_JDK/bin/java$EXE_SUFFIX" does not exist])
 428       fi
 429       BASIC_FIXUP_PATH(JCOV_INPUT_JDK)
 430     fi
 431     if test "x$with_jcov_filters" != "x" ; then
 432       JCOV_FILTERS="$with_jcov_filters"
 433     fi
 434   fi
 435   AC_SUBST(JCOV_ENABLED)
 436   AC_SUBST(JCOV_HOME)
 437   AC_SUBST(JCOV_INPUT_JDK)
 438   AC_SUBST(JCOV_FILTERS)
 439 ])
 440 
 441 ###############################################################################
 442 #
 443 # AddressSanitizer
 444 #
 445 AC_DEFUN_ONCE([JDKOPT_SETUP_ADDRESS_SANITIZER],
 446 [
 447   AC_ARG_ENABLE(asan, [AS_HELP_STRING([--enable-asan],
 448       [enable AddressSanitizer if possible @<:@disabled@:>@])])
 449   ASAN_ENABLED="no"
 450   if test "x$enable_asan" = "xyes"; then
 451     case $TOOLCHAIN_TYPE in
 452       gcc | clang)
 453         AC_MSG_CHECKING([if asan is enabled])
 454         AC_MSG_RESULT([yes])
 455         ASAN_CFLAGS="-fsanitize=address -fno-omit-frame-pointer"
 456         ASAN_LDFLAGS="-fsanitize=address"
 457         JVM_CFLAGS="$JVM_CFLAGS $ASAN_CFLAGS"
 458         JVM_LDFLAGS="$JVM_LDFLAGS $ASAN_LDFLAGS"
 459         CFLAGS_JDKLIB="$CFLAGS_JDKLIB $ASAN_CFLAGS"
 460         CFLAGS_JDKEXE="$CFLAGS_JDKEXE $ASAN_CFLAGS"
 461         CXXFLAGS_JDKLIB="$CXXFLAGS_JDKLIB $ASAN_CFLAGS"
 462         CXXFLAGS_JDKEXE="$CXXFLAGS_JDKEXE $ASAN_CFLAGS"
 463         LDFLAGS_JDKLIB="$LDFLAGS_JDKLIB $ASAN_LDFLAGS"
 464         LDFLAGS_JDKEXE="$LDFLAGS_JDKEXE $ASAN_LDFLAGS"
 465         ASAN_ENABLED="yes"
 466         ;;
 467       *)
 468         AC_MSG_ERROR([--enable-asan only works with toolchain type gcc or clang])
 469         ;;
 470     esac
 471   elif test "x$enable_asan" = "xno"; then
 472     AC_MSG_CHECKING([if asan is enabled])
 473     AC_MSG_RESULT([no])
 474   elif test "x$enable_asan" != "x"; then
 475     AC_MSG_ERROR([--enable-asan can only be assigned "yes" or "no"])
 476   fi
 477 
 478   AC_SUBST(ASAN_ENABLED)
 479 ])
 480 
 481 ################################################################################
 482 #
 483 # Static build support.  When enabled will generate static
 484 # libraries instead of shared libraries for all JDK libs.
 485 #
 486 AC_DEFUN_ONCE([JDKOPT_SETUP_STATIC_BUILD],
 487 [
 488   AC_ARG_ENABLE([static-build], [AS_HELP_STRING([--enable-static-build],
 489     [enable static library build @<:@disabled@:>@])])
 490   STATIC_BUILD=false
 491   if test "x$enable_static_build" = "xyes"; then
 492     AC_MSG_CHECKING([if static build is enabled])
 493     AC_MSG_RESULT([yes])
 494     if test "x$OPENJDK_TARGET_OS" != "xmacosx"; then
 495       AC_MSG_ERROR([--enable-static-build is only supported for macosx builds])
 496     fi
 497     STATIC_BUILD_CFLAGS="-DSTATIC_BUILD=1"
 498     CFLAGS_JDKLIB_EXTRA="$CFLAGS_JDKLIB_EXTRA $STATIC_BUILD_CFLAGS"
 499     CXXFLAGS_JDKLIB_EXTRA="$CXXFLAGS_JDKLIB_EXTRA $STATIC_BUILD_CFLAGS"
 500     STATIC_BUILD=true
 501   elif test "x$enable_static_build" = "xno"; then
 502     AC_MSG_CHECKING([if static build is enabled])
 503     AC_MSG_RESULT([no])
 504   elif test "x$enable_static_build" != "x"; then
 505     AC_MSG_ERROR([--enable-static-build can only be assigned "yes" or "no"])
 506   fi
 507 
 508   AC_SUBST(STATIC_BUILD)
 509 ])
 510 
 511 ################################################################################
 512 #
 513 # jlink options.
 514 # We always keep packaged modules in JDK image.
 515 #
 516 AC_DEFUN_ONCE([JDKOPT_SETUP_JLINK_OPTIONS],
 517 [
 518   AC_ARG_ENABLE([keep-packaged-modules], [AS_HELP_STRING([--disable-keep-packaged-modules],
 519     [Do not keep packaged modules in jdk image @<:@enable@:>@])])
 520 
 521   AC_MSG_CHECKING([if packaged modules are kept])
 522   if test "x$enable_keep_packaged_modules" = "xyes"; then
 523     AC_MSG_RESULT([yes])
 524     JLINK_KEEP_PACKAGED_MODULES=true
 525   elif test "x$enable_keep_packaged_modules" = "xno"; then
 526     AC_MSG_RESULT([no])
 527     JLINK_KEEP_PACKAGED_MODULES=false
 528   elif test "x$enable_keep_packaged_modules" = "x"; then
 529     AC_MSG_RESULT([yes (default)])
 530     JLINK_KEEP_PACKAGED_MODULES=true
 531   else
 532     AC_MSG_RESULT([error])
 533     AC_MSG_ERROR([--enable-keep-packaged-modules accepts no argument])
 534   fi
 535 
 536   AC_SUBST(JLINK_KEEP_PACKAGED_MODULES)
 537 ])
 538 
 539 ################################################################################
 540 #
 541 # Check if building of the jtreg failure handler should be enabled.
 542 #
 543 AC_DEFUN_ONCE([JDKOPT_ENABLE_DISABLE_FAILURE_HANDLER],
 544 [
 545   AC_ARG_ENABLE([jtreg-failure-handler], [AS_HELP_STRING([--enable-jtreg-failure-handler],
 546     [forces build of the jtreg failure handler to be enabled, missing dependencies
 547      become fatal errors. Default is auto, where the failure handler is built if all
 548      dependencies are present and otherwise just disabled.])])
 549 
 550   AC_MSG_CHECKING([if jtreg failure handler should be built])
 551 
 552   if test "x$enable_jtreg_failure_handler" = "xyes"; then
 553     if test "x$JT_HOME" = "x"; then
 554       AC_MSG_ERROR([Cannot enable jtreg failure handler without jtreg.])
 555     else
 556       BUILD_FAILURE_HANDLER=true
 557       AC_MSG_RESULT([yes, forced])
 558     fi
 559   elif test "x$enable_jtreg_failure_handler" = "xno"; then
 560     BUILD_FAILURE_HANDLER=false
 561     AC_MSG_RESULT([no, forced])
 562   elif test "x$enable_jtreg_failure_handler" = "xauto" \
 563       || test "x$enable_jtreg_failure_handler" = "x"; then
 564     if test "x$JT_HOME" = "x"; then
 565       BUILD_FAILURE_HANDLER=false
 566       AC_MSG_RESULT([no, missing jtreg])
 567     else
 568       BUILD_FAILURE_HANDLER=true
 569       AC_MSG_RESULT([yes, jtreg present])
 570     fi
 571   else
 572     AC_MSG_ERROR([Invalid value for --enable-jtreg-failure-handler: $enable_jtreg_failure_handler])
 573   fi
 574 
 575   AC_SUBST(BUILD_FAILURE_HANDLER)
 576 ])
 577 
 578 ################################################################################
 579 #
 580 # Enable or disable generation of the classlist at build time
 581 #
 582 AC_DEFUN_ONCE([JDKOPT_ENABLE_DISABLE_GENERATE_CLASSLIST],
 583 [
 584   AC_ARG_ENABLE([generate-classlist], [AS_HELP_STRING([--disable-generate-classlist],
 585       [forces enabling or disabling of the generation of a CDS classlist at build time.
 586       Default is to generate it when either the server or client JVMs are built and
 587       enable-cds is true.])])
 588 
 589   # Check if it's likely that it's possible to generate the classlist. Depending
 590   # on exact jvm configuration it could be possible anyway.
 591   if test "x$ENABLE_CDS" = "xtrue" && (HOTSPOT_CHECK_JVM_VARIANT(server) || HOTSPOT_CHECK_JVM_VARIANT(client) || HOTSPOT_CHECK_JVM_FEATURE(cds)); then
 592     ENABLE_GENERATE_CLASSLIST_POSSIBLE="true"
 593   else
 594     ENABLE_GENERATE_CLASSLIST_POSSIBLE="false"
 595   fi
 596 
 597   AC_MSG_CHECKING([if the CDS classlist generation should be enabled])
 598   if test "x$enable_generate_classlist" = "xyes"; then
 599     AC_MSG_RESULT([yes, forced])
 600     ENABLE_GENERATE_CLASSLIST="true"
 601     if test "x$ENABLE_GENERATE_CLASSLIST_POSSIBLE" = "xfalse"; then
 602       AC_MSG_WARN([Generation of classlist might not be possible with JVM Variants $JVM_VARIANTS and enable-cds=$ENABLE_CDS])
 603     fi
 604   elif test "x$enable_generate_classlist" = "xno"; then
 605     AC_MSG_RESULT([no, forced])
 606     ENABLE_GENERATE_CLASSLIST="false"
 607   elif test "x$enable_generate_classlist" = "x"; then
 608     if test "x$ENABLE_GENERATE_CLASSLIST_POSSIBLE" = "xtrue"; then
 609       AC_MSG_RESULT([yes])
 610       ENABLE_GENERATE_CLASSLIST="true"
 611     else
 612       AC_MSG_RESULT([no])
 613       ENABLE_GENERATE_CLASSLIST="false"
 614     fi
 615   else
 616     AC_MSG_ERROR([Invalid value for --enable-generate-classlist: $enable_generate_classlist])
 617   fi
 618 
 619   AC_SUBST(ENABLE_GENERATE_CLASSLIST)
 620 ])
 621 
 622 ################################################################################
 623 #
 624 # Optionally filter resource translations
 625 #
 626 AC_DEFUN([JDKOPT_EXCLUDE_TRANSLATIONS],
 627 [
 628   AC_ARG_WITH([exclude-translations], [AS_HELP_STRING([--with-exclude-translations],
 629       [a comma separated list of locales to exclude translations for. Default is
 630       to include all translations present in the source.])])
 631 
 632   EXCLUDE_TRANSLATIONS=""
 633   AC_MSG_CHECKING([if any translations should be excluded])
 634   if test "x$with_exclude_translations" != "x"; then
 635     EXCLUDE_TRANSLATIONS="${with_exclude_translations//,/ }"
 636     AC_MSG_RESULT([yes: $EXCLUDE_TRANSLATIONS])
 637   else
 638     AC_MSG_RESULT([no])
 639   fi
 640 
 641   AC_SUBST(EXCLUDE_TRANSLATIONS)
 642 ])
 643 
 644 ################################################################################
 645 #
 646 # Optionally disable man pages
 647 #
 648 AC_DEFUN([JDKOPT_ENABLE_DISABLE_MANPAGES],
 649 [
 650   AC_ARG_ENABLE([manpages], [AS_HELP_STRING([--disable-manpages],
 651       [Set to disable copy of static man pages @<:@enabled@:>@])])
 652 
 653   BUILD_MANPAGES="true"
 654   AC_MSG_CHECKING([if static man pages should be copied])
 655   if test "x$enable_manpages" = "x"; then
 656     AC_MSG_RESULT([yes])
 657   elif test "x$enable_manpages" = "xyes"; then
 658     AC_MSG_RESULT([yes, forced])
 659   elif test "x$enable_manpages" = "xno"; then
 660     AC_MSG_RESULT([no, forced])
 661     BUILD_MANPAGES="false"
 662   else
 663     AC_MSG_RESULT([no])
 664     AC_MSG_ERROR([--enable-manpages can only yes/no or empty])
 665   fi
 666 
 667   AC_SUBST(BUILD_MANPAGES)
 668 ])
 669 
 670 ################################################################################
 671 #
 672 # Disable the default CDS archive generation
 673 #   cross compilation - disabled
 674 #
 675 AC_DEFUN([JDKOPT_ENABLE_DISABLE_CDS_ARCHIVE],
 676 [
 677   AC_ARG_ENABLE([cds-archive], [AS_HELP_STRING([--disable-cds-archive],
 678       [Set to disable generation of a default CDS archive in the product image @<:@enabled@:>@])])
 679 
 680   AC_MSG_CHECKING([if a default CDS archive should be generated])
 681   if test "x$ENABLE_CDS" = "xfalse"; then
 682     AC_MSG_RESULT([no, because CDS is disabled])
 683     BUILD_CDS_ARCHIVE="false"
 684   elif test "x$COMPILE_TYPE" = "xcross"; then
 685     AC_MSG_RESULT([no, not possible with cross compilation])
 686     BUILD_CDS_ARCHIVE="false"
 687   elif test "x$enable_cds_archive" = "xyes"; then
 688     AC_MSG_RESULT([yes, forced])
 689     BUILD_CDS_ARCHIVE="true"
 690   elif test "x$enable_cds_archive" = "x"; then
 691     AC_MSG_RESULT([yes])
 692     BUILD_CDS_ARCHIVE="true"
 693   elif test "x$enable_cds_archive" = "xno"; then
 694     AC_MSG_RESULT([no, forced])
 695     BUILD_CDS_ARCHIVE="false"
 696   else
 697     AC_MSG_RESULT([no])
 698     AC_MSG_ERROR([--enable-cds_archive can only be yes/no or empty])
 699   fi
 700 
 701   AC_SUBST(BUILD_CDS_ARCHIVE)
 702 ])