1 #
   2 # Copyright (c) 2011, 2019, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],
  27 [
  28   ###############################################################################
  29   #
  30   # Check which variant of the JDK that we want to build.
  31   # Currently we have:
  32   #    normal:   standard edition
  33   # but the custom make system may add other variants
  34   #
  35   # Effectively the JDK variant gives a name to a specific set of
  36   # modules to compile into the JDK. In the future, these modules
  37   # might even be Jigsaw modules.
  38   #
  39   AC_MSG_CHECKING([which variant of the JDK to build])
  40   AC_ARG_WITH([jdk-variant], [AS_HELP_STRING([--with-jdk-variant],
  41       [JDK variant to build (normal) @<:@normal@:>@])])
  42 
  43   if test "x$with_jdk_variant" = xnormal || test "x$with_jdk_variant" = x; then
  44     JDK_VARIANT="normal"
  45   else
  46     AC_MSG_ERROR([The available JDK variants are: normal])
  47   fi
  48 
  49   AC_SUBST(JDK_VARIANT)
  50 
  51   AC_MSG_RESULT([$JDK_VARIANT])
  52 ])
  53 
  54 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_INTERPRETER],
  55 [
  56 ###############################################################################
  57 #
  58 # Check which interpreter of the JVM we want to build.
  59 # Currently we have:
  60 #    template: Template interpreter (the default)
  61 #    cpp     : C++ interpreter
  62 AC_MSG_CHECKING([which interpreter of the JVM to build])
  63 AC_ARG_WITH([jvm-interpreter], [AS_HELP_STRING([--with-jvm-interpreter],
  64         [JVM interpreter to build (template, cpp) @<:@template@:>@])])
  65 
  66 if test "x$with_jvm_interpreter" = x; then
  67      with_jvm_interpreter="template"
  68 fi
  69 
  70 JVM_INTERPRETER="$with_jvm_interpreter"
  71 
  72 if test "x$JVM_INTERPRETER" != xtemplate && test "x$JVM_INTERPRETER" != xcpp; then
  73    AC_MSG_ERROR([The available JVM interpreters are: template, cpp])
  74 fi
  75 
  76 AC_SUBST(JVM_INTERPRETER)
  77 
  78 AC_MSG_RESULT([$with_jvm_interpreter])
  79 ])
  80 
  81 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_VARIANTS],
  82 [
  83 
  84   ###############################################################################
  85   #
  86   # Check which variants of the JVM that we want to build.
  87   # Currently we have:
  88   #    server: normal interpreter and a tiered C1/C2 compiler
  89   #    client: normal interpreter and C1 (no C2 compiler) (only 32-bit platforms)
  90   #    minimal1: reduced form of client with optional VM services and features stripped out
  91   #    kernel: kernel footprint JVM that passes the TCK without major performance problems,
  92   #             ie normal interpreter and C1, only the serial GC, kernel jvmti etc
  93   #    zero: no machine code interpreter, no compiler
  94   #    zeroshark: zero interpreter and shark/llvm compiler backend
  95 #    core: interpreter only, no compiler (only works on some platforms)
  96   AC_MSG_CHECKING([which variants of the JVM to build])
  97   AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
  98         [JVM variants (separated by commas) to build (server, client, minimal1, kernel, zero, zeroshark, core) @<:@server@:>@])])
  99 
 100   if test "x$with_jvm_variants" = x; then
 101     with_jvm_variants="server"
 102   fi
 103 
 104   JVM_VARIANTS=",$with_jvm_variants,"
 105   TEST_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,//' -e 's/client,//'  -e 's/minimal1,//' -e 's/kernel,//' -e 's/zero,//' -e 's/zeroshark,//' -e 's/core,//'`
 106 
 107   if test "x$TEST_VARIANTS" != "x,"; then
 108      AC_MSG_ERROR([The available JVM variants are: server, client, minimal1, kernel, zero, zeroshark, core])
 109   fi
 110   AC_MSG_RESULT([$with_jvm_variants])
 111 
 112   JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`
 113   JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`
 114   JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS" | $SED -e '/,minimal1,/!s/.*/false/g' -e '/,minimal1,/s/.*/true/g'`
 115   JVM_VARIANT_KERNEL=`$ECHO "$JVM_VARIANTS" | $SED -e '/,kernel,/!s/.*/false/g' -e '/,kernel,/s/.*/true/g'`
 116   JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`
 117   JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`
 118   JVM_VARIANT_CORE=`$ECHO "$JVM_VARIANTS" | $SED -e '/,core,/!s/.*/false/g' -e '/,core,/s/.*/true/g'`
 119 
 120   if test "x$JVM_VARIANT_CLIENT" = xtrue; then
 121     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 122       AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])
 123     fi
 124   fi
 125   if test "x$JVM_VARIANT_KERNEL" = xtrue; then
 126     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 127       AC_MSG_ERROR([You cannot build a kernel JVM for a 64-bit machine.])
 128     fi
 129   fi
 130   if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
 131     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 132       AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])
 133     fi
 134   fi
 135 
 136   # Replace the commas with AND for use in the build directory name.
 137   ANDED_JVM_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/^,//' -e 's/,$//' -e 's/,/AND/g'`
 138   COUNT_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,/1/' -e 's/client,/1/' -e 's/minimal1,/1/' -e 's/kernel,/1/' -e 's/zero,/1/' -e 's/zeroshark,/1/' -e 's/core,/1/'`
 139   if test "x$COUNT_VARIANTS" != "x,1"; then
 140     BUILDING_MULTIPLE_JVM_VARIANTS=yes
 141   else
 142     BUILDING_MULTIPLE_JVM_VARIANTS=no
 143   fi
 144 
 145   AC_SUBST(JVM_VARIANTS)
 146   AC_SUBST(JVM_VARIANT_SERVER)
 147   AC_SUBST(JVM_VARIANT_CLIENT)
 148   AC_SUBST(JVM_VARIANT_MINIMAL1)
 149   AC_SUBST(JVM_VARIANT_KERNEL)
 150   AC_SUBST(JVM_VARIANT_ZERO)
 151   AC_SUBST(JVM_VARIANT_ZEROSHARK)
 152   AC_SUBST(JVM_VARIANT_CORE)
 153 
 154   INCLUDE_SA=true
 155   if test "x$JVM_VARIANT_ZERO" = xtrue ; then
 156     INCLUDE_SA=false
 157   fi
 158   if test "x$JVM_VARIANT_ZEROSHARK" = xtrue ; then
 159     INCLUDE_SA=false
 160   fi
 161   if test "x$VAR_CPU" = xppc64 -o "x$VAR_CPU" = xppc64le ; then
 162     INCLUDE_SA=false
 163   fi
 164   if test "x$OPENJDK_TARGET_CPU" = xaarch64; then
 165     INCLUDE_SA=false
 166   fi
 167   AC_SUBST(INCLUDE_SA)
 168 
 169   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 170     MACOSX_UNIVERSAL="false"
 171   fi
 172 
 173   AC_SUBST(MACOSX_UNIVERSAL)
 174 ])
 175 
 176 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],
 177 [
 178   ###############################################################################
 179   #
 180   # Set the debug level
 181   #    release: no debug information, all optimizations, no asserts.
 182   #    fastdebug: debug information (-g), all optimizations, all asserts
 183   #    slowdebug: debug information (-g), no optimizations, all asserts
 184   #
 185   DEBUG_LEVEL="release"
 186   AC_MSG_CHECKING([which debug level to use])
 187   AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],
 188       [set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],
 189       [
 190         ENABLE_DEBUG="${enableval}"
 191         DEBUG_LEVEL="fastdebug"
 192       ], [ENABLE_DEBUG="no"])
 193 
 194   AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],
 195       [set the debug level (release, fastdebug, slowdebug) @<:@release@:>@])],
 196       [
 197         DEBUG_LEVEL="${withval}"
 198         if test "x$ENABLE_DEBUG" = xyes; then
 199           AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])
 200         fi
 201       ])
 202   AC_MSG_RESULT([$DEBUG_LEVEL])
 203 
 204   if test "x$DEBUG_LEVEL" != xrelease && \
 205       test "x$DEBUG_LEVEL" != xfastdebug && \
 206       test "x$DEBUG_LEVEL" != xslowdebug; then
 207     AC_MSG_ERROR([Allowed debug levels are: release, fastdebug and slowdebug])
 208   fi
 209 
 210 
 211   ###############################################################################
 212   #
 213   # Setup legacy vars/targets and new vars to deal with different debug levels.
 214   #
 215 
 216   case $DEBUG_LEVEL in
 217     release )
 218       VARIANT="OPT"
 219       FASTDEBUG="false"
 220       DEBUG_CLASSFILES="false"
 221       BUILD_VARIANT_RELEASE=""
 222       HOTSPOT_DEBUG_LEVEL="product"
 223       HOTSPOT_EXPORT="product"
 224       ;;
 225     fastdebug )
 226       VARIANT="DBG"
 227       FASTDEBUG="true"
 228       DEBUG_CLASSFILES="true"
 229       BUILD_VARIANT_RELEASE="-fastdebug"
 230       HOTSPOT_DEBUG_LEVEL="fastdebug"
 231       HOTSPOT_EXPORT="fastdebug"
 232       ;;
 233     slowdebug )
 234       VARIANT="DBG"
 235       FASTDEBUG="false"
 236       DEBUG_CLASSFILES="true"
 237       BUILD_VARIANT_RELEASE="-debug"
 238       HOTSPOT_DEBUG_LEVEL="jvmg"
 239       HOTSPOT_EXPORT="debug"
 240       ;;
 241   esac
 242 
 243   #####
 244   # Generate the legacy makefile targets for hotspot.
 245   # The hotspot api for selecting the build artifacts, really, needs to be improved.
 246   # JDK-7195896 will fix this on the hotspot side by using the JVM_VARIANT_* variables to
 247   # determine what needs to be built. All we will need to set here is all_product, all_fastdebug etc
 248   # But until then ...
 249   HOTSPOT_TARGET=""
 250 
 251   if test "x$JVM_VARIANT_SERVER" = xtrue; then
 252     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "
 253   fi
 254 
 255   if test "x$JVM_VARIANT_CLIENT" = xtrue; then
 256     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "
 257   fi
 258 
 259   if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
 260     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "
 261   fi
 262 
 263   if test "x$JVM_VARIANT_KERNEL" = xtrue; then
 264     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}kernel "
 265   fi
 266 
 267   if test "x$JVM_VARIANT_ZERO" = xtrue; then
 268     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "
 269   fi
 270 
 271   if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
 272     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "
 273   fi
 274 
 275   if test "x$JVM_VARIANT_CORE" = xtrue; then
 276     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}core "
 277   fi
 278 
 279   HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_EXPORT"
 280 
 281   # On Macosx universal binaries are produced, but they only contain
 282   # 64 bit intel. This invalidates control of which jvms are built
 283   # from configure, but only server is valid anyway. Fix this
 284   # when hotspot makefiles are rewritten.
 285   if test "x$MACOSX_UNIVERSAL" = xtrue; then
 286     HOTSPOT_TARGET=universal_${HOTSPOT_EXPORT}
 287   fi
 288 
 289   #####
 290 
 291   AC_SUBST(DEBUG_LEVEL)
 292   AC_SUBST(VARIANT)
 293   AC_SUBST(FASTDEBUG)
 294   AC_SUBST(DEBUG_CLASSFILES)
 295   AC_SUBST(BUILD_VARIANT_RELEASE)
 296 ])
 297 
 298 
 299 ###############################################################################
 300 #
 301 # Should we build only OpenJDK even if closed sources are present?
 302 #
 303 AC_DEFUN_ONCE([JDKOPT_SETUP_OPEN_OR_CUSTOM],
 304 [
 305   AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],
 306       [suppress building custom source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])
 307 
 308   AC_MSG_CHECKING([for presence of closed sources])
 309   if test -d "$SRC_ROOT/jdk/src/closed"; then
 310     CLOSED_SOURCE_PRESENT=yes
 311   else
 312     CLOSED_SOURCE_PRESENT=no
 313   fi
 314   AC_MSG_RESULT([$CLOSED_SOURCE_PRESENT])
 315 
 316   AC_MSG_CHECKING([if closed source is suppressed (openjdk-only)])
 317   SUPPRESS_CLOSED_SOURCE="$enable_openjdk_only"
 318   AC_MSG_RESULT([$SUPPRESS_CLOSED_SOURCE])
 319 
 320   if test "x$CLOSED_SOURCE_PRESENT" = xno; then
 321     OPENJDK=true
 322     if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
 323       AC_MSG_WARN([No closed source present, --enable-openjdk-only makes no sense])
 324     fi
 325   else
 326     if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
 327       OPENJDK=true
 328     else
 329       OPENJDK=false
 330     fi
 331   fi
 332 
 333   if test "x$OPENJDK" = "xtrue"; then
 334     SET_OPENJDK="OPENJDK=true"
 335   fi
 336 
 337   AC_SUBST(SET_OPENJDK)
 338 ])
 339 
 340 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],
 341 [
 342 
 343   ###############################################################################
 344   #
 345   # Should we build a JDK/JVM with headful support (ie a graphical ui)?
 346   # We always build headless support.
 347   #
 348   AC_MSG_CHECKING([headful support])
 349   AC_ARG_ENABLE([headful], [AS_HELP_STRING([--disable-headful],
 350       [disable building headful support (graphical UI support) @<:@enabled@:>@])],
 351       [SUPPORT_HEADFUL=${enable_headful}], [SUPPORT_HEADFUL=yes])
 352 
 353   SUPPORT_HEADLESS=yes
 354   BUILD_HEADLESS="BUILD_HEADLESS:=true"
 355 
 356   if test "x$SUPPORT_HEADFUL" = xyes; then
 357     # We are building both headful and headless.
 358     headful_msg="include support for both headful and headless"
 359   fi
 360 
 361   if test "x$SUPPORT_HEADFUL" = xno; then
 362     # Thus we are building headless only.
 363     BUILD_HEADLESS="BUILD_HEADLESS:=true"
 364     headful_msg="headless only"
 365   fi
 366 
 367   AC_MSG_RESULT([$headful_msg])
 368 
 369   AC_SUBST(SUPPORT_HEADLESS)
 370   AC_SUBST(SUPPORT_HEADFUL)
 371   AC_SUBST(BUILD_HEADLESS)
 372 
 373   # Control wether Hotspot runs Queens test after build.
 374   AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],
 375       [run the Queens test after Hotspot build @<:@disabled@:>@])],,
 376       [enable_hotspot_test_in_build=no])
 377   if test "x$enable_hotspot_test_in_build" = "xyes"; then
 378     TEST_IN_BUILD=true
 379   else
 380     TEST_IN_BUILD=false
 381   fi
 382   AC_SUBST(TEST_IN_BUILD)
 383 
 384   ###############################################################################
 385   #
 386   # Choose cacerts source file
 387   #
 388   AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],
 389       [specify alternative cacerts file])])
 390   if test "x$with_cacerts_file" != x; then
 391     CACERTS_FILE=$with_cacerts_file
 392   else
 393     CACERTS_FILE=${SRC_ROOT}/jdk/src/share/lib/security/cacerts
 394   fi
 395   AC_SUBST(CACERTS_FILE)
 396 
 397   ###############################################################################
 398   #
 399   # Enable or disable unlimited crypto
 400   #
 401   AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--enable-unlimited-crypto],
 402       [Enable unlimited crypto policy @<:@disabled@:>@])],,
 403       [enable_unlimited_crypto=no])
 404   if test "x$enable_unlimited_crypto" = "xyes"; then
 405     UNLIMITED_CRYPTO=true
 406   else
 407     UNLIMITED_CRYPTO=false
 408   fi
 409   AC_SUBST(UNLIMITED_CRYPTO)
 410 
 411   ###############################################################################
 412   #
 413   # Enable or disable the elliptic curve crypto implementation
 414   #
 415   AC_DEFUN_ONCE([JDKOPT_DETECT_INTREE_EC],
 416   [
 417     AC_MSG_CHECKING([if elliptic curve crypto implementation is present])
 418 
 419     if test -d "${SRC_ROOT}/jdk/src/share/native/sun/security/ec/impl"; then
 420       ENABLE_INTREE_EC=yes
 421       AC_MSG_RESULT([yes])
 422     else
 423       ENABLE_INTREE_EC=no
 424       AC_MSG_RESULT([no])
 425     fi
 426 
 427     AC_SUBST(ENABLE_INTREE_EC)
 428   ])
 429 
 430   ###############################################################################
 431   #
 432   # Compress jars
 433   #
 434   COMPRESS_JARS=false
 435 
 436   AC_SUBST(COMPRESS_JARS)
 437 ])
 438 
 439 ###############################################################################
 440 #
 441 # Setup version numbers
 442 #
 443 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VERSION_NUMBERS],
 444 [
 445   # Source the version numbers
 446   . $AUTOCONF_DIR/version-numbers
 447 
 448   # Get the settings from parameters
 449   AC_ARG_WITH(milestone, [AS_HELP_STRING([--with-milestone],
 450       [Set milestone value for build @<:@internal@:>@])])
 451   if test "x$with_milestone" = xyes; then
 452     AC_MSG_ERROR([Milestone must have a value])
 453   elif test "x$with_milestone" != x; then
 454     MILESTONE="$with_milestone"
 455   fi
 456   if test "x$MILESTONE" = x; then
 457     MILESTONE=internal
 458   fi
 459 
 460   AC_ARG_WITH(update-version, [AS_HELP_STRING([--with-update-version],
 461       [Set update version value for build @<:@b00@:>@])])
 462   if test "x$with_update_version" = xyes; then
 463     AC_MSG_ERROR([Update version must have a value])
 464   elif test "x$with_update_version" != x; then
 465     JDK_UPDATE_VERSION="$with_update_version"
 466     # On macosx 10.7, it's not possible to set --with-update-version=0X due
 467     # to a bug in expr (which reduces it to just X). To work around this, we
 468     # always add a 0 to one digit update versions.
 469     if test "${#JDK_UPDATE_VERSION}" = "1"; then
 470       JDK_UPDATE_VERSION="0${JDK_UPDATE_VERSION}"
 471     fi
 472   fi
 473 
 474   AC_ARG_WITH(user-release-suffix, [AS_HELP_STRING([--with-user-release-suffix],
 475       [Add a custom string to the version string if build number isn't set.@<:@username_builddateb00@:>@])])
 476   if test "x$with_user_release_suffix" = xyes; then
 477     AC_MSG_ERROR([Release suffix must have a value])
 478   elif test "x$with_user_release_suffix" != x; then
 479     USER_RELEASE_SUFFIX="$with_user_release_suffix"
 480   fi
 481 
 482   AC_ARG_WITH(build-number, [AS_HELP_STRING([--with-build-number],
 483       [Set build number value for build @<:@b00@:>@])])
 484   if test "x$with_build_number" = xyes; then
 485     AC_MSG_ERROR([Build number must have a value])
 486   elif test "x$with_build_number" != x; then
 487     JDK_BUILD_NUMBER="$with_build_number"
 488   fi
 489   # Define default USER_RELEASE_SUFFIX if BUILD_NUMBER and USER_RELEASE_SUFFIX are not set
 490   if test "x$JDK_BUILD_NUMBER" = x; then
 491     JDK_BUILD_NUMBER=b00
 492     if test "x$USER_RELEASE_SUFFIX" = x; then
 493       BUILD_DATE=`date '+%Y_%m_%d_%H_%M'`
 494       # Avoid [:alnum:] since it depends on the locale.
 495       CLEAN_USERNAME=`echo "$USER" | $TR -d -c 'abcdefghijklmnopqrstuvqxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789'`
 496       USER_RELEASE_SUFFIX=`echo "${CLEAN_USERNAME}_${BUILD_DATE}" | $TR 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' 'abcdefghijklmnopqrstuvwxyz'`
 497     fi
 498   fi
 499 
 500   # Now set the JDK version, milestone, build number etc.
 501   AC_SUBST(USER_RELEASE_SUFFIX)
 502   AC_SUBST(JDK_MAJOR_VERSION)
 503   AC_SUBST(JDK_MINOR_VERSION)
 504   AC_SUBST(JDK_MICRO_VERSION)
 505   AC_SUBST(JDK_UPDATE_VERSION)
 506   AC_SUBST(JDK_BUILD_NUMBER)
 507   AC_SUBST(MILESTONE)
 508   AC_SUBST(LAUNCHER_NAME)
 509   AC_SUBST(PRODUCT_NAME)
 510   AC_SUBST(PRODUCT_SUFFIX)
 511   AC_SUBST(JDK_RC_PLATFORM_NAME)
 512   AC_SUBST(MACOSX_BUNDLE_NAME_BASE)
 513   AC_SUBST(MACOSX_BUNDLE_ID_BASE)
 514 
 515   # The vendor name, if any
 516   AC_ARG_WITH(vendor-name, [AS_HELP_STRING([--with-vendor-name],
 517       [Set vendor name. Among others, used to set the 'java.vendor'
 518        and 'java.vm.vendor' system properties. @<:@not specified@:>@])])
 519   if test "x$with_vendor_name" = xyes; then
 520     AC_MSG_ERROR([--with-vendor-name must have a value])
 521   elif [ ! [[ $with_vendor_name =~ ^[[:print:]]*$ ]] ]; then
 522     AC_MSG_ERROR([--with-vendor-name contains non-printing characters: $with_vendor_name])
 523   elif test "x$with_vendor_name" != x; then
 524     # Only set COMPANY_NAME if '--with-vendor-name' was used and is not empty.
 525     # Otherwise we will use the value from "version-numbers" included above.
 526     COMPANY_NAME="$with_vendor_name"
 527   fi
 528   AC_SUBST(COMPANY_NAME)
 529 
 530   # The vendor URL, if any
 531   AC_ARG_WITH(vendor-url, [AS_HELP_STRING([--with-vendor-url],
 532       [Set the 'java.vendor.url' system property @<:@not specified@:>@])])
 533   if test "x$with_vendor_url" = xyes; then
 534     AC_MSG_ERROR([--with-vendor-url must have a value])
 535   elif [ ! [[ $with_vendor_url =~ ^[[:print:]]*$ ]] ]; then
 536     AC_MSG_ERROR([--with-vendor-url contains non-printing characters: $with_vendor_url])
 537   else
 538     VENDOR_URL="$with_vendor_url"
 539   fi
 540   AC_SUBST(VENDOR_URL)
 541 
 542   # The vendor bug URL, if any
 543   AC_ARG_WITH(vendor-bug-url, [AS_HELP_STRING([--with-vendor-bug-url],
 544       [Set the 'java.vendor.url.bug' system property @<:@not specified@:>@])])
 545   if test "x$with_vendor_bug_url" = xyes; then
 546     AC_MSG_ERROR([--with-vendor-bug-url must have a value])
 547   elif [ ! [[ $with_vendor_bug_url =~ ^[[:print:]]*$ ]] ]; then
 548     AC_MSG_ERROR([--with-vendor-bug-url contains non-printing characters: $with_vendor_bug_url])
 549   else
 550     VENDOR_URL_BUG="$with_vendor_bug_url"
 551   fi
 552   AC_SUBST(VENDOR_URL_BUG)
 553 
 554   # The vendor VM bug URL, if any
 555   AC_ARG_WITH(vendor-vm-bug-url, [AS_HELP_STRING([--with-vendor-vm-bug-url],
 556       [Sets the bug URL which will be displayed when the VM crashes @<:@not specified@:>@])])
 557   if test "x$with_vendor_vm_bug_url" = xyes; then
 558     AC_MSG_ERROR([--with-vendor-vm-bug-url must have a value])
 559   elif [ ! [[ $with_vendor_vm_bug_url =~ ^[[:print:]]*$ ]] ]; then
 560     AC_MSG_ERROR([--with-vendor-vm-bug-url contains non-printing characters: $with_vendor_vm_bug_url])
 561   else
 562     VENDOR_URL_VM_BUG="$with_vendor_vm_bug_url"
 563   fi
 564   AC_SUBST(VENDOR_URL_VM_BUG)
 565 
 566   AC_ARG_WITH(copyright-year, [AS_HELP_STRING([--with-copyright-year],
 567       [Set copyright year value for build @<:@current year@:>@])])
 568   if test "x$with_copyright_year" = xyes; then
 569     AC_MSG_ERROR([Copyright year must have a value])
 570   elif test "x$with_copyright_year" != x; then
 571     COPYRIGHT_YEAR="$with_copyright_year"
 572   else
 573     COPYRIGHT_YEAR=`date +'%Y'`
 574   fi
 575   AC_SUBST(COPYRIGHT_YEAR)
 576 
 577   if test "x$JDK_UPDATE_VERSION" != x; then
 578     JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}_${JDK_UPDATE_VERSION}"
 579   else
 580     JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}"
 581   fi
 582   AC_SUBST(JDK_VERSION)
 583 
 584   # The cooked update version used to encode trailing letters in the update
 585   # version into a trailing number. That is no longer needed, but need to
 586   # keep the format in 8u for compatibility.
 587   COOKED_JDK_UPDATE_VERSION="${JDK_UPDATE_VERSION}0"
 588   AC_SUBST(COOKED_JDK_UPDATE_VERSION)
 589 
 590   COOKED_BUILD_NUMBER=`$ECHO $JDK_BUILD_NUMBER | $SED -e 's/^b//' -e 's/^0//'`
 591   AC_SUBST(COOKED_BUILD_NUMBER)
 592 ])
 593 
 594 AC_DEFUN_ONCE([JDKOPT_SETUP_BUILD_TWEAKS],
 595 [
 596   HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"
 597   AC_SUBST(HOTSPOT_MAKE_ARGS)
 598 
 599   # The name of the Service Agent jar.
 600   SALIB_NAME="${LIBRARY_PREFIX}saproc${SHARED_LIBRARY_SUFFIX}"
 601   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 602     SALIB_NAME="${LIBRARY_PREFIX}sawindbg${SHARED_LIBRARY_SUFFIX}"
 603   fi
 604   AC_SUBST(SALIB_NAME)
 605 ])
 606 
 607 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],
 608 [
 609   # Backwards compatibility. --with-native-debug-symbols is preferred post JDK-8207234,
 610   # but if somebody does not specify it via configure, we still want to preserve old
 611   # behaviour of --disable-debug-symbols
 612   #
 613   # ENABLE_DEBUG_SYMBOLS
 614   # This must be done after the toolchain is setup, since we're looking at objcopy.
 615   #
 616   AC_ARG_ENABLE([debug-symbols],
 617       [AS_HELP_STRING([--disable-debug-symbols],[disable generation of debug symbols @<:@enabled@:>@])])
 618 
 619   AC_MSG_CHECKING([if we should generate debug symbols])
 620 
 621   if test "x$enable_debug_symbols" = "xyes" && test "x$OBJCOPY" = x; then
 622     # explicit enabling of enable-debug-symbols and can't find objcopy
 623     #   this is an error
 624     AC_MSG_ERROR([Unable to find objcopy, cannot enable debug-symbols])
 625   fi
 626 
 627   if test "x$enable_debug_symbols" = "xyes"; then
 628     ENABLE_DEBUG_SYMBOLS=true
 629   elif test "x$enable_debug_symbols" = "xno"; then
 630     ENABLE_DEBUG_SYMBOLS=false
 631   else
 632     # Default is on if objcopy is found
 633     if test "x$OBJCOPY" != x; then
 634       ENABLE_DEBUG_SYMBOLS=true
 635     # MacOS X and Windows don't use objcopy but default is on for those OSes
 636     elif test "x$OPENJDK_TARGET_OS" = xmacosx || test "x$OPENJDK_TARGET_OS" = xwindows; then
 637       ENABLE_DEBUG_SYMBOLS=true
 638     else
 639       ENABLE_DEBUG_SYMBOLS=false
 640     fi
 641   fi
 642 
 643   AC_MSG_RESULT([$ENABLE_DEBUG_SYMBOLS])
 644 
 645   # Backwards compatibility. --with-native-debug-symbols is preferred post JDK-8207234,
 646   # but if somebody does not specify it via configure, we still want to preserve old
 647   # behaviour of --disable-zip-debug-info.
 648   #
 649   # ZIP_DEBUGINFO_FILES
 650   #
 651   AC_MSG_CHECKING([if we should zip debug-info files])
 652   AC_ARG_ENABLE([zip-debug-info],
 653       [AS_HELP_STRING([--disable-zip-debug-info],[disable zipping of debug-info files @<:@enabled@:>@])],
 654       [enable_zip_debug_info="${enableval}"], [enable_zip_debug_info="yes"])
 655   AC_MSG_RESULT([${enable_zip_debug_info}])
 656 
 657   if test "x${enable_zip_debug_info}" = "xno"; then
 658     ZIP_DEBUGINFO_FILES=false
 659   elif test "x${enable_zip_debug_info}" = "xyes"; then
 660     ZIP_DEBUGINFO_FILES=true
 661   fi
 662 
 663   #
 664   # NATIVE_DEBUG_SYMBOLS
 665   # This must be done after the toolchain is setup, since we're looking at objcopy.
 666   # In addition, this must be done after ENABLE_DEBUG_SYMBOLS and ZIP_DEBUGINFO_FILES
 667   # checking in order to preserve backwards compatibility post JDK-8207234.
 668   #
 669   AC_MSG_CHECKING([what type of native debug symbols to use (this will override previous settings)])
 670   AC_ARG_WITH([native-debug-symbols],
 671       [AS_HELP_STRING([--with-native-debug-symbols],
 672       [set the native debug symbol configuration (none, internal, external, zipped) @<:@varying@:>@])],
 673       [
 674         if test "x$OPENJDK_TARGET_OS" = xaix; then
 675           if test "x$with_native_debug_symbols" = xexternal || test "x$with_native_debug_symbols" = xzipped; then
 676             AC_MSG_ERROR([AIX only supports the parameters 'none' and 'internal' for --with-native-debug-symbols])
 677           fi
 678         fi
 679       ],
 680       [
 681         # Default to unset for backwards compatibility
 682         with_native_debug_symbols=""
 683       ])
 684   NATIVE_DEBUG_SYMBOLS=$with_native_debug_symbols
 685   if test "x$NATIVE_DEBUG_SYMBOLS" = x; then
 686     AC_MSG_RESULT([not specified])
 687   else
 688     AC_MSG_RESULT([$NATIVE_DEBUG_SYMBOLS])
 689   fi
 690   # Default is empty
 691   DEBUG_BINARIES=
 692   # Default is min_strip. Possible values are min_strip, all_strip, no_strip
 693   STRIP_POLICY=min_strip
 694 
 695   if test "x$NATIVE_DEBUG_SYMBOLS" = xzipped; then
 696 
 697     if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
 698       if test "x$OBJCOPY" = x; then
 699         # enabling of enable-debug-symbols and can't find objcopy
 700         # this is an error
 701         AC_MSG_ERROR([Unable to find objcopy, cannot enable native debug symbols])
 702       fi
 703     fi
 704 
 705     ENABLE_DEBUG_SYMBOLS=true
 706     STRIP_POLICY=min_strip
 707     ZIP_DEBUGINFO_FILES=true
 708   elif test "x$NATIVE_DEBUG_SYMBOLS" = xnone; then
 709     ENABLE_DEBUG_SYMBOLS=false
 710     STRIP_POLICY=min_strip
 711     ZIP_DEBUGINFO_FILES=false
 712   elif test "x$NATIVE_DEBUG_SYMBOLS" = xinternal; then
 713     ENABLE_DEBUG_SYMBOLS=true
 714     STRIP_POLICY=no_strip
 715     ZIP_DEBUGINFO_FILES=false
 716     POST_STRIP_CMD=
 717     DEBUG_BINARIES=true
 718   elif test "x$NATIVE_DEBUG_SYMBOLS" = xexternal; then
 719 
 720     if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
 721       if test "x$OBJCOPY" = x; then
 722         # enabling of enable-debug-symbols and can't find objcopy
 723         # this is an error
 724         AC_MSG_ERROR([Unable to find objcopy, cannot enable native debug symbols])
 725       fi
 726     fi
 727 
 728     ENABLE_DEBUG_SYMBOLS=true
 729     STRIP_POLICY=min_strip
 730     ZIP_DEBUGINFO_FILES=false
 731   elif test "x$NATIVE_DEBUG_SYMBOLS" != x; then
 732     AC_MSG_ERROR([Allowed native debug symbols are: none, internal, external, zipped])
 733   else
 734     AC_MSG_NOTICE([--with-native-debug-symbols not specified. Using values from --disable-debug-symbols and --disable-zip-debug-info])
 735   fi
 736 
 737   AC_SUBST(ENABLE_DEBUG_SYMBOLS)
 738   AC_SUBST(STRIP_POLICY)
 739   AC_SUBST(POST_STRIP_CMD)
 740   AC_SUBST(DEBUG_BINARIES)
 741   AC_SUBST(ZIP_DEBUGINFO_FILES)
 742 ])
 743 
 744 # Support for customization of the build process. Some build files
 745 # will include counterparts from this location, if they exist. This allows
 746 # for a degree of customization of the build targets and the rules/recipes
 747 # to create them
 748 AC_ARG_WITH([custom-make-dir], [AS_HELP_STRING([--with-custom-make-dir],
 749 [use this directory for custom build/make files])], [CUSTOM_MAKE_DIR=$with_custom_make_dir])
 750 AC_SUBST(CUSTOM_MAKE_DIR)