1 #
   2 # Copyright (c) 2011, 2019, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 AC_DEFUN([BPERF_CHECK_CORES],
  27 [
  28   AC_MSG_CHECKING([for number of cores])
  29   NUM_CORES=1
  30   FOUND_CORES=no
  31 
  32   if test -f /proc/cpuinfo; then
  33     # Looks like a Linux (or cygwin) system
  34     NUM_CORES=`cat /proc/cpuinfo  | grep -c processor`
  35     FOUND_CORES=yes
  36   elif test -x /usr/sbin/psrinfo; then
  37     # Looks like a Solaris system
  38     NUM_CORES=`LC_MESSAGES=C /usr/sbin/psrinfo -v | grep -c on-line`
  39     FOUND_CORES=yes
  40   elif test -x /usr/sbin/sysctl; then
  41     # Looks like a MacOSX system
  42     NUM_CORES=`/usr/sbin/sysctl -n hw.ncpu`
  43     FOUND_CORES=yes
  44   elif test "x$OPENJDK_BUILD_OS" = xaix ; then
  45     NUM_LCPU=`lparstat -m 2> /dev/null | $GREP -o "lcpu=[[0-9]]*" | $CUT -d "=" -f 2`
  46     if test -n "$NUM_LCPU"; then
  47       NUM_CORES=$NUM_LCPU
  48       FOUND_CORES=yes
  49     fi
  50   elif test -n "$NUMBER_OF_PROCESSORS"; then
  51     # On windows, look in the env
  52     NUM_CORES=$NUMBER_OF_PROCESSORS
  53     FOUND_CORES=yes
  54   fi
  55 
  56   if test "x$FOUND_CORES" = xyes; then
  57     AC_MSG_RESULT([$NUM_CORES])
  58   else
  59     AC_MSG_RESULT([could not detect number of cores, defaulting to 1])
  60     AC_MSG_WARN([This will disable all parallelism from build!])
  61   fi
  62 ])
  63 
  64 AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],
  65 [
  66   AC_MSG_CHECKING([for memory size])
  67   # Default to 1024 MB
  68   MEMORY_SIZE=1024
  69   FOUND_MEM=no
  70 
  71   if test -f /proc/meminfo; then
  72     # Looks like a Linux (or cygwin) system
  73     MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`
  74     MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`
  75     FOUND_MEM=yes
  76   elif test -x /usr/sbin/prtconf; then
  77     # Looks like a Solaris or AIX system
  78     MEMORY_SIZE=`/usr/sbin/prtconf 2> /dev/null | grep "^Memory [[Ss]]ize" | awk '{ print [$]3 }'`
  79     FOUND_MEM=yes
  80   elif test -x /usr/sbin/sysctl; then
  81     # Looks like a MacOSX system
  82     MEMORY_SIZE=`/usr/sbin/sysctl -n hw.memsize`
  83     MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
  84     FOUND_MEM=yes
  85   elif test "x$OPENJDK_BUILD_OS" = xwindows; then
  86     # Windows, but without cygwin
  87     MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`
  88     MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
  89     FOUND_MEM=yes
  90   fi
  91 
  92   if test "x$FOUND_MEM" = xyes; then
  93     AC_MSG_RESULT([$MEMORY_SIZE MB])
  94   else
  95     AC_MSG_RESULT([could not detect memory size, defaulting to $MEMORY_SIZE MB])
  96     AC_MSG_WARN([This might seriously impact build performance!])
  97   fi
  98 ])
  99 
 100 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],
 101 [
 102   # How many cores do we have on this build system?
 103   AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],
 104       [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])
 105   if test "x$with_num_cores" = x; then
 106     # The number of cores were not specified, try to probe them.
 107     BPERF_CHECK_CORES
 108   else
 109     NUM_CORES=$with_num_cores
 110   fi
 111   AC_SUBST(NUM_CORES)
 112 ])
 113 
 114 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],
 115 [
 116   # How much memory do we have on this build system?
 117   AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],
 118       [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])
 119   if test "x$with_memory_size" = x; then
 120     # The memory size was not specified, try to probe it.
 121     BPERF_CHECK_MEMORY_SIZE
 122   else
 123     MEMORY_SIZE=$with_memory_size
 124   fi
 125   AC_SUBST(MEMORY_SIZE)
 126 ])
 127 
 128 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],
 129 [
 130   # Provide a decent default number of parallel jobs for make depending on
 131   # number of cores, amount of memory and machine architecture.
 132   AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],
 133       [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])
 134   if test "x$with_jobs" = x; then
 135     # Number of jobs was not specified, calculate.
 136     AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])
 137     # Approximate memory in GB.
 138     memory_gb=`expr $MEMORY_SIZE / 1024`
 139     # Pick the lowest of memory in gb and number of cores.
 140     if test "$memory_gb" -lt "$NUM_CORES"; then
 141       JOBS="$memory_gb"
 142     else
 143       JOBS="$NUM_CORES"
 144     fi
 145     if test "$JOBS" -eq "0"; then
 146       JOBS=1
 147     fi
 148     AC_MSG_RESULT([$JOBS])
 149   else
 150     JOBS=$with_jobs
 151   fi
 152   AC_SUBST(JOBS)
 153 ])
 154 
 155 AC_DEFUN_ONCE([BPERF_SETUP_TEST_JOBS],
 156 [
 157   # The number of test jobs will be chosen automatically if TEST_JOBS is 0
 158   AC_ARG_WITH(test-jobs, [AS_HELP_STRING([--with-test-jobs],
 159       [number of parallel tests jobs to run @<:@based on build jobs@:>@])])
 160   if test "x$with_test_jobs" = x; then
 161       TEST_JOBS=0
 162   else
 163       TEST_JOBS=$with_test_jobs
 164   fi
 165   AC_SUBST(TEST_JOBS)
 166 ])
 167 
 168 AC_DEFUN([BPERF_SETUP_CCACHE],
 169 [
 170   AC_ARG_ENABLE([ccache],
 171       [AS_HELP_STRING([--enable-ccache],
 172       [enable using ccache to speed up recompilations @<:@disabled@:>@])])
 173 
 174   CCACHE_STATUS=
 175   AC_MSG_CHECKING([is ccache enabled])
 176   if test "x$enable_ccache" = xyes; then
 177     if test "x$TOOLCHAIN_TYPE" = "xgcc" -o "x$TOOLCHAIN_TYPE" = "xclang"; then
 178       AC_MSG_RESULT([yes])
 179       OLD_PATH="$PATH"
 180       if test "x$TOOLCHAIN_PATH" != x; then
 181         PATH=$TOOLCHAIN_PATH:$PATH
 182       fi
 183       BASIC_REQUIRE_PROGS(CCACHE, ccache)
 184       PATH="$OLD_PATH"
 185       CCACHE_VERSION=[`$CCACHE --version | head -n1 | $SED 's/[A-Za-z ]*//'`]
 186       CCACHE_STATUS="Active ($CCACHE_VERSION)"
 187     else
 188       AC_MSG_RESULT([no])
 189       AC_MSG_WARN([ccache is not supported with toolchain type $TOOLCHAIN_TYPE])
 190     fi
 191   elif test "x$enable_ccache" = xno; then
 192     AC_MSG_RESULT([no, explicitly disabled])
 193     CCACHE_STATUS="Disabled"
 194   elif test "x$enable_ccache" = x; then
 195     AC_MSG_RESULT([no])
 196   else
 197     AC_MSG_RESULT([unknown])
 198     AC_MSG_ERROR([--enable-ccache does not accept any parameters])
 199   fi
 200   AC_SUBST(CCACHE)
 201 
 202   AC_ARG_WITH([ccache-dir],
 203       [AS_HELP_STRING([--with-ccache-dir],
 204       [where to store ccache files @<:@~/.ccache@:>@])])
 205 
 206   if test "x$with_ccache_dir" != x; then
 207     # When using a non home ccache directory, assume the use is to share ccache files
 208     # with other users. Thus change the umask.
 209     SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"
 210     if test "x$CCACHE" = x; then
 211       AC_MSG_WARN([--with-ccache-dir has no meaning when ccache is not enabled])
 212     fi
 213   fi
 214 
 215   if test "x$CCACHE" != x; then
 216     BPERF_SETUP_CCACHE_USAGE
 217   fi
 218 ])
 219 
 220 AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],
 221 [
 222   if test "x$CCACHE" != x; then
 223     if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
 224       HAS_BAD_CCACHE=[`$ECHO $CCACHE_VERSION | \
 225           $GREP -e '^1\.' -e '^2\.' -e '^3\.0\.' -e '^3\.1\.'`]
 226       if test "x$HAS_BAD_CCACHE" != "x"; then
 227         AC_MSG_ERROR([On macosx, ccache 3.2 or later is required, found $CCACHE_VERSION])
 228       fi
 229     fi
 230     if test "x$USE_PRECOMPILED_HEADER" = "xtrue"; then
 231       HAS_BAD_CCACHE=[`$ECHO $CCACHE_VERSION | \
 232           $GREP -e '^1.*' -e '^2.*' -e '^3\.0.*' -e '^3\.1\.[0123]$'`]
 233       if test "x$HAS_BAD_CCACHE" != "x"; then
 234         AC_MSG_ERROR([Precompiled headers requires ccache 3.1.4 or later, found $CCACHE_VERSION])
 235       fi
 236       AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])
 237       CCACHE_PRECOMP_FLAG="-fpch-preprocess"
 238       PUSHED_FLAGS="$CXXFLAGS"
 239       CXXFLAGS="$CCACHE_PRECOMP_FLAG $CXXFLAGS"
 240       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])
 241       CXXFLAGS="$PUSHED_FLAGS"
 242       if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then
 243         AC_MSG_RESULT([yes])
 244         CFLAGS_CCACHE="$CCACHE_PRECOMP_FLAG"
 245         AC_SUBST(CFLAGS_CCACHE)
 246         CCACHE_SLOPPINESS=pch_defines,time_macros
 247       else
 248         AC_MSG_RESULT([no])
 249         AC_MSG_ERROR([Cannot use ccache with precompiled headers without compiler support for $CCACHE_PRECOMP_FLAG])
 250       fi
 251     fi
 252 
 253     CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR \
 254         CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS CCACHE_BASEDIR=$TOPDIR $CCACHE"
 255 
 256     if test "x$SET_CCACHE_DIR" != x; then
 257       mkdir -p $CCACHE_DIR > /dev/null 2>&1
 258       chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1
 259     fi
 260   fi
 261 ])
 262 
 263 ################################################################################
 264 #
 265 # Runs icecc-create-env once and prints the error if it fails
 266 #
 267 # $1: arguments to icecc-create-env
 268 # $2: log file
 269 #
 270 AC_DEFUN([BPERF_RUN_ICECC_CREATE_ENV],
 271 [
 272   ( cd ${CONFIGURESUPPORT_OUTPUTDIR}/icecc \
 273       && ${ICECC_CREATE_ENV} $1 > $2 2>&1 )
 274   if test "$?" != "0"; then
 275     AC_MSG_NOTICE([icecc-create-env output:])
 276     cat $2
 277     AC_MSG_ERROR([Failed to create icecc compiler environment])
 278   fi
 279 ])
 280 
 281 ################################################################################
 282 #
 283 # Optionally enable distributed compilation of native code using icecc/icecream
 284 #
 285 AC_DEFUN([BPERF_SETUP_ICECC],
 286 [
 287   AC_ARG_ENABLE([icecc], [AS_HELP_STRING([--enable-icecc],
 288       [enable distribted compilation of native code using icecc/icecream @<:@disabled@:>@])])
 289 
 290   if test "x${enable_icecc}" = "xyes"; then
 291     BASIC_REQUIRE_PROGS(ICECC_CMD, icecc)
 292     old_path="$PATH"
 293 
 294     # Look for icecc-create-env in some known places
 295     PATH="$PATH:/usr/lib/icecc:/usr/lib64/icecc"
 296     BASIC_REQUIRE_PROGS(ICECC_CREATE_ENV, icecc-create-env)
 297     # Use icecc-create-env to create a minimal compilation environment that can
 298     # be sent to the other hosts in the icecream cluster.
 299     icecc_create_env_log="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/icecc_create_env.log"
 300     ${MKDIR} -p ${CONFIGURESUPPORT_OUTPUTDIR}/icecc
 301     # Older versions of icecc does not have the --gcc parameter
 302     if ${ICECC_CREATE_ENV} | $GREP -q -e --gcc; then
 303       icecc_gcc_arg="--gcc"
 304     fi
 305     if test "x${TOOLCHAIN_TYPE}" = "xgcc"; then
 306       BPERF_RUN_ICECC_CREATE_ENV([${icecc_gcc_arg} ${CC} ${CXX}], \
 307           ${icecc_create_env_log})
 308     elif test "x$TOOLCHAIN_TYPE" = "xclang"; then
 309       # For clang, the icecc compilerwrapper is needed. It usually resides next
 310       # to icecc-create-env.
 311       BASIC_REQUIRE_PROGS(ICECC_WRAPPER, compilerwrapper)
 312       BPERF_RUN_ICECC_CREATE_ENV([--clang ${CC} ${ICECC_WRAPPER}], ${icecc_create_env_log})
 313     else
 314       AC_MSG_ERROR([Can only create icecc compiler packages for toolchain types gcc and clang])
 315     fi
 316     PATH="$old_path"
 317     # The bundle with the compiler gets a name based on checksums. Parse log file
 318     # to find it.
 319     ICECC_ENV_BUNDLE_BASENAME="`${SED} -n '/^creating/s/creating //p' ${icecc_create_env_log}`"
 320     ICECC_ENV_BUNDLE="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/${ICECC_ENV_BUNDLE_BASENAME}"
 321     if test ! -f ${ICECC_ENV_BUNDLE}; then
 322       AC_MSG_ERROR([icecc-create-env did not produce an environment ${ICECC_ENV_BUNDLE}])
 323     fi
 324     AC_MSG_CHECKING([for icecc build environment for target compiler])
 325     AC_MSG_RESULT([${ICECC_ENV_BUNDLE}])
 326     ICECC="ICECC_VERSION=${ICECC_ENV_BUNDLE} ICECC_CC=${CC} ICECC_CXX=${CXX} ${ICECC_CMD}"
 327 
 328     if test "x${COMPILE_TYPE}" = "xcross"; then
 329       # If cross compiling, create a separate env package for the build compiler
 330       # Assume "gcc" or "cc" is gcc and "clang" is clang. Otherwise bail.
 331       icecc_create_env_log_build="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/icecc_create_env_build.log"
 332       if test "x${BUILD_CC##*/}" = "xgcc" ||  test "x${BUILD_CC##*/}" = "xcc"; then
 333         BPERF_RUN_ICECC_CREATE_ENV([${icecc_gcc_arg} ${BUILD_CC} ${BUILD_CXX}], \
 334             ${icecc_create_env_log_build})
 335       elif test "x${BUILD_CC##*/}" = "xclang"; then
 336         BPERF_RUN_ICECC_CREATE_ENV([--clang ${BUILD_CC} ${ICECC_WRAPPER}], ${icecc_create_env_log_build})
 337       else
 338         AC_MSG_ERROR([Cannot create icecc compiler package for ${BUILD_CC}])
 339       fi
 340       ICECC_ENV_BUNDLE_BASENAME="`${SED} -n '/^creating/s/creating //p' ${icecc_create_env_log_build}`"
 341       ICECC_ENV_BUNDLE="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/${ICECC_ENV_BUNDLE_BASENAME}"
 342       if test ! -f ${ICECC_ENV_BUNDLE}; then
 343         AC_MSG_ERROR([icecc-create-env did not produce an environment ${ICECC_ENV_BUNDLE}])
 344       fi
 345       AC_MSG_CHECKING([for icecc build environment for build compiler])
 346       AC_MSG_RESULT([${ICECC_ENV_BUNDLE}])
 347       BUILD_ICECC="ICECC_VERSION=${ICECC_ENV_BUNDLE} ICECC_CC=${BUILD_CC} \
 348           ICECC_CXX=${BUILD_CXX} ${ICECC_CMD}"
 349     else
 350       BUILD_ICECC="${ICECC}"
 351     fi
 352     AC_SUBST(ICECC)
 353     AC_SUBST(BUILD_ICECC)
 354   fi
 355 ])
 356 
 357 AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],
 358 [
 359 
 360   ###############################################################################
 361   #
 362   # Can the C/C++ compiler use precompiled headers?
 363   #
 364   AC_ARG_ENABLE([precompiled-headers], [AS_HELP_STRING([--disable-precompiled-headers],
 365       [disable using precompiled headers when compiling C++ @<:@enabled@:>@])],
 366       [ENABLE_PRECOMPH=${enable_precompiled_headers}], [ENABLE_PRECOMPH=yes])
 367 
 368   USE_PRECOMPILED_HEADER=true
 369   AC_MSG_CHECKING([If precompiled header is enabled])
 370   if test "x$ENABLE_PRECOMPH" = xno; then
 371     AC_MSG_RESULT([no, forced])
 372     USE_PRECOMPILED_HEADER=false
 373   elif test "x$ICECC" != "x"; then
 374     AC_MSG_RESULT([no, does not work effectively with icecc])
 375     USE_PRECOMPILED_HEADER=false
 376   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 377     AC_MSG_RESULT([no, does not work with Solaris Studio])
 378     USE_PRECOMPILED_HEADER=false
 379   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 380     AC_MSG_RESULT([no, does not work with xlc])
 381     USE_PRECOMPILED_HEADER=false
 382   else
 383     AC_MSG_RESULT([yes])
 384   fi
 385 
 386   if test "x$ENABLE_PRECOMPH" = xyes; then
 387     # Check that the compiler actually supports precomp headers.
 388     if test "x$TOOLCHAIN_TYPE" = xgcc; then
 389       AC_MSG_CHECKING([that precompiled headers work])
 390       echo "int alfa();" > conftest.h
 391       $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 392       if test ! -f conftest.hpp.gch; then
 393         USE_PRECOMPILED_HEADER=false
 394         AC_MSG_RESULT([no])
 395       else
 396         AC_MSG_RESULT([yes])
 397       fi
 398       $RM conftest.h conftest.hpp.gch
 399     fi
 400   fi
 401 
 402   AC_SUBST(USE_PRECOMPILED_HEADER)
 403 ])
 404 
 405 
 406 AC_DEFUN_ONCE([BPERF_SETUP_SMART_JAVAC],
 407 [
 408   AC_ARG_WITH(sjavac-server-java, [AS_HELP_STRING([--with-sjavac-server-java],
 409       [use this java binary for running the sjavac background server @<:@Boot JDK java@:>@])])
 410 
 411   if test "x$with_sjavac_server_java" != x; then
 412     SJAVAC_SERVER_JAVA="$with_sjavac_server_java"
 413     FOUND_VERSION=`$SJAVAC_SERVER_JAVA -version 2>&1 | grep " version \""`
 414     if test "x$FOUND_VERSION" = x; then
 415       AC_MSG_ERROR([Could not execute server java: $SJAVAC_SERVER_JAVA])
 416     fi
 417   else
 418     SJAVAC_SERVER_JAVA="$JAVA"
 419   fi
 420   AC_SUBST(SJAVAC_SERVER_JAVA)
 421 
 422   if test "$MEMORY_SIZE" -gt "3000"; then
 423     if "$JAVA" -version 2>&1 | $GREP -q "64-Bit"; then
 424       JVM_64BIT=true
 425     fi
 426   fi
 427 
 428   MX_VALUE=`expr $MEMORY_SIZE / 2`
 429   if test "$JVM_64BIT" = true; then
 430     # Set ms lower than mx since more than one instance of the server might
 431     # get launched at the same time before they figure out which instance won.
 432     MS_VALUE=512
 433     if test "$MX_VALUE" -gt "2048"; then
 434       MX_VALUE=2048
 435     fi
 436   else
 437     MS_VALUE=256
 438     if test "$MX_VALUE" -gt "1500"; then
 439       MX_VALUE=1500
 440     fi
 441   fi
 442   if test "$MX_VALUE" -lt "512"; then
 443     MX_VALUE=512
 444   fi
 445   ADD_JVM_ARG_IF_OK([-Xms${MS_VALUE}M -Xmx${MX_VALUE}M],SJAVAC_SERVER_JAVA_FLAGS,[$SJAVAC_SERVER_JAVA])
 446   AC_SUBST(SJAVAC_SERVER_JAVA_FLAGS)
 447 
 448   AC_ARG_ENABLE([sjavac], [AS_HELP_STRING([--enable-sjavac],
 449       [use sjavac to do fast incremental compiles @<:@disabled@:>@])],
 450       [ENABLE_SJAVAC="${enableval}"], [ENABLE_SJAVAC="no"])
 451   if test "x$JVM_ARG_OK" = "xfalse"; then
 452     AC_MSG_WARN([Could not set -Xms${MS_VALUE}M -Xmx${MX_VALUE}M, disabling sjavac])
 453     ENABLE_SJAVAC="no"
 454   fi
 455   AC_MSG_CHECKING([whether to use sjavac])
 456   AC_MSG_RESULT([$ENABLE_SJAVAC])
 457   AC_SUBST(ENABLE_SJAVAC)
 458 
 459   AC_ARG_ENABLE([javac-server], [AS_HELP_STRING([--disable-javac-server],
 460       [disable javac server @<:@enabled@:>@])],
 461       [ENABLE_JAVAC_SERVER="${enableval}"], [ENABLE_JAVAC_SERVER="yes"])
 462   if test "x$JVM_ARG_OK" = "xfalse"; then
 463     AC_MSG_WARN([Could not set -Xms${MS_VALUE}M -Xmx${MX_VALUE}M, disabling javac server])
 464     ENABLE_JAVAC_SERVER="no"
 465   fi
 466   AC_MSG_CHECKING([whether to use javac server])
 467   AC_MSG_RESULT([$ENABLE_JAVAC_SERVER])
 468   AC_SUBST(ENABLE_JAVAC_SERVER)
 469 
 470   if test "x$ENABLE_JAVAC_SERVER" = "xyes" || test "x$ENABLE_SJAVAC" = "xyes"; then
 471     # When using a server javac, the small client instances do not need much
 472     # resources.
 473     JAVA_FLAGS_JAVAC="$JAVA_FLAGS_SMALL"
 474   fi
 475 ])