1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
  27 # Converts autoconf style CPU name to OpenJDK style, into
  28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
  29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
  30 [
  31   # First argument is the cpu name from the trip/quad
  32   case "$1" in
  33     x86_64*x32)
  34       VAR_CPU=x32
  35       VAR_CPU_ARCH=x86
  36       VAR_CPU_BITS=32
  37       VAR_CPU_ENDIAN=little
  38       ;;
  39     x86_64)
  40       VAR_CPU=x86_64
  41       VAR_CPU_ARCH=x86
  42       VAR_CPU_BITS=64
  43       VAR_CPU_ENDIAN=little
  44       ;;
  45     i?86)
  46       VAR_CPU=x86
  47       VAR_CPU_ARCH=x86
  48       VAR_CPU_BITS=32
  49       VAR_CPU_ENDIAN=little
  50       ;;
  51     alpha*)
  52       VAR_CPU=alpha
  53       VAR_CPU_ARCH=alpha
  54       VAR_CPU_BITS=64
  55       VAR_CPU_ENDIAN=little
  56       ;;
  57     arm*)
  58       VAR_CPU=arm
  59       VAR_CPU_ARCH=arm
  60       VAR_CPU_BITS=32
  61       VAR_CPU_ENDIAN=little
  62       ;;
  63     aarch64)
  64       VAR_CPU=aarch64
  65       VAR_CPU_ARCH=aarch64
  66       VAR_CPU_BITS=64
  67       VAR_CPU_ENDIAN=little
  68       ;;
  69     ia64)
  70       VAR_CPU=ia64
  71       VAR_CPU_ARCH=ia64
  72       VAR_CPU_BITS=64
  73       VAR_CPU_ENDIAN=little
  74       ;;
  75     m68k)
  76       VAR_CPU=m68k
  77       VAR_CPU_ARCH=m68k
  78       VAR_CPU_BITS=32
  79       VAR_CPU_ENDIAN=big
  80       ;;
  81     mips)
  82       VAR_CPU=mips
  83       VAR_CPU_ARCH=mips
  84       VAR_CPU_BITS=32
  85       VAR_CPU_ENDIAN=big
  86       ;;
  87     mipsel)
  88       VAR_CPU=mipsel
  89       VAR_CPU_ARCH=mipsel
  90       VAR_CPU_BITS=32
  91       VAR_CPU_ENDIAN=little
  92       ;;
  93     mips64)
  94       VAR_CPU=mips64
  95       VAR_CPU_ARCH=mips64
  96       VAR_CPU_BITS=64
  97       VAR_CPU_ENDIAN=big
  98       ;;
  99     mips64el)
 100       VAR_CPU=mips64el
 101       VAR_CPU_ARCH=mips64el
 102       VAR_CPU_BITS=64
 103       VAR_CPU_ENDIAN=little
 104       ;;
 105     powerpc)
 106       VAR_CPU=ppc
 107       VAR_CPU_ARCH=ppc
 108       VAR_CPU_BITS=32
 109       VAR_CPU_ENDIAN=big
 110       ;;
 111     powerpc64)
 112       VAR_CPU=ppc64
 113       VAR_CPU_ARCH=ppc
 114       VAR_CPU_BITS=64
 115       VAR_CPU_ENDIAN=big
 116       ;;
 117     powerpc64le)
 118       VAR_CPU=ppc64le
 119       VAR_CPU_ARCH=ppc
 120       VAR_CPU_BITS=64
 121       VAR_CPU_ENDIAN=little
 122       ;;
 123     s390)
 124       VAR_CPU=s390
 125       VAR_CPU_ARCH=s390
 126       VAR_CPU_BITS=32
 127       VAR_CPU_ENDIAN=big
 128       ;;
 129     s390x)
 130       VAR_CPU=s390x
 131       VAR_CPU_ARCH=s390
 132       VAR_CPU_BITS=64
 133       VAR_CPU_ENDIAN=big
 134       ;;
 135     sh*eb)
 136       VAR_CPU=sh
 137       VAR_CPU_ARCH=sh
 138       VAR_CPU_BITS=32
 139       VAR_CPU_ENDIAN=big
 140       ;;
 141     sh*)
 142       VAR_CPU=sh
 143       VAR_CPU_ARCH=sh
 144       VAR_CPU_BITS=32
 145       VAR_CPU_ENDIAN=little
 146       ;;
 147     sparc)
 148       VAR_CPU=sparc
 149       VAR_CPU_ARCH=sparc
 150       VAR_CPU_BITS=32
 151       VAR_CPU_ENDIAN=big
 152       ;;
 153     sparcv9|sparc64)
 154       VAR_CPU=sparcv9
 155       VAR_CPU_ARCH=sparc
 156       VAR_CPU_BITS=64
 157       VAR_CPU_ENDIAN=big
 158       ;;
 159     *)
 160       AC_MSG_ERROR([unsupported cpu $1])
 161       ;;
 162   esac
 163 ])
 164 
 165 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
 166 # Converts autoconf style OS name to OpenJDK style, into
 167 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
 168 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
 169 [
 170   case "$1" in
 171     *linux*)
 172       VAR_OS=linux
 173       VAR_OS_TYPE=unix
 174       ;;
 175     *solaris*)
 176       VAR_OS=solaris
 177       VAR_OS_TYPE=unix
 178       ;;
 179     *darwin*)
 180       VAR_OS=macosx
 181       VAR_OS_TYPE=unix
 182       ;;
 183     *bsd*)
 184       VAR_OS=bsd
 185       VAR_OS_TYPE=unix
 186       ;;
 187     *cygwin*)
 188       VAR_OS=windows
 189       VAR_OS_ENV=windows.cygwin
 190       ;;
 191     *wsl*)
 192       VAR_OS=windows
 193       VAR_OS_ENV=windows.wsl
 194       ;;
 195     *mingw*)
 196       VAR_OS=windows
 197       VAR_OS_ENV=windows.msys
 198       ;;
 199     *aix*)
 200       VAR_OS=aix
 201       VAR_OS_TYPE=unix
 202       ;;
 203     *)
 204       AC_MSG_ERROR([unsupported operating system $1])
 205       ;;
 206   esac
 207 
 208   case "$1" in
 209     *linux*-musl)
 210       VAR_LIBC=musl
 211       ;;
 212     *linux*-gnu)
 213       VAR_LIBC=gnu
 214       ;;
 215     *)
 216       VAR_LIBC=default
 217       ;;
 218   esac
 219 ])
 220 
 221 # Expects $host_os $host_cpu $build_os and $build_cpu
 222 # and $with_target_bits to have been setup!
 223 #
 224 # Translate the standard triplet(quadruplet) definition
 225 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
 226 # OPENJDK_BUILD_OS, etc.
 227 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
 228 [
 229   # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
 230   # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
 231   # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
 232   # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
 233   OPENJDK_TARGET_AUTOCONF_NAME="$host"
 234   OPENJDK_BUILD_AUTOCONF_NAME="$build"
 235   AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
 236   AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
 237 
 238   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
 239   PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
 240   PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
 241   # ..and setup our own variables. (Do this explicitly to facilitate searching)
 242   OPENJDK_BUILD_OS="$VAR_OS"
 243   if test "x$VAR_OS_TYPE" != x; then
 244     OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
 245   else
 246     OPENJDK_BUILD_OS_TYPE="$VAR_OS"
 247   fi
 248   if test "x$VAR_OS_ENV" != x; then
 249     OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
 250   else
 251     OPENJDK_BUILD_OS_ENV="$VAR_OS"
 252   fi
 253   OPENJDK_BUILD_CPU="$VAR_CPU"
 254   OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
 255   OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
 256   OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
 257   OPENJDK_BUILD_LIBC="$VAR_LIBC"
 258   AC_SUBST(OPENJDK_BUILD_OS)
 259   AC_SUBST(OPENJDK_BUILD_OS_TYPE)
 260   AC_SUBST(OPENJDK_BUILD_OS_ENV)
 261   AC_SUBST(OPENJDK_BUILD_CPU)
 262   AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
 263   AC_SUBST(OPENJDK_BUILD_CPU_BITS)
 264   AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
 265   AC_SUBST(OPENJDK_BUILD_LIBC)
 266 
 267   AC_MSG_CHECKING([openjdk-build os-cpu])
 268   AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
 269 
 270   if test "x$OPENJDK_BUILD_OS" = "xlinux"; then
 271     AC_MSG_CHECKING([openjdk-build C library])
 272     AC_MSG_RESULT([$OPENJDK_BUILD_LIBC])
 273   fi
 274 
 275   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
 276   PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
 277   PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
 278   # ... and setup our own variables. (Do this explicitly to facilitate searching)
 279   OPENJDK_TARGET_OS="$VAR_OS"
 280   if test "x$VAR_OS_TYPE" != x; then
 281     OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
 282   else
 283     OPENJDK_TARGET_OS_TYPE="$VAR_OS"
 284   fi
 285   if test "x$VAR_OS_ENV" != x; then
 286     OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
 287   else
 288     OPENJDK_TARGET_OS_ENV="$VAR_OS"
 289   fi
 290   OPENJDK_TARGET_CPU="$VAR_CPU"
 291   OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
 292   OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
 293   OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
 294   OPENJDK_TARGET_OS_UPPERCASE=`$ECHO $OPENJDK_TARGET_OS | $TR 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 295   OPENJDK_TARGET_LIBC="$VAR_LIBC"
 296 
 297   AC_SUBST(OPENJDK_TARGET_OS)
 298   AC_SUBST(OPENJDK_TARGET_OS_TYPE)
 299   AC_SUBST(OPENJDK_TARGET_OS_ENV)
 300   AC_SUBST(OPENJDK_TARGET_OS_UPPERCASE)
 301   AC_SUBST(OPENJDK_TARGET_CPU)
 302   AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
 303   AC_SUBST(OPENJDK_TARGET_CPU_BITS)
 304   AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
 305   AC_SUBST(OPENJDK_TARGET_LIBC)
 306 
 307   AC_MSG_CHECKING([openjdk-target os-cpu])
 308   AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
 309 
 310   if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
 311     AC_MSG_CHECKING([openjdk-target C library])
 312     AC_MSG_RESULT([$OPENJDK_TARGET_LIBC])
 313   fi
 314 ])
 315 
 316 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
 317 # accordingly. Must be done after setting up build and target system, but before
 318 # doing anything else with these values.
 319 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
 320 [
 321   AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
 322        [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
 323 
 324   # We have three types of compiles:
 325   # native  == normal compilation, target system == build system
 326   # cross   == traditional cross compilation, target system != build system; special toolchain needed
 327   # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
 328   #
 329   if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
 330     # We're doing a proper cross-compilation
 331     COMPILE_TYPE="cross"
 332   else
 333     COMPILE_TYPE="native"
 334   fi
 335 
 336   if test "x$with_target_bits" != x; then
 337     if test "x$COMPILE_TYPE" = "xcross"; then
 338       AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
 339     fi
 340 
 341     if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 342       # A reduced build is requested
 343       COMPILE_TYPE="reduced"
 344       OPENJDK_TARGET_CPU_BITS=32
 345       if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
 346         OPENJDK_TARGET_CPU=x86
 347       elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
 348         OPENJDK_TARGET_CPU=sparc
 349       else
 350         AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
 351       fi
 352     elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
 353       AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
 354     elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
 355       AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
 356     else
 357       AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
 358     fi
 359   fi
 360   AC_SUBST(COMPILE_TYPE)
 361 
 362   AC_MSG_CHECKING([compilation type])
 363   AC_MSG_RESULT([$COMPILE_TYPE])
 364 ])
 365 
 366 # Setup the legacy variables, for controlling the old makefiles.
 367 #
 368 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
 369 [
 370   PLATFORM_SETUP_LEGACY_VARS_HELPER([TARGET])
 371   PLATFORM_SETUP_LEGACY_VARS_HELPER([BUILD])
 372 ])
 373 
 374 # $1 - Either TARGET or BUILD to setup the variables for.
 375 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS_HELPER],
 376 [
 377   # Also store the legacy naming of the cpu.
 378   # Ie i586 and amd64 instead of x86 and x86_64
 379   OPENJDK_$1_CPU_LEGACY="$OPENJDK_$1_CPU"
 380   if test "x$OPENJDK_$1_CPU" = xx86; then
 381     OPENJDK_$1_CPU_LEGACY="i586"
 382   elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
 383     # On all platforms except MacOSX replace x86_64 with amd64.
 384     OPENJDK_$1_CPU_LEGACY="amd64"
 385   elif test "x$OPENJDK_$1_CPU" = xalpha; then
 386     # Avoid name collisions with variables named alpha
 387     OPENJDK_$1_CPU_LEGACY="_alpha_"
 388   elif test "x$OPENJDK_$1_CPU" = xsh; then
 389     # Avoid name collisions with variables named sh
 390     OPENJDK_$1_CPU_LEGACY="_sh_"
 391   fi
 392   AC_SUBST(OPENJDK_$1_CPU_LEGACY)
 393 
 394   # And the second legacy naming of the cpu.
 395   # Ie i386 and amd64 instead of x86 and x86_64.
 396   OPENJDK_$1_CPU_LEGACY_LIB="$OPENJDK_$1_CPU"
 397   if test "x$OPENJDK_$1_CPU" = xx86; then
 398     OPENJDK_$1_CPU_LEGACY_LIB="i386"
 399   elif test "x$OPENJDK_$1_CPU" = xx86_64; then
 400     OPENJDK_$1_CPU_LEGACY_LIB="amd64"
 401   fi
 402   AC_SUBST(OPENJDK_$1_CPU_LEGACY_LIB)
 403 
 404   # OPENJDK_$1_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
 405   # /amd64 or /sparcv9. This string is appended to some library paths, like this:
 406   # /usr/lib${OPENJDK_$1_CPU_ISADIR}/libexample.so
 407   OPENJDK_$1_CPU_ISADIR=""
 408   if test "x$OPENJDK_$1_OS" = xsolaris; then
 409     if test "x$OPENJDK_$1_CPU" = xx86_64; then
 410       OPENJDK_$1_CPU_ISADIR="/amd64"
 411     elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
 412       OPENJDK_$1_CPU_ISADIR="/sparcv9"
 413     fi
 414   fi
 415   AC_SUBST(OPENJDK_$1_CPU_ISADIR)
 416 
 417   # Setup OPENJDK_$1_CPU_OSARCH, which is used to set the os.arch Java system property
 418   OPENJDK_$1_CPU_OSARCH="$OPENJDK_$1_CPU"
 419   if test "x$OPENJDK_$1_OS" = xlinux && test "x$OPENJDK_$1_CPU" = xx86; then
 420     # On linux only, we replace x86 with i386.
 421     OPENJDK_$1_CPU_OSARCH="i386"
 422   elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
 423     # On all platforms except macosx, we replace x86_64 with amd64.
 424     OPENJDK_$1_CPU_OSARCH="amd64"
 425   fi
 426   AC_SUBST(OPENJDK_$1_CPU_OSARCH)
 427 
 428   OPENJDK_$1_CPU_JLI="$OPENJDK_$1_CPU"
 429   if test "x$OPENJDK_$1_CPU" = xx86; then
 430     OPENJDK_$1_CPU_JLI="i386"
 431   elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
 432     # On all platforms except macosx, we replace x86_64 with amd64.
 433     OPENJDK_$1_CPU_JLI="amd64"
 434   fi
 435 
 436   # The new version string in JDK 9 also defined new naming of OS and ARCH for bundles
 437   # Macosx is osx and x86_64 is x64
 438   if test "x$OPENJDK_$1_OS" = xmacosx; then
 439     OPENJDK_$1_OS_BUNDLE="osx"
 440   else
 441     OPENJDK_$1_OS_BUNDLE="$OPENJDK_TARGET_OS"
 442   fi
 443   if test "x$OPENJDK_$1_CPU" = xx86_64; then
 444     OPENJDK_$1_CPU_BUNDLE="x64"
 445   else
 446     OPENJDK_$1_CPU_BUNDLE="$OPENJDK_$1_CPU"
 447   fi
 448 
 449   OPENJDK_$1_LIBC_BUNDLE=""
 450   if test "x$OPENJDK_$1_LIBC" = "xmusl"; then  
 451     OPENJDK_$1_LIBC_BUNDLE="-$OPENJDK_$1_LIBC"
 452   fi
 453 
 454   OPENJDK_$1_BUNDLE_PLATFORM="${OPENJDK_$1_OS_BUNDLE}-${OPENJDK_$1_CPU_BUNDLE}${OPENJDK_$1_LIBC_BUNDLE}"
 455   AC_SUBST(OPENJDK_$1_BUNDLE_PLATFORM)
 456 
 457   if test "x$COMPILE_TYPE" = "xcross"; then
 458     # FIXME: ... or should this include reduced builds..?
 459     DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_$1_CPU_LEGACY"
 460   else
 461     DEFINE_CROSS_COMPILE_ARCH=""
 462   fi
 463   AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
 464 
 465   # Convert openjdk platform names to hotspot names
 466 
 467   HOTSPOT_$1_OS=${OPENJDK_$1_OS}
 468   if test "x$OPENJDK_$1_OS" = xmacosx; then
 469     HOTSPOT_$1_OS=bsd
 470   fi
 471   AC_SUBST(HOTSPOT_$1_OS)
 472 
 473   HOTSPOT_$1_OS_TYPE=${OPENJDK_$1_OS_TYPE}
 474   if test "x$OPENJDK_$1_OS_TYPE" = xunix; then
 475     HOTSPOT_$1_OS_TYPE=posix
 476   fi
 477   AC_SUBST(HOTSPOT_$1_OS_TYPE)
 478 
 479   HOTSPOT_$1_CPU=${OPENJDK_$1_CPU}
 480   if test "x$OPENJDK_$1_CPU" = xx86; then
 481     HOTSPOT_$1_CPU=x86_32
 482   elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
 483     HOTSPOT_$1_CPU=sparc
 484   elif test "x$OPENJDK_$1_CPU" = xppc64; then
 485     HOTSPOT_$1_CPU=ppc_64
 486   elif test "x$OPENJDK_$1_CPU" = xppc64le; then
 487     HOTSPOT_$1_CPU=ppc_64
 488   fi
 489   AC_SUBST(HOTSPOT_$1_CPU)
 490 
 491   # This is identical with OPENJDK_*, but define anyway for consistency.
 492   HOTSPOT_$1_CPU_ARCH=${OPENJDK_$1_CPU_ARCH}
 493   AC_SUBST(HOTSPOT_$1_CPU_ARCH)
 494 
 495   # Setup HOTSPOT_$1_CPU_DEFINE
 496   if test "x$OPENJDK_$1_CPU" = xx86; then
 497     HOTSPOT_$1_CPU_DEFINE=IA32
 498   elif test "x$OPENJDK_$1_CPU" = xx86_64; then
 499     HOTSPOT_$1_CPU_DEFINE=AMD64
 500   elif test "x$OPENJDK_$1_CPU" = xx32; then
 501     HOTSPOT_$1_CPU_DEFINE=X32
 502   elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
 503     HOTSPOT_$1_CPU_DEFINE=SPARC
 504   elif test "x$OPENJDK_$1_CPU" = xaarch64; then
 505     HOTSPOT_$1_CPU_DEFINE=AARCH64
 506   elif test "x$OPENJDK_$1_CPU" = xppc64; then
 507     HOTSPOT_$1_CPU_DEFINE=PPC64
 508   elif test "x$OPENJDK_$1_CPU" = xppc64le; then
 509     HOTSPOT_$1_CPU_DEFINE=PPC64
 510 
 511   # The cpu defines below are for zero, we don't support them directly.
 512   elif test "x$OPENJDK_$1_CPU" = xsparc; then
 513     HOTSPOT_$1_CPU_DEFINE=SPARC
 514   elif test "x$OPENJDK_$1_CPU" = xppc; then
 515     HOTSPOT_$1_CPU_DEFINE=PPC32
 516   elif test "x$OPENJDK_$1_CPU" = xs390; then
 517     HOTSPOT_$1_CPU_DEFINE=S390
 518   elif test "x$OPENJDK_$1_CPU" = xs390x; then
 519     HOTSPOT_$1_CPU_DEFINE=S390
 520   elif test "x$OPENJDK_$1_CPU" != x; then
 521     HOTSPOT_$1_CPU_DEFINE=$(echo $OPENJDK_$1_CPU | tr a-z A-Z)
 522   fi
 523   AC_SUBST(HOTSPOT_$1_CPU_DEFINE)
 524 
 525   if test "x$OPENJDK_$1_LIBC" = "xmusl"; then
 526     HOTSPOT_$1_LIBC=$OPENJDK_$1_LIBC
 527   else
 528     HOTSPOT_$1_LIBC=""
 529   fi
 530   AC_SUBST(HOTSPOT_$1_LIBC)
 531 
 532   # For historical reasons, the OS include directories have odd names.
 533   OPENJDK_$1_OS_INCLUDE_SUBDIR="$OPENJDK_TARGET_OS"
 534   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 535     OPENJDK_$1_OS_INCLUDE_SUBDIR="win32"
 536   elif test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 537     OPENJDK_$1_OS_INCLUDE_SUBDIR="darwin"
 538   fi
 539   AC_SUBST(OPENJDK_$1_OS_INCLUDE_SUBDIR)
 540 ])
 541 
 542 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
 543 [
 544   if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
 545     RELEASE_FILE_OS_NAME=SunOS
 546   fi
 547   if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
 548     RELEASE_FILE_OS_NAME=Linux
 549   fi
 550   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 551     RELEASE_FILE_OS_NAME=Windows
 552   fi
 553   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 554     RELEASE_FILE_OS_NAME="Darwin"
 555   fi
 556   if test "x$OPENJDK_TARGET_OS" = "xaix"; then
 557     RELEASE_FILE_OS_NAME="AIX"
 558   fi
 559   RELEASE_FILE_OS_ARCH=${OPENJDK_TARGET_CPU}
 560 
 561   AC_SUBST(RELEASE_FILE_OS_NAME)
 562   AC_SUBST(RELEASE_FILE_OS_ARCH)
 563 ])
 564 
 565 AC_DEFUN([PLATFORM_SET_MODULE_TARGET_OS_VALUES],
 566 [
 567   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 568     OPENJDK_MODULE_TARGET_OS_NAME="macos"
 569   else
 570     OPENJDK_MODULE_TARGET_OS_NAME="$OPENJDK_TARGET_OS"
 571   fi
 572 
 573   if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 574     OPENJDK_MODULE_TARGET_OS_ARCH="amd64"
 575   else
 576     OPENJDK_MODULE_TARGET_OS_ARCH="$OPENJDK_TARGET_CPU"
 577   fi
 578 
 579   OPENJDK_MODULE_TARGET_PLATFORM="${OPENJDK_MODULE_TARGET_OS_NAME}-${OPENJDK_MODULE_TARGET_OS_ARCH}"
 580   AC_SUBST(OPENJDK_MODULE_TARGET_PLATFORM)
 581 ])
 582 
 583 #%%% Build and target systems %%%
 584 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
 585 [
 586   # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
 587   # is confusing; it assumes you are cross-compiling a cross-compiler (!)  and "target" is thus the target of the
 588   # product you're building. The target of this build is called "host". Since this is confusing to most people, we
 589   # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
 590   # to use the configure naming style.
 591   AC_CANONICAL_BUILD
 592   AC_CANONICAL_HOST
 593   AC_CANONICAL_TARGET
 594 
 595   PLATFORM_EXTRACT_TARGET_AND_BUILD
 596   PLATFORM_SETUP_TARGET_CPU_BITS
 597   PLATFORM_SET_MODULE_TARGET_OS_VALUES
 598   PLATFORM_SET_RELEASE_FILE_OS_VALUES
 599   PLATFORM_SETUP_LEGACY_VARS
 600 ])
 601 
 602 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
 603 [
 604   ###############################################################################
 605 
 606   # Note that this is the build platform OS version!
 607 
 608   OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
 609   OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
 610   OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
 611   OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
 612   AC_SUBST(OS_VERSION_MAJOR)
 613   AC_SUBST(OS_VERSION_MINOR)
 614   AC_SUBST(OS_VERSION_MICRO)
 615 ])
 616 
 617 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
 618 [
 619   ###############################################################################
 620   #
 621   # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
 622   # (The JVM can use 32 or 64 bit Java pointers but that decision
 623   # is made at runtime.)
 624   #
 625 
 626   # Make compilation sanity check
 627   AC_CHECK_HEADERS([stdio.h], , [
 628     AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
 629     if test "x$COMPILE_TYPE" = xreduced; then
 630       HELP_MSG_MISSING_DEPENDENCY([reduced])
 631       AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
 632     elif test "x$COMPILE_TYPE" = xcross; then
 633       AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
 634     fi
 635     AC_MSG_ERROR([Cannot continue.])
 636   ])
 637 
 638   AC_CHECK_SIZEOF([int *], [1111])
 639 
 640   # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
 641   if test "x$ac_cv_sizeof_int_p" = x; then
 642     # The test failed, lets stick to the assumed value.
 643     AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
 644   else
 645     TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
 646 
 647     if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
 648       AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
 649       if test "x$COMPILE_TYPE" = xreduced; then
 650         HELP_MSG_MISSING_DEPENDENCY([reduced])
 651         AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
 652       elif test "x$COMPILE_TYPE" = xcross; then
 653         AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
 654       fi
 655       AC_MSG_ERROR([Cannot continue.])
 656     fi
 657   fi
 658 
 659   AC_MSG_CHECKING([for target address size])
 660   AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
 661 ])
 662 
 663 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
 664 [
 665   ###############################################################################
 666   #
 667   # Is the target little of big endian?
 668   #
 669   AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
 670 
 671   if test "x$ENDIAN" = xuniversal_endianness; then
 672     AC_MSG_ERROR([Building with both big and little endianness is not supported])
 673   fi
 674   if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
 675     AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
 676   fi
 677 ])