1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
  27 # Converts autoconf style CPU name to OpenJDK style, into
  28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
  29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
  30 [
  31   # First argument is the cpu name from the trip/quad
  32   case "$1" in
  33     x86_64*x32)
  34       VAR_CPU=x32
  35       VAR_CPU_ARCH=x86
  36       VAR_CPU_BITS=32
  37       VAR_CPU_ENDIAN=little
  38       ;;
  39     x86_64)
  40       VAR_CPU=x86_64
  41       VAR_CPU_ARCH=x86
  42       VAR_CPU_BITS=64
  43       VAR_CPU_ENDIAN=little
  44       ;;
  45     i?86)
  46       VAR_CPU=x86
  47       VAR_CPU_ARCH=x86
  48       VAR_CPU_BITS=32
  49       VAR_CPU_ENDIAN=little
  50       ;;
  51     alpha*)
  52       VAR_CPU=alpha
  53       VAR_CPU_ARCH=alpha
  54       VAR_CPU_BITS=64
  55       VAR_CPU_ENDIAN=little
  56       ;;
  57     arm*)
  58       VAR_CPU=arm
  59       VAR_CPU_ARCH=arm
  60       VAR_CPU_BITS=32
  61       VAR_CPU_ENDIAN=little
  62       ;;
  63     aarch64)
  64       VAR_CPU=aarch64
  65       VAR_CPU_ARCH=aarch64
  66       VAR_CPU_BITS=64
  67       VAR_CPU_ENDIAN=little
  68       ;;
  69     ia64)
  70       VAR_CPU=ia64
  71       VAR_CPU_ARCH=ia64
  72       VAR_CPU_BITS=64
  73       VAR_CPU_ENDIAN=little
  74       ;;
  75     m68k)
  76       VAR_CPU=m68k
  77       VAR_CPU_ARCH=m68k
  78       VAR_CPU_BITS=32
  79       VAR_CPU_ENDIAN=big
  80       ;;
  81     mips)
  82       VAR_CPU=mips
  83       VAR_CPU_ARCH=mips
  84       VAR_CPU_BITS=32
  85       VAR_CPU_ENDIAN=big
  86       ;;
  87     mipsel)
  88       VAR_CPU=mipsel
  89       VAR_CPU_ARCH=mipsel
  90       VAR_CPU_BITS=32
  91       VAR_CPU_ENDIAN=little
  92       ;;
  93     mips64)
  94       VAR_CPU=mips64
  95       VAR_CPU_ARCH=mips64
  96       VAR_CPU_BITS=64
  97       VAR_CPU_ENDIAN=big
  98       ;;
  99     mips64el)
 100       VAR_CPU=mips64el
 101       VAR_CPU_ARCH=mips64el
 102       VAR_CPU_BITS=64
 103       VAR_CPU_ENDIAN=little
 104       ;;
 105     powerpc)
 106       VAR_CPU=ppc
 107       VAR_CPU_ARCH=ppc
 108       VAR_CPU_BITS=32
 109       VAR_CPU_ENDIAN=big
 110       ;;
 111     powerpc64)
 112       VAR_CPU=ppc64
 113       VAR_CPU_ARCH=ppc
 114       VAR_CPU_BITS=64
 115       VAR_CPU_ENDIAN=big
 116       ;;
 117     powerpc64le)
 118       VAR_CPU=ppc64le
 119       VAR_CPU_ARCH=ppc
 120       VAR_CPU_BITS=64
 121       VAR_CPU_ENDIAN=little
 122       ;;
 123     s390)
 124       VAR_CPU=s390
 125       VAR_CPU_ARCH=s390
 126       VAR_CPU_BITS=32
 127       VAR_CPU_ENDIAN=big
 128       ;;
 129     s390x)
 130       VAR_CPU=s390x
 131       VAR_CPU_ARCH=s390
 132       VAR_CPU_BITS=64
 133       VAR_CPU_ENDIAN=big
 134       ;;
 135     sh*eb)
 136       VAR_CPU=sh
 137       VAR_CPU_ARCH=sh
 138       VAR_CPU_BITS=32
 139       VAR_CPU_ENDIAN=big
 140       ;;
 141     sh*)
 142       VAR_CPU=sh
 143       VAR_CPU_ARCH=sh
 144       VAR_CPU_BITS=32
 145       VAR_CPU_ENDIAN=little
 146       ;;
 147     sparc)
 148       VAR_CPU=sparc
 149       VAR_CPU_ARCH=sparc
 150       VAR_CPU_BITS=32
 151       VAR_CPU_ENDIAN=big
 152       ;;
 153     sparcv9|sparc64)
 154       VAR_CPU=sparcv9
 155       VAR_CPU_ARCH=sparc
 156       VAR_CPU_BITS=64
 157       VAR_CPU_ENDIAN=big
 158       ;;
 159     *)
 160       AC_MSG_ERROR([unsupported cpu $1])
 161       ;;
 162   esac
 163 ])
 164 
 165 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
 166 # Converts autoconf style OS name to OpenJDK style, into
 167 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
 168 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
 169 [
 170   case "$1" in
 171     *linux*)
 172       VAR_OS=linux
 173       VAR_OS_TYPE=unix
 174       ;;
 175     *solaris*)
 176       VAR_OS=solaris
 177       VAR_OS_TYPE=unix
 178       ;;
 179     *darwin*)
 180       VAR_OS=macosx
 181       VAR_OS_TYPE=unix
 182       ;;
 183     *bsd*)
 184       VAR_OS=bsd
 185       VAR_OS_TYPE=unix
 186       ;;
 187     *cygwin*)
 188       VAR_OS=windows
 189       VAR_OS_ENV=windows.cygwin
 190       ;;
 191     *wsl*)
 192       VAR_OS=windows
 193       VAR_OS_ENV=windows.wsl
 194       ;;
 195     *mingw*)
 196       VAR_OS=windows
 197       VAR_OS_ENV=windows.msys
 198       ;;
 199     *aix*)
 200       VAR_OS=aix
 201       VAR_OS_TYPE=unix
 202       ;;
 203     *)
 204       AC_MSG_ERROR([unsupported operating system $1])
 205       ;;
 206   esac
 207 ])
 208 
 209 # Expects $host_os $host_cpu $build_os and $build_cpu
 210 # and $with_target_bits to have been setup!
 211 #
 212 # Translate the standard triplet(quadruplet) definition
 213 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
 214 # OPENJDK_BUILD_OS, etc.
 215 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
 216 [
 217   # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
 218   # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
 219   # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
 220   # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
 221   OPENJDK_TARGET_AUTOCONF_NAME="$host"
 222   OPENJDK_BUILD_AUTOCONF_NAME="$build"
 223   AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
 224   AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
 225 
 226   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
 227   PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
 228   PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
 229   # ..and setup our own variables. (Do this explicitly to facilitate searching)
 230   OPENJDK_BUILD_OS="$VAR_OS"
 231   if test "x$VAR_OS_TYPE" != x; then
 232     OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
 233   else
 234     OPENJDK_BUILD_OS_TYPE="$VAR_OS"
 235   fi
 236   if test "x$VAR_OS_ENV" != x; then
 237     OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
 238   else
 239     OPENJDK_BUILD_OS_ENV="$VAR_OS"
 240   fi
 241   OPENJDK_BUILD_CPU="$VAR_CPU"
 242   OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
 243   OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
 244   OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
 245   AC_SUBST(OPENJDK_BUILD_OS)
 246   AC_SUBST(OPENJDK_BUILD_OS_TYPE)
 247   AC_SUBST(OPENJDK_BUILD_OS_ENV)
 248   AC_SUBST(OPENJDK_BUILD_CPU)
 249   AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
 250   AC_SUBST(OPENJDK_BUILD_CPU_BITS)
 251   AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
 252 
 253   AC_MSG_CHECKING([openjdk-build os-cpu])
 254   AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
 255 
 256   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
 257   PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
 258   PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
 259   # ... and setup our own variables. (Do this explicitly to facilitate searching)
 260   OPENJDK_TARGET_OS="$VAR_OS"
 261   if test "x$VAR_OS_TYPE" != x; then
 262     OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
 263   else
 264     OPENJDK_TARGET_OS_TYPE="$VAR_OS"
 265   fi
 266   if test "x$VAR_OS_ENV" != x; then
 267     OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
 268   else
 269     OPENJDK_TARGET_OS_ENV="$VAR_OS"
 270   fi
 271   OPENJDK_TARGET_CPU="$VAR_CPU"
 272   OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
 273   OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
 274   OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
 275   OPENJDK_TARGET_OS_UPPERCASE=`$ECHO $OPENJDK_TARGET_OS | $TR 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 276 
 277   AC_SUBST(OPENJDK_TARGET_OS)
 278   AC_SUBST(OPENJDK_TARGET_OS_TYPE)
 279   AC_SUBST(OPENJDK_TARGET_OS_ENV)
 280   AC_SUBST(OPENJDK_TARGET_OS_UPPERCASE)
 281   AC_SUBST(OPENJDK_TARGET_CPU)
 282   AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
 283   AC_SUBST(OPENJDK_TARGET_CPU_BITS)
 284   AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
 285 
 286   AC_MSG_CHECKING([openjdk-target os-cpu])
 287   AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
 288 ])
 289 
 290 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
 291 # accordingly. Must be done after setting up build and target system, but before
 292 # doing anything else with these values.
 293 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
 294 [
 295   AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
 296        [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
 297 
 298   # We have three types of compiles:
 299   # native  == normal compilation, target system == build system
 300   # cross   == traditional cross compilation, target system != build system; special toolchain needed
 301   # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
 302   #
 303   if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
 304     # We're doing a proper cross-compilation
 305     COMPILE_TYPE="cross"
 306   else
 307     COMPILE_TYPE="native"
 308   fi
 309 
 310   if test "x$with_target_bits" != x; then
 311     if test "x$COMPILE_TYPE" = "xcross"; then
 312       AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
 313     fi
 314 
 315     if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 316       # A reduced build is requested
 317       COMPILE_TYPE="reduced"
 318       OPENJDK_TARGET_CPU_BITS=32
 319       if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
 320         OPENJDK_TARGET_CPU=x86
 321       elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
 322         OPENJDK_TARGET_CPU=sparc
 323       else
 324         AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
 325       fi
 326     elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
 327       AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
 328     elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
 329       AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
 330     else
 331       AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
 332     fi
 333   fi
 334   AC_SUBST(COMPILE_TYPE)
 335 
 336   AC_MSG_CHECKING([compilation type])
 337   AC_MSG_RESULT([$COMPILE_TYPE])
 338 ])
 339 
 340 # Setup the legacy variables, for controlling the old makefiles.
 341 #
 342 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
 343 [
 344   PLATFORM_SETUP_LEGACY_VARS_HELPER([TARGET])
 345   PLATFORM_SETUP_LEGACY_VARS_HELPER([BUILD])
 346 ])
 347 
 348 # $1 - Either TARGET or BUILD to setup the variables for.
 349 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS_HELPER],
 350 [
 351   # Also store the legacy naming of the cpu.
 352   # Ie i586 and amd64 instead of x86 and x86_64
 353   OPENJDK_$1_CPU_LEGACY="$OPENJDK_$1_CPU"
 354   if test "x$OPENJDK_$1_CPU" = xx86; then
 355     OPENJDK_$1_CPU_LEGACY="i586"
 356   elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
 357     # On all platforms except MacOSX replace x86_64 with amd64.
 358     OPENJDK_$1_CPU_LEGACY="amd64"
 359   elif test "x$OPENJDK_$1_CPU" = xalpha; then
 360     # Avoid name collisions with variables named alpha
 361     OPENJDK_$1_CPU_LEGACY="_alpha_"
 362   elif test "x$OPENJDK_$1_CPU" = xsh; then
 363     # Avoid name collisions with variables named sh
 364     OPENJDK_$1_CPU_LEGACY="_sh_"
 365   fi
 366   AC_SUBST(OPENJDK_$1_CPU_LEGACY)
 367 
 368   # And the second legacy naming of the cpu.
 369   # Ie i386 and amd64 instead of x86 and x86_64.
 370   OPENJDK_$1_CPU_LEGACY_LIB="$OPENJDK_$1_CPU"
 371   if test "x$OPENJDK_$1_CPU" = xx86; then
 372     OPENJDK_$1_CPU_LEGACY_LIB="i386"
 373   elif test "x$OPENJDK_$1_CPU" = xx86_64; then
 374     OPENJDK_$1_CPU_LEGACY_LIB="amd64"
 375   fi
 376   AC_SUBST(OPENJDK_$1_CPU_LEGACY_LIB)
 377 
 378   # OPENJDK_$1_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
 379   # /amd64 or /sparcv9. This string is appended to some library paths, like this:
 380   # /usr/lib${OPENJDK_$1_CPU_ISADIR}/libexample.so
 381   OPENJDK_$1_CPU_ISADIR=""
 382   if test "x$OPENJDK_$1_OS" = xsolaris; then
 383     if test "x$OPENJDK_$1_CPU" = xx86_64; then
 384       OPENJDK_$1_CPU_ISADIR="/amd64"
 385     elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
 386       OPENJDK_$1_CPU_ISADIR="/sparcv9"
 387     fi
 388   fi
 389   AC_SUBST(OPENJDK_$1_CPU_ISADIR)
 390 
 391   # Setup OPENJDK_$1_CPU_OSARCH, which is used to set the os.arch Java system property
 392   OPENJDK_$1_CPU_OSARCH="$OPENJDK_$1_CPU"
 393   if test "x$OPENJDK_$1_OS" = xlinux && test "x$OPENJDK_$1_CPU" = xx86; then
 394     # On linux only, we replace x86 with i386.
 395     OPENJDK_$1_CPU_OSARCH="i386"
 396   elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
 397     # On all platforms except macosx, we replace x86_64 with amd64.
 398     OPENJDK_$1_CPU_OSARCH="amd64"
 399   fi
 400   AC_SUBST(OPENJDK_$1_CPU_OSARCH)
 401 
 402   OPENJDK_$1_CPU_JLI="$OPENJDK_$1_CPU"
 403   if test "x$OPENJDK_$1_CPU" = xx86; then
 404     OPENJDK_$1_CPU_JLI="i386"
 405   elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
 406     # On all platforms except macosx, we replace x86_64 with amd64.
 407     OPENJDK_$1_CPU_JLI="amd64"
 408   fi
 409 
 410   # The new version string in JDK 9 also defined new naming of OS and ARCH for bundles
 411   # Macosx is osx and x86_64 is x64
 412   if test "x$OPENJDK_$1_OS" = xmacosx; then
 413     OPENJDK_$1_OS_BUNDLE="osx"
 414   else
 415     OPENJDK_$1_OS_BUNDLE="$OPENJDK_TARGET_OS"
 416   fi
 417   if test "x$OPENJDK_$1_CPU" = xx86_64; then
 418     OPENJDK_$1_CPU_BUNDLE="x64"
 419   else
 420     OPENJDK_$1_CPU_BUNDLE="$OPENJDK_$1_CPU"
 421   fi
 422   OPENJDK_$1_BUNDLE_PLATFORM="${OPENJDK_$1_OS_BUNDLE}-${OPENJDK_$1_CPU_BUNDLE}"
 423   AC_SUBST(OPENJDK_$1_BUNDLE_PLATFORM)
 424 
 425   if test "x$COMPILE_TYPE" = "xcross"; then
 426     # FIXME: ... or should this include reduced builds..?
 427     DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_$1_CPU_LEGACY"
 428   else
 429     DEFINE_CROSS_COMPILE_ARCH=""
 430   fi
 431   AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
 432 
 433   # Convert openjdk platform names to hotspot names
 434 
 435   HOTSPOT_$1_OS=${OPENJDK_$1_OS}
 436   if test "x$OPENJDK_$1_OS" = xmacosx; then
 437     HOTSPOT_$1_OS=bsd
 438   fi
 439   AC_SUBST(HOTSPOT_$1_OS)
 440 
 441   HOTSPOT_$1_OS_TYPE=${OPENJDK_$1_OS_TYPE}
 442   if test "x$OPENJDK_$1_OS_TYPE" = xunix; then
 443     HOTSPOT_$1_OS_TYPE=posix
 444   fi
 445   AC_SUBST(HOTSPOT_$1_OS_TYPE)
 446 
 447   HOTSPOT_$1_CPU=${OPENJDK_$1_CPU}
 448   if test "x$OPENJDK_$1_CPU" = xx86; then
 449     HOTSPOT_$1_CPU=x86_32
 450   elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
 451     HOTSPOT_$1_CPU=sparc
 452   elif test "x$OPENJDK_$1_CPU" = xppc64; then
 453     HOTSPOT_$1_CPU=ppc_64
 454   elif test "x$OPENJDK_$1_CPU" = xppc64le; then
 455     HOTSPOT_$1_CPU=ppc_64
 456   fi
 457   AC_SUBST(HOTSPOT_$1_CPU)
 458 
 459   # This is identical with OPENJDK_*, but define anyway for consistency.
 460   HOTSPOT_$1_CPU_ARCH=${OPENJDK_$1_CPU_ARCH}
 461   AC_SUBST(HOTSPOT_$1_CPU_ARCH)
 462 
 463   # Setup HOTSPOT_$1_CPU_DEFINE
 464   if test "x$OPENJDK_$1_CPU" = xx86; then
 465     HOTSPOT_$1_CPU_DEFINE=IA32
 466   elif test "x$OPENJDK_$1_CPU" = xx86_64; then
 467     HOTSPOT_$1_CPU_DEFINE=AMD64
 468   elif test "x$OPENJDK_$1_CPU" = xx32; then
 469     HOTSPOT_$1_CPU_DEFINE=X32
 470   elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
 471     HOTSPOT_$1_CPU_DEFINE=SPARC
 472   elif test "x$OPENJDK_$1_CPU" = xaarch64; then
 473     HOTSPOT_$1_CPU_DEFINE=AARCH64
 474   elif test "x$OPENJDK_$1_CPU" = xppc64; then
 475     HOTSPOT_$1_CPU_DEFINE=PPC64
 476   elif test "x$OPENJDK_$1_CPU" = xppc64le; then
 477     HOTSPOT_$1_CPU_DEFINE=PPC64
 478 
 479   # The cpu defines below are for zero, we don't support them directly.
 480   elif test "x$OPENJDK_$1_CPU" = xsparc; then
 481     HOTSPOT_$1_CPU_DEFINE=SPARC
 482   elif test "x$OPENJDK_$1_CPU" = xppc; then
 483     HOTSPOT_$1_CPU_DEFINE=PPC32
 484   elif test "x$OPENJDK_$1_CPU" = xs390; then
 485     HOTSPOT_$1_CPU_DEFINE=S390
 486   elif test "x$OPENJDK_$1_CPU" = xs390x; then
 487     HOTSPOT_$1_CPU_DEFINE=S390
 488   elif test "x$OPENJDK_$1_CPU" != x; then
 489     HOTSPOT_$1_CPU_DEFINE=$(echo $OPENJDK_$1_CPU | tr a-z A-Z)
 490   fi
 491   AC_SUBST(HOTSPOT_$1_CPU_DEFINE)
 492 
 493   # For historical reasons, the OS include directories have odd names.
 494   OPENJDK_$1_OS_INCLUDE_SUBDIR="$OPENJDK_TARGET_OS"
 495   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 496     OPENJDK_$1_OS_INCLUDE_SUBDIR="win32"
 497   elif test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 498     OPENJDK_$1_OS_INCLUDE_SUBDIR="darwin"
 499   fi
 500   AC_SUBST(OPENJDK_$1_OS_INCLUDE_SUBDIR)
 501 ])
 502 
 503 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
 504 [
 505   if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
 506     RELEASE_FILE_OS_NAME=SunOS
 507   fi
 508   if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
 509     RELEASE_FILE_OS_NAME=Linux
 510   fi
 511   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 512     RELEASE_FILE_OS_NAME=Windows
 513   fi
 514   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 515     RELEASE_FILE_OS_NAME="Darwin"
 516   fi
 517   if test "x$OPENJDK_TARGET_OS" = "xaix"; then
 518     RELEASE_FILE_OS_NAME="AIX"
 519   fi
 520   RELEASE_FILE_OS_ARCH=${OPENJDK_TARGET_CPU}
 521 
 522   AC_SUBST(RELEASE_FILE_OS_NAME)
 523   AC_SUBST(RELEASE_FILE_OS_ARCH)
 524 ])
 525 
 526 AC_DEFUN([PLATFORM_SET_MODULE_TARGET_OS_VALUES],
 527 [
 528   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 529     OPENJDK_MODULE_TARGET_OS_NAME="macos"
 530   else
 531     OPENJDK_MODULE_TARGET_OS_NAME="$OPENJDK_TARGET_OS"
 532   fi
 533 
 534   if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 535     OPENJDK_MODULE_TARGET_OS_ARCH="amd64"
 536   else
 537     OPENJDK_MODULE_TARGET_OS_ARCH="$OPENJDK_TARGET_CPU"
 538   fi
 539 
 540   OPENJDK_MODULE_TARGET_PLATFORM="${OPENJDK_MODULE_TARGET_OS_NAME}-${OPENJDK_MODULE_TARGET_OS_ARCH}"
 541   AC_SUBST(OPENJDK_MODULE_TARGET_PLATFORM)
 542 ])
 543 
 544 #%%% Build and target systems %%%
 545 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
 546 [
 547   # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
 548   # is confusing; it assumes you are cross-compiling a cross-compiler (!)  and "target" is thus the target of the
 549   # product you're building. The target of this build is called "host". Since this is confusing to most people, we
 550   # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
 551   # to use the configure naming style.
 552   AC_CANONICAL_BUILD
 553   AC_CANONICAL_HOST
 554   AC_CANONICAL_TARGET
 555 
 556   PLATFORM_EXTRACT_TARGET_AND_BUILD
 557   PLATFORM_SETUP_TARGET_CPU_BITS
 558   PLATFORM_SET_MODULE_TARGET_OS_VALUES
 559   PLATFORM_SET_RELEASE_FILE_OS_VALUES
 560   PLATFORM_SETUP_LEGACY_VARS
 561 ])
 562 
 563 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
 564 [
 565   ###############################################################################
 566 
 567   # Note that this is the build platform OS version!
 568 
 569   OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
 570   OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
 571   OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
 572   OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
 573   AC_SUBST(OS_VERSION_MAJOR)
 574   AC_SUBST(OS_VERSION_MINOR)
 575   AC_SUBST(OS_VERSION_MICRO)
 576 ])
 577 
 578 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
 579 [
 580   ###############################################################################
 581   #
 582   # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
 583   # (The JVM can use 32 or 64 bit Java pointers but that decision
 584   # is made at runtime.)
 585   #
 586 
 587   # Make compilation sanity check
 588   AC_CHECK_HEADERS([stdio.h], , [
 589     AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
 590     if test "x$COMPILE_TYPE" = xreduced; then
 591       HELP_MSG_MISSING_DEPENDENCY([reduced])
 592       AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
 593     elif test "x$COMPILE_TYPE" = xcross; then
 594       AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
 595     fi
 596     AC_MSG_ERROR([Cannot continue.])
 597   ])
 598 
 599   AC_CHECK_SIZEOF([int *], [1111])
 600 
 601   # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
 602   if test "x$ac_cv_sizeof_int_p" = x; then
 603     # The test failed, lets stick to the assumed value.
 604     AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
 605   else
 606     TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
 607 
 608     if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
 609       AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
 610       if test "x$COMPILE_TYPE" = xreduced; then
 611         HELP_MSG_MISSING_DEPENDENCY([reduced])
 612         AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
 613       elif test "x$COMPILE_TYPE" = xcross; then
 614         AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
 615       fi
 616       AC_MSG_ERROR([Cannot continue.])
 617     fi
 618   fi
 619 
 620   AC_MSG_CHECKING([for target address size])
 621   AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
 622 ])
 623 
 624 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
 625 [
 626   ###############################################################################
 627   #
 628   # Is the target little of big endian?
 629   #
 630   AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
 631 
 632   if test "x$ENDIAN" = xuniversal_endianness; then
 633     AC_MSG_ERROR([Building with both big and little endianness is not supported])
 634   fi
 635   if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
 636     AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
 637   fi
 638 ])