1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ###############################################################################
  27 # Create a function/macro that takes a series of named arguments. The call is
  28 # similar to AC_DEFUN, but the setup of the function looks like this:
  29 # BASIC_DEFUN_NAMED([MYFUNC], [FOO *BAR], [$@], [
  30 # ... do something
  31 #   AC_MSG_NOTICE([Value of BAR is ARG_BAR])
  32 # ])
  33 # A star (*) in front of a named argument means that it is required and it's
  34 # presence will be verified. To pass e.g. the first value as a normal indexed
  35 # argument, use [m4_shift($@)] as the third argument instead of [$@]. These
  36 # arguments are referenced in the function by their name prefixed by ARG_, e.g.
  37 # "ARG_FOO".
  38 #
  39 # The generated function can be called like this:
  40 # MYFUNC(FOO: [foo-val],
  41 #     BAR: [
  42 #         $ECHO hello world
  43 #     ])
  44 # Note that the argument value must start on the same line as the argument name.
  45 #
  46 # Argument 1: Name of the function to define
  47 # Argument 2: List of legal named arguments, with a * prefix for required arguments
  48 # Argument 3: Argument array to treat as named, typically $@
  49 # Argument 4: The main function body
  50 AC_DEFUN([BASIC_DEFUN_NAMED],
  51 [
  52   AC_DEFUN($1, [
  53     m4_foreach(arg, m4_split($2), [
  54       m4_if(m4_bregexp(arg, [^\*]), -1,
  55         [
  56           m4_set_add(legal_named_args, arg)
  57         ],
  58         [
  59           m4_set_add(legal_named_args, m4_substr(arg, 1))
  60           m4_set_add(required_named_args, m4_substr(arg, 1))
  61         ]
  62       )
  63     ])
  64 
  65     m4_foreach([arg], [$3], [
  66       m4_define(arg_name, m4_substr(arg, 0, m4_bregexp(arg, [: ])))
  67       m4_set_contains(legal_named_args, arg_name, [],[AC_MSG_ERROR([Internal error: arg_name is not a valid named argument to [$1]. Valid arguments are 'm4_set_contents(legal_named_args, [ ])'.])])
  68       m4_set_remove(required_named_args, arg_name)
  69       m4_set_remove(legal_named_args, arg_name)
  70       m4_pushdef([ARG_][]arg_name, m4_substr(arg, m4_incr(m4_incr(m4_bregexp(arg, [: ])))))
  71       m4_set_add(defined_args, arg_name)
  72       m4_undefine([arg_name])
  73     ])
  74     m4_set_empty(required_named_args, [], [
  75       AC_MSG_ERROR([Internal error: Required named arguments are missing for [$1]. Missing arguments: 'm4_set_contents(required_named_args, [ ])'])
  76     ])
  77     m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([legal_named_args])), [
  78       m4_pushdef([ARG_][]arg, [])
  79       m4_set_add(defined_args, arg)
  80     ])
  81     m4_set_delete(legal_named_args)
  82     m4_set_delete(required_named_args)
  83 
  84     # Execute function body
  85     $4
  86 
  87     m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([defined_args])), [
  88       m4_popdef([ARG_][]arg)
  89     ])
  90 
  91     m4_set_delete(defined_args)
  92   ])
  93 ])
  94 
  95 ###############################################################################
  96 # Check if a list of space-separated words are selected only from a list of
  97 # space-separated legal words. Typical use is to see if a user-specified
  98 # set of words is selected from a set of legal words.
  99 #
 100 # Sets the specified variable to list of non-matching (offending) words, or to
 101 # the empty string if all words are matching the legal set.
 102 #
 103 # $1: result variable name
 104 # $2: list of values to check
 105 # $3: list of legal values
 106 AC_DEFUN([BASIC_GET_NON_MATCHING_VALUES],
 107 [
 108   # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
 109   # Notice that the original variant fails on SLES 10 and 11
 110   # Some grep versions (at least bsd) behaves strangely on the base case with
 111   # no legal_values, so make it explicit.
 112   values_to_check=`$ECHO $2 | $TR ' ' '\n'`
 113   legal_values=`$ECHO $3 | $TR ' ' '\n'`
 114   if test -z "$legal_values"; then
 115     $1="$2"
 116   else
 117     result=`$GREP -Fvx "$legal_values" <<< "$values_to_check" | $GREP -v '^$'`
 118     $1=${result//$'\n'/ }
 119   fi
 120 ])
 121 
 122 ###############################################################################
 123 # Check if a list of space-separated words contains any word(s) from a list of
 124 # space-separated illegal words. Typical use is to see if a user-specified
 125 # set of words contains any from a set of illegal words.
 126 #
 127 # Sets the specified variable to list of matching illegal words, or to
 128 # the empty string if no words are matching the illegal set.
 129 #
 130 # $1: result variable name
 131 # $2: list of values to check
 132 # $3: list of illegal values
 133 AC_DEFUN([BASIC_GET_MATCHING_VALUES],
 134 [
 135   # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
 136   # Notice that the original variant fails on SLES 10 and 11
 137   # Some grep versions (at least bsd) behaves strangely on the base case with
 138   # no legal_values, so make it explicit.
 139   values_to_check=`$ECHO $2 | $TR ' ' '\n'`
 140   illegal_values=`$ECHO $3 | $TR ' ' '\n'`
 141   if test -z "$illegal_values"; then
 142     $1=""
 143   else
 144     result=`$GREP -Fx "$illegal_values" <<< "$values_to_check" | $GREP -v '^$'`
 145     $1=${result//$'\n'/ }
 146   fi
 147 ])
 148 
 149 ###############################################################################
 150 # Sort a space-separated list, and remove duplicates.
 151 #
 152 # Sets the specified variable to the resulting list.
 153 #
 154 # $1: result variable name
 155 # $2: list of values to sort
 156 AC_DEFUN([BASIC_SORT_LIST],
 157 [
 158   values_to_sort=`$ECHO $2 | $TR ' ' '\n'`
 159   result=`$SORT -u <<< "$values_to_sort" | $GREP -v '^$'`
 160   $1=${result//$'\n'/ }
 161 ])
 162 
 163 ###############################################################################
 164 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
 165 # If so, then append $1 to $2 \
 166 # Also set JVM_ARG_OK to true/false depending on outcome.
 167 AC_DEFUN([ADD_JVM_ARG_IF_OK],
 168 [
 169   $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
 170   $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
 171   OUTPUT=`$3 $1 $USER_BOOT_JDK_OPTIONS -version 2>&1`
 172   FOUND_WARN=`$ECHO "$OUTPUT" | $GREP -i warn`
 173   FOUND_VERSION=`$ECHO $OUTPUT | $GREP " version \""`
 174   if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
 175     $2="[$]$2 $1"
 176     JVM_ARG_OK=true
 177   else
 178     $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
 179     $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
 180     JVM_ARG_OK=false
 181   fi
 182 ])
 183 
 184 # Appends a string to a path variable, only adding the : when needed.
 185 AC_DEFUN([BASIC_APPEND_TO_PATH],
 186 [
 187   if test "x$2" != x; then
 188     if test "x[$]$1" = x; then
 189       $1="$2"
 190     else
 191       $1="[$]$1:$2"
 192     fi
 193   fi
 194 ])
 195 
 196 # Prepends a string to a path variable, only adding the : when needed.
 197 AC_DEFUN([BASIC_PREPEND_TO_PATH],
 198 [
 199   if test "x$2" != x; then
 200     if test "x[$]$1" = x; then
 201       $1="$2"
 202     else
 203       $1="$2:[$]$1"
 204     fi
 205   fi
 206 ])
 207 
 208 ###############################################################################
 209 # This will make sure the given variable points to a full and proper
 210 # path. This means:
 211 # 1) There will be no spaces in the path. On unix platforms,
 212 #    spaces in the path will result in an error. On Windows,
 213 #    the path will be rewritten using short-style to be space-free.
 214 # 2) The path will be absolute, and it will be in unix-style (on
 215 #     cygwin).
 216 # $1: The name of the variable to fix
 217 AC_DEFUN([BASIC_FIXUP_PATH],
 218 [
 219   # Only process if variable expands to non-empty
 220 
 221   if test "x[$]$1" != x; then
 222     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 223       BASIC_FIXUP_PATH_CYGWIN($1)
 224     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 225       BASIC_FIXUP_PATH_MSYS($1)
 226     else
 227       # We're on a unix platform. Hooray! :)
 228       path="[$]$1"
 229       has_space=`$ECHO "$path" | $GREP " "`
 230       if test "x$has_space" != x; then
 231         AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
 232         AC_MSG_ERROR([Spaces are not allowed in this path.])
 233       fi
 234 
 235       # Use eval to expand a potential ~
 236       eval path="$path"
 237       if test ! -f "$path" && test ! -d "$path"; then
 238         AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
 239       fi
 240 
 241       if test -d "$path"; then
 242         $1="`cd "$path"; $THEPWDCMD -L`"
 243       else
 244         dir="`$DIRNAME "$path"`"
 245         base="`$BASENAME "$path"`"
 246         $1="`cd "$dir"; $THEPWDCMD -L`/$base"
 247       fi
 248     fi
 249   fi
 250 ])
 251 
 252 ###############################################################################
 253 # This will make sure the given variable points to a executable
 254 # with a full and proper path. This means:
 255 # 1) There will be no spaces in the path. On unix platforms,
 256 #    spaces in the path will result in an error. On Windows,
 257 #    the path will be rewritten using short-style to be space-free.
 258 # 2) The path will be absolute, and it will be in unix-style (on
 259 #     cygwin).
 260 # Any arguments given to the executable is preserved.
 261 # If the input variable does not have a directory specification, then
 262 # it need to be in the PATH.
 263 # $1: The name of the variable to fix
 264 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
 265 [
 266   # Only process if variable expands to non-empty
 267 
 268   if test "x[$]$1" != x; then
 269     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 270       BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
 271     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 272       BASIC_FIXUP_EXECUTABLE_MSYS($1)
 273     else
 274       # We're on a unix platform. Hooray! :)
 275       # First separate the path from the arguments. This will split at the first
 276       # space.
 277       complete="[$]$1"
 278       path="${complete%% *}"
 279       tmp="$complete EOL"
 280       arguments="${tmp#* }"
 281 
 282       # Cannot rely on the command "which" here since it doesn't always work.
 283       is_absolute_path=`$ECHO "$path" | $GREP ^/`
 284       if test -z "$is_absolute_path"; then
 285         # Path to executable is not absolute. Find it.
 286         IFS_save="$IFS"
 287         IFS=:
 288         for p in $PATH; do
 289           if test -f "$p/$path" && test -x "$p/$path"; then
 290             new_path="$p/$path"
 291             break
 292           fi
 293         done
 294         IFS="$IFS_save"
 295       else
 296         # This is an absolute path, we can use it without further modifications.
 297         new_path="$path"
 298       fi
 299 
 300       if test "x$new_path" = x; then
 301         AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
 302         has_space=`$ECHO "$complete" | $GREP " "`
 303         if test "x$has_space" != x; then
 304           AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
 305         fi
 306         AC_MSG_ERROR([Cannot locate the the path of $1])
 307       fi
 308     fi
 309 
 310     # Now join together the path and the arguments once again
 311     if test "x$arguments" != xEOL; then
 312       new_complete="$new_path ${arguments% *}"
 313     else
 314       new_complete="$new_path"
 315     fi
 316 
 317     if test "x$complete" != "x$new_complete"; then
 318       $1="$new_complete"
 319       AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
 320     fi
 321   fi
 322 ])
 323 
 324 ###############################################################################
 325 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
 326 [
 327   if test "x$OPENJDK_BUILD_OS" != xwindows; then
 328     # Follow a chain of symbolic links. Use readlink
 329     # where it exists, else fall back to horribly
 330     # complicated shell code.
 331     if test "x$READLINK_TESTED" != yes; then
 332       # On MacOSX there is a readlink tool with a different
 333       # purpose than the GNU readlink tool. Check the found readlink.
 334       READLINK_ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
 335       # If READLINK_ISGNU is empty, then it's a non-GNU readlink. Don't use it.
 336       READLINK_TESTED=yes
 337     fi
 338 
 339     if test "x$READLINK" != x && test "x$READLINK_ISGNU" != x; then
 340       $1=`$READLINK -f [$]$1`
 341     else
 342       # Save the current directory for restoring afterwards
 343       STARTDIR=$PWD
 344       COUNTER=0
 345       sym_link_dir=`$DIRNAME [$]$1`
 346       sym_link_file=`$BASENAME [$]$1`
 347       cd $sym_link_dir
 348       # Use -P flag to resolve symlinks in directories.
 349       cd `$THEPWDCMD -P`
 350       sym_link_dir=`$THEPWDCMD -P`
 351       # Resolve file symlinks
 352       while test $COUNTER -lt 20; do
 353         ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
 354         if test "x$ISLINK" == x; then
 355           # This is not a symbolic link! We are done!
 356           break
 357         fi
 358         # Again resolve directory symlinks since the target of the just found
 359         # link could be in a different directory
 360         cd `$DIRNAME $ISLINK`
 361         sym_link_dir=`$THEPWDCMD -P`
 362         sym_link_file=`$BASENAME $ISLINK`
 363         let COUNTER=COUNTER+1
 364       done
 365       cd $STARTDIR
 366       $1=$sym_link_dir/$sym_link_file
 367     fi
 368   fi
 369 ])
 370 
 371 ###############################################################################
 372 # Register a --with argument but mark it as deprecated
 373 # $1: The name of the with argument to deprecate, not including --with-
 374 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
 375 [
 376   AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
 377       [Deprecated. Option is kept for backwards compatibility and is ignored])],
 378       [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
 379 ])
 380 
 381 ###############################################################################
 382 # Register a --enable argument but mark it as deprecated
 383 # $1: The name of the with argument to deprecate, not including --enable-
 384 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
 385 # $3: Messages to user.
 386 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
 387 [
 388   AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
 389       [Deprecated. Option is kept for backwards compatibility and is ignored])])
 390   if test "x$enable_$2" != x; then
 391     AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
 392 
 393     if test "x$3" != x; then
 394       AC_MSG_WARN([$3])
 395     fi
 396 
 397   fi
 398 ])
 399 
 400 ###############################################################################
 401 AC_DEFUN_ONCE([BASIC_INIT],
 402 [
 403   # Save the original command line. This is passed to us by the wrapper configure script.
 404   AC_SUBST(CONFIGURE_COMMAND_LINE)
 405   # Save the path variable before it gets changed
 406   ORIGINAL_PATH="$PATH"
 407   AC_SUBST(ORIGINAL_PATH)
 408   DATE_WHEN_CONFIGURED=`LANG=C date`
 409   AC_SUBST(DATE_WHEN_CONFIGURED)
 410   AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
 411 ])
 412 
 413 ###############################################################################
 414 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
 415 # $1: variable to check
 416 AC_DEFUN([BASIC_CHECK_NONEMPTY],
 417 [
 418   if test "x[$]$1" = x; then
 419     AC_MSG_ERROR([Could not find required tool for $1])
 420   fi
 421 ])
 422 
 423 ###############################################################################
 424 # Check that there are no unprocessed overridden variables left.
 425 # If so, they are an incorrect argument and we will exit with an error.
 426 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
 427 [
 428   if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
 429     # Replace the separating ! with spaces before presenting for end user.
 430     unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
 431     AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
 432   fi
 433 ])
 434 
 435 ###############################################################################
 436 # Setup a tool for the given variable. If correctly specified by the user,
 437 # use that value, otherwise search for the tool using the supplied code snippet.
 438 # $1: variable to set
 439 # $2: code snippet to call to look for the tool
 440 # $3: code snippet to call if variable was used to find tool
 441 AC_DEFUN([BASIC_SETUP_TOOL],
 442 [
 443   # Publish this variable in the help.
 444   AC_ARG_VAR($1, [Override default value for $1])
 445 
 446   if [[ -z "${$1+x}" ]]; then
 447     # The variable is not set by user, try to locate tool using the code snippet
 448     $2
 449   else
 450     # The variable is set, but is it from the command line or the environment?
 451 
 452     # Try to remove the string !$1! from our list.
 453     try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
 454     if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
 455       # If it failed, the variable was not from the command line. Ignore it,
 456       # but warn the user (except for BASH, which is always set by the calling BASH).
 457       if test "x$1" != xBASH; then
 458         AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
 459       fi
 460       # Try to locate tool using the code snippet
 461       $2
 462     else
 463       # If it succeeded, then it was overridden by the user. We will use it
 464       # for the tool.
 465 
 466       # First remove it from the list of overridden variables, so we can test
 467       # for unknown variables in the end.
 468       CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
 469 
 470       # Check if we try to supply an empty value
 471       if test "x[$]$1" = x; then
 472         AC_MSG_NOTICE([Setting user supplied tool $1= (no value)])
 473         AC_MSG_CHECKING([for $1])
 474         AC_MSG_RESULT([disabled])
 475       else
 476         # Check if the provided tool contains a complete path.
 477         tool_specified="[$]$1"
 478         tool_basename="${tool_specified##*/}"
 479         if test "x$tool_basename" = "x$tool_specified"; then
 480           # A command without a complete path is provided, search $PATH.
 481           AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
 482           AC_PATH_PROG($1, $tool_basename)
 483           if test "x[$]$1" = x; then
 484             AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
 485           fi
 486         else
 487           # Otherwise we believe it is a complete path. Use it as it is.
 488           AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
 489           AC_MSG_CHECKING([for $1])
 490           if test ! -x "$tool_specified"; then
 491             AC_MSG_RESULT([not found])
 492             AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
 493           fi
 494           AC_MSG_RESULT([$tool_specified])
 495         fi
 496       fi
 497     fi
 498     $3
 499   fi
 500 ])
 501 
 502 ###############################################################################
 503 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
 504 # $1: variable to set
 505 # $2: executable name (or list of names) to look for
 506 # $3: [path]
 507 AC_DEFUN([BASIC_PATH_PROGS],
 508 [
 509   BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2, , $3)])
 510 ])
 511 
 512 ###############################################################################
 513 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
 514 # $1: variable to set
 515 # $2: executable name (or list of names) to look for
 516 AC_DEFUN([BASIC_CHECK_TOOLS],
 517 [
 518   BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
 519 ])
 520 
 521 ###############################################################################
 522 # Like BASIC_PATH_PROGS but fails if no tool was found.
 523 # $1: variable to set
 524 # $2: executable name (or list of names) to look for
 525 # $3: [path]
 526 AC_DEFUN([BASIC_REQUIRE_PROGS],
 527 [
 528   BASIC_PATH_PROGS($1, $2, , $3)
 529   BASIC_CHECK_NONEMPTY($1)
 530 ])
 531 
 532 ###############################################################################
 533 # Like BASIC_SETUP_TOOL but fails if no tool was found.
 534 # $1: variable to set
 535 # $2: autoconf macro to call to look for the special tool
 536 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
 537 [
 538   BASIC_SETUP_TOOL($1, [$2])
 539   BASIC_CHECK_NONEMPTY($1)
 540 ])
 541 
 542 ###############################################################################
 543 # Setup the most fundamental tools that relies on not much else to set up,
 544 # but is used by much of the early bootstrap code.
 545 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
 546 [
 547   # Start with tools that do not need have cross compilation support
 548   # and can be expected to be found in the default PATH. These tools are
 549   # used by configure.
 550 
 551   # First are all the simple required tools.
 552   BASIC_REQUIRE_PROGS(BASENAME, basename)
 553   BASIC_REQUIRE_PROGS(BASH, bash)
 554   BASIC_REQUIRE_PROGS(CAT, cat)
 555   BASIC_REQUIRE_PROGS(CHMOD, chmod)
 556   BASIC_REQUIRE_PROGS(CMP, cmp)
 557   BASIC_REQUIRE_PROGS(COMM, comm)
 558   BASIC_REQUIRE_PROGS(CP, cp)
 559   BASIC_REQUIRE_PROGS(CUT, cut)
 560   BASIC_REQUIRE_PROGS(DATE, date)
 561   BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
 562   BASIC_REQUIRE_PROGS(DIRNAME, dirname)
 563   BASIC_REQUIRE_PROGS(ECHO, echo)
 564   BASIC_REQUIRE_PROGS(EXPR, expr)
 565   BASIC_REQUIRE_PROGS(FILE, file)
 566   BASIC_REQUIRE_PROGS(FIND, find)
 567   BASIC_REQUIRE_PROGS(HEAD, head)
 568   BASIC_REQUIRE_PROGS(GUNZIP, gunzip)
 569   BASIC_REQUIRE_PROGS(GZIP, pigz gzip)
 570   BASIC_REQUIRE_PROGS(LN, ln)
 571   BASIC_REQUIRE_PROGS(LS, ls)
 572   # gmkdir is known to be safe for concurrent invocations with -p flag.
 573   BASIC_REQUIRE_PROGS(MKDIR, [gmkdir mkdir])
 574   BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
 575   BASIC_REQUIRE_PROGS(MV, mv)
 576   BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
 577   BASIC_REQUIRE_PROGS(PRINTF, printf)
 578   BASIC_REQUIRE_PROGS(READLINK, [greadlink readlink])
 579   BASIC_REQUIRE_PROGS(RM, rm)
 580   BASIC_REQUIRE_PROGS(RMDIR, rmdir)
 581   BASIC_REQUIRE_PROGS(SH, sh)
 582   BASIC_REQUIRE_PROGS(SORT, sort)
 583   BASIC_REQUIRE_PROGS(TAIL, tail)
 584   BASIC_REQUIRE_PROGS(TAR, gtar tar)
 585   BASIC_REQUIRE_PROGS(TEE, tee)
 586   BASIC_REQUIRE_PROGS(TOUCH, touch)
 587   BASIC_REQUIRE_PROGS(TR, tr)
 588   BASIC_REQUIRE_PROGS(UNAME, uname)
 589   BASIC_REQUIRE_PROGS(UNIQ, uniq)
 590   BASIC_REQUIRE_PROGS(WC, wc)
 591   BASIC_REQUIRE_PROGS(WHICH, which)
 592   BASIC_REQUIRE_PROGS(XARGS, xargs)
 593 
 594   # Then required tools that require some special treatment.
 595   BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
 596   BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
 597   BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
 598   BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
 599   BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
 600 
 601   # Always force rm.
 602   RM="$RM -f"
 603 
 604   # pwd behaves differently on various platforms and some don't support the -L flag.
 605   # Always use the bash builtin pwd to get uniform behavior.
 606   THEPWDCMD=pwd
 607 
 608   # These are not required on all platforms
 609   BASIC_PATH_PROGS(CYGPATH, cygpath)
 610   BASIC_PATH_PROGS(DF, df)
 611   BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])
 612   BASIC_PATH_PROGS(NICE, nice)
 613   BASIC_PATH_PROGS(PANDOC, pandoc)
 614 ])
 615 
 616 ###############################################################################
 617 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
 618 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
 619 [
 620   # Save the current directory this script was started from
 621   CURDIR="$PWD"
 622 
 623   # We might need to rewrite ORIGINAL_PATH, if it includes "#", to quote them
 624   # for make. We couldn't do this when we retrieved ORIGINAL_PATH, since SED
 625   # was not available at that time.
 626   REWRITTEN_PATH=`$ECHO "$ORIGINAL_PATH" | $SED -e 's/#/\\\\#/g'`
 627   if test "x$REWRITTEN_PATH" != "x$ORIGINAL_PATH"; then
 628     ORIGINAL_PATH="$REWRITTEN_PATH"
 629     AC_MSG_NOTICE([Rewriting ORIGINAL_PATH to $REWRITTEN_PATH])
 630   fi
 631 
 632   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 633     PATH_SEP=";"
 634     BASIC_CHECK_PATHS_WINDOWS
 635   else
 636     PATH_SEP=":"
 637   fi
 638   AC_SUBST(PATH_SEP)
 639 
 640   # We get the top-level directory from the supporting wrappers.
 641   AC_MSG_CHECKING([for top-level directory])
 642   AC_MSG_RESULT([$TOPDIR])
 643   AC_SUBST(TOPDIR)
 644 
 645   # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
 646   BASIC_FIXUP_PATH(CURDIR)
 647   BASIC_FIXUP_PATH(TOPDIR)
 648 
 649   # Locate the directory of this script.
 650   AUTOCONF_DIR=$TOPDIR/make/autoconf
 651 
 652   # Setup username (for use in adhoc version strings etc)
 653   # Outer [ ] to quote m4.
 654   [ USERNAME=`$ECHO "$USER" | $TR -d -c '[a-z][A-Z][0-9]'` ]
 655   AC_SUBST(USERNAME)
 656 ])
 657 
 658 ###############################################################################
 659 # Evaluates platform specific overrides for devkit variables.
 660 # $1: Name of variable
 661 AC_DEFUN([BASIC_EVAL_DEVKIT_VARIABLE],
 662 [
 663   if test "x[$]$1" = x; then
 664     eval $1="\${$1_${OPENJDK_TARGET_CPU}}"
 665   fi
 666 ])
 667 
 668 ###############################################################################
 669 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
 670 [
 671   AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
 672       [use this devkit for compilers, tools and resources])])
 673 
 674   if test "x$with_devkit" = xyes; then
 675     AC_MSG_ERROR([--with-devkit must have a value])
 676   elif test "x$with_devkit" != x && test "x$with_devkit" != xno; then
 677     BASIC_FIXUP_PATH([with_devkit])
 678     DEVKIT_ROOT="$with_devkit"
 679     # Check for a meta data info file in the root of the devkit
 680     if test -f "$DEVKIT_ROOT/devkit.info"; then
 681       . $DEVKIT_ROOT/devkit.info
 682       # This potentially sets the following:
 683       # A descriptive name of the devkit
 684       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_NAME])
 685       # Corresponds to --with-extra-path
 686       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_EXTRA_PATH])
 687       # Corresponds to --with-toolchain-path
 688       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_TOOLCHAIN_PATH])
 689       # Corresponds to --with-sysroot
 690       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_SYSROOT])
 691 
 692       # Identifies the Visual Studio version in the devkit
 693       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_VERSION])
 694       # The Visual Studio include environment variable
 695       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_INCLUDE])
 696       # The Visual Studio lib environment variable
 697       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_LIB])
 698       # Corresponds to --with-msvcr-dll
 699       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCR_DLL])
 700       # Corresponds to --with-msvcp-dll
 701       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCP_DLL])
 702       # Corresponds to --with-ucrt-dll-dir
 703       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_UCRT_DLL_DIR])
 704     fi
 705 
 706     AC_MSG_CHECKING([for devkit])
 707     if test "x$DEVKIT_NAME" != x; then
 708       AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
 709     else
 710       AC_MSG_RESULT([$DEVKIT_ROOT])
 711     fi
 712 
 713     BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
 714 
 715     # Fallback default of just /bin if DEVKIT_PATH is not defined
 716     if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
 717       DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
 718     fi
 719     BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
 720 
 721     # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
 722     # places for backwards compatiblity.
 723     if test "x$DEVKIT_SYSROOT" != x; then
 724       SYSROOT="$DEVKIT_SYSROOT"
 725     elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
 726       SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
 727     elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
 728       SYSROOT="$DEVKIT_ROOT/$host/sys-root"
 729     fi
 730 
 731     if test "x$DEVKIT_ROOT" != x; then
 732       DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib"
 733       if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 734         DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib64"
 735       fi
 736       AC_SUBST(DEVKIT_LIB_DIR)
 737     fi
 738   fi
 739 
 740   # You can force the sysroot if the sysroot encoded into the compiler tools
 741   # is not correct.
 742   AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
 743       [alias for --with-sysroot for backwards compatability])],
 744       [SYSROOT=$with_sys_root]
 745   )
 746 
 747   AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
 748       [use this directory as sysroot])],
 749       [SYSROOT=$with_sysroot]
 750   )
 751 
 752   AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
 753       [alias for --with-toolchain-path for backwards compatibility])],
 754       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
 755   )
 756 
 757   AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
 758       [prepend these directories when searching for toolchain binaries (compilers etc)])],
 759       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
 760   )
 761 
 762   AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
 763       [prepend these directories to the default path])],
 764       [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
 765   )
 766 
 767   if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
 768     # If a devkit has been supplied, find xcodebuild in the toolchain_path.
 769     # If not, detect if Xcode is installed by running xcodebuild -version
 770     # if no Xcode installed, xcodebuild exits with 1
 771     # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0
 772     if test "x$DEVKIT_ROOT" != x || /usr/bin/xcodebuild -version >/dev/null 2>&1; then
 773       # We need to use xcodebuild in the toolchain dir provided by the user, this will
 774       # fall back on the stub binary in /usr/bin/xcodebuild
 775       AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])
 776     else
 777       # this should result in SYSROOT being empty, unless --with-sysroot is provided
 778       # when only the command line tools are installed there are no SDKs, so headers
 779       # are copied into the system frameworks
 780       XCODEBUILD=
 781       AC_SUBST(XCODEBUILD)
 782     fi
 783 
 784     AC_MSG_CHECKING([for sdk name])
 785     AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],
 786         [use the platform SDK of the given name. @<:@macosx@:>@])],
 787         [SDKNAME=$with_sdk_name]
 788     )
 789     AC_MSG_RESULT([$SDKNAME])
 790 
 791     # if toolchain path is specified then don't rely on system headers, they may not compile
 792     HAVE_SYSTEM_FRAMEWORK_HEADERS=0
 793     test -z "$TOOLCHAIN_PATH" && \
 794       HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`
 795 
 796     if test -z "$SYSROOT"; then
 797       if test -n "$XCODEBUILD"; then
 798         # if we don't have system headers, use default SDK name (last resort)
 799         if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
 800           SDKNAME=${SDKNAME:-macosx}
 801         fi
 802 
 803         if test -n "$SDKNAME"; then
 804           # Call xcodebuild to determine SYSROOT
 805           SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | $GREP '^Path: ' | $SED 's/Path: //'`
 806         fi
 807       else
 808         if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
 809           AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])
 810         fi
 811       fi
 812     else
 813       # warn user if --with-sdk-name was also set
 814       if test -n "$with_sdk_name"; then
 815         AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])
 816       fi
 817     fi
 818 
 819     if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then
 820       # If no system framework headers, then SYSROOT must be set, or we won't build
 821       AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])
 822     fi
 823 
 824     # Perform a basic sanity test
 825     if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
 826       if test -z "$SYSROOT"; then
 827         AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])
 828       else
 829         AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])
 830       fi
 831     fi
 832 
 833     # set SDKROOT too, Xcode tools will pick it up
 834     SDKROOT="$SYSROOT"
 835     AC_SUBST(SDKROOT)
 836   fi
 837 
 838   # Prepend the extra path to the global path
 839   BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
 840 
 841   AC_MSG_CHECKING([for sysroot])
 842   AC_MSG_RESULT([$SYSROOT])
 843   AC_MSG_CHECKING([for toolchain path])
 844   AC_MSG_RESULT([$TOOLCHAIN_PATH])
 845   AC_MSG_CHECKING([for extra path])
 846   AC_MSG_RESULT([$EXTRA_PATH])
 847 ])
 848 
 849 ###############################################################################
 850 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
 851 [
 852 
 853   AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
 854       [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
 855       [ CONF_NAME=${with_conf_name} ])
 856 
 857   # Test from where we are running configure, in or outside of src root.
 858   AC_MSG_CHECKING([where to store configuration])
 859   if test "x$CURDIR" = "x$TOPDIR" || test "x$CURDIR" = "x$CUSTOM_ROOT" \
 860       || test "x$CURDIR" = "x$TOPDIR/make/autoconf" \
 861       || test "x$CURDIR" = "x$TOPDIR/make" ; then
 862     # We are running configure from the src root.
 863     # Create a default ./build/target-variant-debuglevel output root.
 864     if test "x${CONF_NAME}" = x; then
 865       AC_MSG_RESULT([in default location])
 866       CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JVM_VARIANTS_WITH_AND}-${DEBUG_LEVEL}"
 867     else
 868       AC_MSG_RESULT([in build directory with custom name])
 869     fi
 870 
 871     if test "x$CUSTOM_ROOT" != x; then
 872       OUTPUTDIR="${CUSTOM_ROOT}/build/${CONF_NAME}"
 873     else
 874       OUTPUTDIR="${TOPDIR}/build/${CONF_NAME}"
 875     fi
 876     $MKDIR -p "$OUTPUTDIR"
 877     if test ! -d "$OUTPUTDIR"; then
 878       AC_MSG_ERROR([Could not create build directory $OUTPUTDIR])
 879     fi
 880   else
 881     # We are running configure from outside of the src dir.
 882     # Then use the current directory as output dir!
 883     # If configuration is situated in normal build directory, just use the build
 884     # directory name as configuration name, otherwise use the complete path.
 885     if test "x${CONF_NAME}" = x; then
 886       CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${TOPDIR}/build/!!"`
 887     fi
 888     OUTPUTDIR="$CURDIR"
 889     AC_MSG_RESULT([in current directory])
 890 
 891     # WARNING: This might be a bad thing to do. You need to be sure you want to
 892     # have a configuration in this directory. Do some sanity checks!
 893 
 894     if test ! -e "$OUTPUTDIR/spec.gmk"; then
 895       # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
 896       # other files
 897       files_present=`$LS $OUTPUTDIR`
 898       # Configure has already touched config.log and confdefs.h in the current dir when this check
 899       # is performed.
 900       filtered_files=`$ECHO "$files_present" \
 901           | $SED -e 's/config.log//g' \
 902               -e 's/configure.log//g' \
 903               -e 's/confdefs.h//g' \
 904               -e 's/configure-support//g' \
 905               -e 's/ //g' \
 906           | $TR -d '\n'`
 907       if test "x$filtered_files" != x; then
 908         AC_MSG_NOTICE([Current directory is $CURDIR.])
 909         AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
 910         AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
 911         AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
 912         AC_MSG_NOTICE([seriously mess up just about everything.])
 913         AC_MSG_NOTICE([Try 'cd $TOPDIR' and restart configure])
 914         AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
 915         AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
 916       fi
 917     fi
 918   fi
 919   AC_MSG_CHECKING([what configuration name to use])
 920   AC_MSG_RESULT([$CONF_NAME])
 921 
 922   BASIC_FIXUP_PATH(OUTPUTDIR)
 923 
 924   CONFIGURESUPPORT_OUTPUTDIR="$OUTPUTDIR/configure-support"
 925   $MKDIR -p "$CONFIGURESUPPORT_OUTPUTDIR"
 926 
 927   SPEC="$OUTPUTDIR/spec.gmk"
 928   AC_SUBST(SPEC)
 929   AC_SUBST(CONF_NAME)
 930   AC_SUBST(OUTPUTDIR)
 931   AC_SUBST(CONFIGURESUPPORT_OUTPUTDIR)
 932 
 933   # The spec.gmk file contains all variables for the make system.
 934   AC_CONFIG_FILES([$OUTPUTDIR/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
 935   # The bootcycle-spec.gmk file contains support for boot cycle builds.
 936   AC_CONFIG_FILES([$OUTPUTDIR/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
 937   # The buildjdk-spec.gmk file contains support for building a buildjdk when cross compiling.
 938   AC_CONFIG_FILES([$OUTPUTDIR/buildjdk-spec.gmk:$AUTOCONF_DIR/buildjdk-spec.gmk.in])
 939   # The compare.sh is used to compare the build output to other builds.
 940   AC_CONFIG_FILES([$OUTPUTDIR/compare.sh:$AUTOCONF_DIR/compare.sh.in])
 941   # The generated Makefile knows where the spec.gmk is and where the source is.
 942   # You can run make from the OUTPUTDIR, or from the top-level Makefile
 943   # which will look for generated configurations
 944   AC_CONFIG_FILES([$OUTPUTDIR/Makefile:$AUTOCONF_DIR/Makefile.in])
 945 ])
 946 
 947 #%%% Simple tools %%%
 948 
 949 ###############################################################################
 950 # Check if we have found a usable version of make
 951 # $1: the path to a potential make binary (or empty)
 952 # $2: the description on how we found this
 953 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
 954 [
 955   MAKE_CANDIDATE="$1"
 956   DESCRIPTION="$2"
 957 
 958   # On Cygwin, we require a newer version of make than on other platforms
 959   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 960     MAKE_VERSION_EXPR="-e 4\."
 961     MAKE_REQUIRED_VERSION="4.0"
 962    else
 963     MAKE_VERSION_EXPR="-e 3\.8[[12]] -e 4\."
 964     MAKE_REQUIRED_VERSION="3.81"
 965   fi
 966 
 967   if test "x$MAKE_CANDIDATE" != x; then
 968     AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
 969     MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
 970     IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
 971     if test "x$IS_GNU_MAKE" = x; then
 972       AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
 973     else
 974       IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP $MAKE_VERSION_EXPR`
 975       if test "x$IS_MODERN_MAKE" = x; then
 976         AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version $MAKE_REQUIRED_VERSION or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
 977       else
 978         if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
 979           if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 980             MAKE_EXPECTED_ENV='cygwin'
 981           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 982             MAKE_EXPECTED_ENV='msys'
 983           else
 984             AC_MSG_ERROR([Unknown Windows environment])
 985           fi
 986           MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
 987           IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
 988         else
 989           # Not relevant for non-Windows
 990           IS_MAKE_CORRECT_ENV=true
 991         fi
 992         if test "x$IS_MAKE_CORRECT_ENV" = x; then
 993           AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
 994         else
 995           FOUND_MAKE=$MAKE_CANDIDATE
 996           BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
 997         fi
 998       fi
 999     fi
1000   fi
1001 ])
1002 
1003 ###############################################################################
1004 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],
1005 [
1006   # Check if make supports the output sync option and if so, setup using it.
1007   AC_MSG_CHECKING([if make --output-sync is supported])
1008   if $MAKE --version -O > /dev/null 2>&1; then
1009     OUTPUT_SYNC_SUPPORTED=true
1010     AC_MSG_RESULT([yes])
1011     AC_MSG_CHECKING([for output-sync value])
1012     AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],
1013       [set make output sync type if supported by make. @<:@recurse@:>@])],
1014       [OUTPUT_SYNC=$with_output_sync])
1015     if test "x$OUTPUT_SYNC" = "x"; then
1016       OUTPUT_SYNC=none
1017     fi
1018     AC_MSG_RESULT([$OUTPUT_SYNC])
1019     if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then
1020       AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])
1021     fi
1022   else
1023     OUTPUT_SYNC_SUPPORTED=false
1024     AC_MSG_RESULT([no])
1025   fi
1026   AC_SUBST(OUTPUT_SYNC_SUPPORTED)
1027   AC_SUBST(OUTPUT_SYNC)
1028 ])
1029 
1030 ###############################################################################
1031 # Goes looking for a usable version of GNU make.
1032 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
1033 [
1034   BASIC_SETUP_TOOL([MAKE],
1035   [
1036     # Try our hardest to locate a correct version of GNU make
1037     AC_PATH_PROGS(CHECK_GMAKE, gmake)
1038     BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
1039 
1040     if test "x$FOUND_MAKE" = x; then
1041       AC_PATH_PROGS(CHECK_MAKE, make)
1042       BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
1043     fi
1044 
1045     if test "x$FOUND_MAKE" = x; then
1046       if test "x$TOOLCHAIN_PATH" != x; then
1047         # We have a toolchain path, check that as well before giving up.
1048         OLD_PATH=$PATH
1049         PATH=$TOOLCHAIN_PATH:$PATH
1050         AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
1051         BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
1052         if test "x$FOUND_MAKE" = x; then
1053           AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
1054           BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
1055         fi
1056         PATH=$OLD_PATH
1057       fi
1058     fi
1059 
1060     if test "x$FOUND_MAKE" = x; then
1061       AC_MSG_ERROR([Cannot find GNU make $MAKE_REQUIRED_VERSION or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
1062     fi
1063   ],[
1064     # If MAKE was set by user, verify the version
1065     BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
1066     if test "x$FOUND_MAKE" = x; then
1067       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make $MAKE_REQUIRED_VERSION or newer.])
1068     fi
1069   ])
1070 
1071   MAKE=$FOUND_MAKE
1072   AC_SUBST(MAKE)
1073   AC_MSG_NOTICE([Using GNU make at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
1074 
1075   BASIC_CHECK_MAKE_OUTPUT_SYNC
1076 ])
1077 
1078 ###############################################################################
1079 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
1080 [
1081   # Test if find supports -delete
1082   AC_MSG_CHECKING([if find supports -delete])
1083   FIND_DELETE="-delete"
1084 
1085   DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
1086 
1087   echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
1088 
1089   TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
1090   if test -f $DELETEDIR/TestIfFindSupportsDelete; then
1091     # No, it does not.
1092     $RM $DELETEDIR/TestIfFindSupportsDelete
1093     if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1094       # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list
1095       FIND_DELETE="-print | $XARGS $RM"
1096     else
1097       FIND_DELETE="-exec $RM \{\} \+"
1098     fi
1099     AC_MSG_RESULT([no])
1100   else
1101     AC_MSG_RESULT([yes])
1102   fi
1103   $RMDIR $DELETEDIR
1104   AC_SUBST(FIND_DELETE)
1105 ])
1106 
1107 ###############################################################################
1108 AC_DEFUN([BASIC_CHECK_TAR],
1109 [
1110   # Test which kind of tar was found
1111   if test "x$($TAR --version | $GREP "GNU tar")" != "x"; then
1112     TAR_TYPE="gnu"
1113   elif test "x$($TAR --version | $GREP "bsdtar")" != "x"; then
1114     TAR_TYPE="bsd"
1115   elif test "x$($TAR -v | $GREP "bsdtar")" != "x"; then
1116     TAR_TYPE="bsd"
1117   elif test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
1118     TAR_TYPE="solaris"
1119   fi
1120   AC_MSG_CHECKING([what type of tar was found])
1121   AC_MSG_RESULT([$TAR_TYPE])
1122 
1123   TAR_CREATE_FILE_PARAM=""
1124 
1125   if test "x$TAR_TYPE" = "xgnu"; then
1126     TAR_INCLUDE_PARAM="T"
1127     TAR_SUPPORTS_TRANSFORM="true"
1128     if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
1129       # When using gnu tar for Solaris targets, need to use compatibility mode
1130       TAR_CREATE_EXTRA_PARAM="--format=ustar"
1131     fi
1132   else
1133     TAR_INCLUDE_PARAM="I"
1134     TAR_SUPPORTS_TRANSFORM="false"
1135   fi
1136   AC_SUBST(TAR_TYPE)
1137   AC_SUBST(TAR_CREATE_EXTRA_PARAM)
1138   AC_SUBST(TAR_INCLUDE_PARAM)
1139   AC_SUBST(TAR_SUPPORTS_TRANSFORM)
1140 ])
1141 
1142 ###############################################################################
1143 AC_DEFUN([BASIC_CHECK_GREP],
1144 [
1145   # Test that grep supports -Fx with a list of pattern which includes null pattern.
1146   # This is a problem for the grep resident on AIX.
1147   AC_MSG_CHECKING([that grep ($GREP) -Fx handles empty lines in the pattern list correctly])
1148   # Multiple subsequent spaces..
1149   STACK_SPACES='aaa   bbb   ccc'
1150   # ..converted to subsequent newlines, causes STACK_LIST to be a list with some empty
1151   # patterns in it.
1152   STACK_LIST=${STACK_SPACES// /$'\n'}
1153   NEEDLE_SPACES='ccc bbb aaa'
1154   NEEDLE_LIST=${NEEDLE_SPACES// /$'\n'}
1155   RESULT="$($GREP -Fvx "$STACK_LIST" <<< "$NEEDLE_LIST")"
1156   if test "x$RESULT" == "x"; then
1157     AC_MSG_RESULT([yes])
1158   else
1159     if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1160       ADDINFO="Please make sure you use GNU grep, usually found at /opt/freeware/bin."
1161     fi
1162     AC_MSG_ERROR([grep does not handle -Fx correctly. ${ADDINFO}])
1163   fi
1164 ])
1165 
1166 ###############################################################################
1167 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
1168 [
1169   BASIC_CHECK_GNU_MAKE
1170 
1171   BASIC_CHECK_FIND_DELETE
1172   BASIC_CHECK_TAR
1173   BASIC_CHECK_GREP
1174 
1175   # These tools might not be installed by default,
1176   # need hint on how to install them.
1177   BASIC_REQUIRE_PROGS(UNZIP, unzip)
1178   # Since zip uses "ZIP" as a environment variable for passing options, we need
1179   # to name our variable differently, hence ZIPEXE.
1180   BASIC_REQUIRE_PROGS(ZIPEXE, zip)
1181 
1182   # Non-required basic tools
1183 
1184   BASIC_PATH_PROGS(LDD, ldd)
1185   if test "x$LDD" = "x"; then
1186     # List shared lib dependencies is used for
1187     # debug output and checking for forbidden dependencies.
1188     # We can build without it.
1189     LDD="true"
1190   fi
1191   BASIC_PATH_PROGS(READELF, [greadelf readelf])
1192   BASIC_PATH_PROGS(DOT, dot)
1193   BASIC_PATH_PROGS(HG, hg)
1194   BASIC_PATH_PROGS(GIT, git)
1195   BASIC_PATH_PROGS(STAT, stat)
1196   BASIC_PATH_PROGS(TIME, time)
1197   BASIC_PATH_PROGS(FLOCK, flock)
1198   # Dtrace is usually found in /usr/sbin on Solaris, but that directory may not
1199   # be in the user path.
1200   BASIC_PATH_PROGS(DTRACE, dtrace, $PATH:/usr/sbin)
1201   BASIC_PATH_PROGS(PATCH, [gpatch patch])
1202   # Check if it's GNU time
1203   IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
1204   if test "x$IS_GNU_TIME" != x; then
1205     IS_GNU_TIME=yes
1206   else
1207     IS_GNU_TIME=no
1208   fi
1209   AC_SUBST(IS_GNU_TIME)
1210 
1211   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
1212     BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
1213     BASIC_REQUIRE_PROGS(MIG, mig)
1214     BASIC_REQUIRE_PROGS(XATTR, xattr)
1215     BASIC_PATH_PROGS(CODESIGN, codesign)
1216     if test "x$CODESIGN" != "x"; then
1217       # Verify that the openjdk_codesign certificate is present
1218       AC_MSG_CHECKING([if openjdk_codesign certificate is present])
1219       $RM codesign-testfile
1220       $TOUCH codesign-testfile
1221       $CODESIGN -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
1222       $RM codesign-testfile
1223       if test "x$CODESIGN" = x; then
1224         AC_MSG_RESULT([no])
1225       else
1226         AC_MSG_RESULT([yes])
1227       fi
1228     fi
1229     BASIC_REQUIRE_PROGS(SETFILE, SetFile)
1230   elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
1231     BASIC_REQUIRE_PROGS(ELFEDIT, elfedit)
1232   fi
1233 ])
1234 
1235 ###############################################################################
1236 # Check if build directory is on local disk. If not possible to determine,
1237 # we prefer to claim it's local.
1238 # Argument 1: directory to test
1239 # Argument 2: what to do if it is on local disk
1240 # Argument 3: what to do otherwise (remote disk or failure)
1241 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
1242 [
1243   # df -l lists only local disks; if the given directory is not found then
1244   # a non-zero exit code is given
1245   if test "x$DF" = x; then
1246     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
1247       # msys does not have df; use Windows "net use" instead.
1248       IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
1249       if test "x$IS_NETWORK_DISK" = x; then
1250         $2
1251       else
1252         $3
1253       fi
1254     else
1255       # No df here, say it's local
1256       $2
1257     fi
1258   else
1259     # JDK-8189619
1260     # df on AIX does not understand -l. On modern AIXes it understands "-T local" which
1261     # is the same. On older AIXes we just continue to live with a "not local build" warning.
1262     if test "x$OPENJDK_TARGET_OS" = xaix; then
1263       DF_LOCAL_ONLY_OPTION='-T local'
1264     else
1265       DF_LOCAL_ONLY_OPTION='-l'
1266     fi
1267     if $DF $DF_LOCAL_ONLY_OPTION $1 > /dev/null 2>&1; then
1268       $2
1269     else
1270       $3
1271     fi
1272   fi
1273 ])
1274 
1275 ###############################################################################
1276 # Check that source files have basic read permissions set. This might
1277 # not be the case in cygwin in certain conditions.
1278 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
1279 [
1280   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
1281     file_to_test="$TOPDIR/LICENSE"
1282     if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
1283       AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
1284     fi
1285   fi
1286 ])
1287 
1288 ###############################################################################
1289 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
1290 [
1291   AC_MSG_CHECKING([if build directory is on local disk])
1292   BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUTDIR,
1293       [OUTPUT_DIR_IS_LOCAL="yes"],
1294       [OUTPUT_DIR_IS_LOCAL="no"])
1295   AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
1296 
1297   BASIC_CHECK_SRC_PERMS
1298 
1299   # Check if the user has any old-style ALT_ variables set.
1300   FOUND_ALT_VARIABLES=`env | grep ^ALT_`
1301 
1302   # Before generating output files, test if they exist. If they do, this is a reconfigure.
1303   # Since we can't properly handle the dependencies for this, warn the user about the situation
1304   if test -e $OUTPUTDIR/spec.gmk; then
1305     IS_RECONFIGURE=yes
1306   else
1307     IS_RECONFIGURE=no
1308   fi
1309 ])
1310 
1311 ###############################################################################
1312 # Check for support for specific options in bash
1313 AC_DEFUN_ONCE([BASIC_CHECK_BASH_OPTIONS],
1314 [
1315   # Check bash version
1316   # Extra [ ] to stop m4 mangling
1317   [ BASH_VER=`$BASH --version | $SED -n  -e 's/^.*bash.*ersion *\([0-9.]*\).*$/\1/ p'` ]
1318   AC_MSG_CHECKING([bash version])
1319   AC_MSG_RESULT([$BASH_VER])
1320 
1321   BASH_MAJOR=`$ECHO $BASH_VER | $CUT -d . -f 1`
1322   BASH_MINOR=`$ECHO $BASH_VER | $CUT -d . -f 2`
1323   if test $BASH_MAJOR -lt 3 || (test $BASH_MAJOR -eq 3 && test $BASH_MINOR -lt 2); then
1324     AC_MSG_ERROR([bash version 3.2 or better is required])
1325   fi
1326 
1327   # Test if bash supports pipefail.
1328   AC_MSG_CHECKING([if bash supports pipefail])
1329   if ${BASH} -c 'set -o pipefail'; then
1330     BASH_ARGS="$BASH_ARGS -o pipefail"
1331     AC_MSG_RESULT([yes])
1332   else
1333     AC_MSG_RESULT([no])
1334   fi
1335 
1336   AC_MSG_CHECKING([if bash supports errexit (-e)])
1337   if ${BASH} -e -c 'true'; then
1338     BASH_ARGS="$BASH_ARGS -e"
1339     AC_MSG_RESULT([yes])
1340   else
1341     AC_MSG_RESULT([no])
1342   fi
1343 
1344   AC_SUBST(BASH_ARGS)
1345 ])
1346 
1347 ################################################################################
1348 #
1349 # Default make target
1350 #
1351 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_MAKE_TARGET],
1352 [
1353   AC_ARG_WITH(default-make-target, [AS_HELP_STRING([--with-default-make-target],
1354       [set the default make target @<:@exploded-image@:>@])])
1355   if test "x$with_default_make_target" = "x" \
1356       || test "x$with_default_make_target" = "xyes"; then
1357     DEFAULT_MAKE_TARGET="exploded-image"
1358   elif test "x$with_default_make_target" = "xno"; then
1359     AC_MSG_ERROR([--without-default-make-target is not a valid option])
1360   else
1361     DEFAULT_MAKE_TARGET="$with_default_make_target"
1362   fi
1363 
1364   AC_SUBST(DEFAULT_MAKE_TARGET)
1365 ])
1366 
1367 ###############################################################################
1368 # Setup the default value for LOG=
1369 #
1370 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_LOG],
1371 [
1372   AC_ARG_WITH(log, [AS_HELP_STRING([--with-log],
1373       [[default vaue for make LOG argument [warn]]])])
1374   AC_MSG_CHECKING([for default LOG value])
1375   if test "x$with_log" = x; then
1376     DEFAULT_LOG=""
1377   else
1378     # Syntax for valid LOG options is a bit too complex for it to be worth
1379     # implementing a test for correctness in configure. Just accept it.
1380     DEFAULT_LOG=$with_log
1381   fi
1382   AC_MSG_RESULT([$DEFAULT_LOG])
1383   AC_SUBST(DEFAULT_LOG)
1384 ])
1385 
1386 ###############################################################################
1387 # Code to run after AC_OUTPUT
1388 AC_DEFUN_ONCE([BASIC_POST_CONFIG_OUTPUT],
1389 [
1390   # Try to move config.log (generated by autoconf) to the configure-support directory.
1391   if test -e ./config.log; then
1392     $MV -f ./config.log "$CONFIGURESUPPORT_OUTPUTDIR/config.log" 2> /dev/null
1393   fi
1394 
1395   # Rotate our log file (configure.log)
1396   if test -e "$OUTPUTDIR/configure.log.old"; then
1397     $RM -f "$OUTPUTDIR/configure.log.old"
1398   fi
1399   if test -e "$OUTPUTDIR/configure.log"; then
1400     $MV -f "$OUTPUTDIR/configure.log" "$OUTPUTDIR/configure.log.old" 2> /dev/null
1401   fi
1402 
1403   # Move configure.log from current directory to the build output root
1404   if test -e ./configure.log; then
1405     $MV -f ./configure.log "$OUTPUTDIR/configure.log" 2> /dev/null
1406   fi
1407 
1408   # Make the compare script executable
1409   $CHMOD +x $OUTPUTDIR/compare.sh
1410 ])