1 #
2 # Copyright (c) 2011, 2022, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Major library component reside in separate files.
27 m4_include([lib-alsa.m4])
28 m4_include([lib-bundled.m4])
29 m4_include([lib-cups.m4])
30 m4_include([lib-ffi.m4])
31 m4_include([lib-freetype.m4])
32 m4_include([lib-std.m4])
33 m4_include([lib-x11.m4])
34 m4_include([lib-fontconfig.m4])
35 m4_include([lib-tests.m4])
36
37 ################################################################################
38 # Determine which libraries are needed for this configuration
39 ################################################################################
40 AC_DEFUN_ONCE([LIB_DETERMINE_DEPENDENCIES],
41 [
42 # Check if X11 is needed
43 if test "x$OPENJDK_TARGET_OS" = xwindows || test "x$OPENJDK_TARGET_OS" = xmacosx; then
44 # No X11 support on windows or macosx
45 NEEDS_LIB_X11=false
46 elif test "x$ENABLE_HEADLESS_ONLY" = xtrue; then
47 # No X11 support needed when building headless only
48 NEEDS_LIB_X11=false
49 else
50 # All other instances need X11
51 NEEDS_LIB_X11=true
52 fi
53
54 # Check if fontconfig is needed
55 if test "x$OPENJDK_TARGET_OS" = xwindows || test "x$OPENJDK_TARGET_OS" = xmacosx; then
56 # No fontconfig support on windows or macosx
57 NEEDS_LIB_FONTCONFIG=false
58 else
59 # All other instances need fontconfig, even if building headless only,
60 # libawt still needs fontconfig headers.
61 NEEDS_LIB_FONTCONFIG=true
62 fi
63
64 # Check if cups is needed
65 if test "x$OPENJDK_TARGET_OS" = xwindows; then
66 # Windows have a separate print system
67 NEEDS_LIB_CUPS=false
68 else
69 NEEDS_LIB_CUPS=true
70 fi
71
72 # A custom hook may have set this already
73 if test "x$NEEDS_LIB_FREETYPE" = "x"; then
74 NEEDS_LIB_FREETYPE=true
75 fi
76
77 # Check if alsa is needed
78 if test "x$OPENJDK_TARGET_OS" = xlinux; then
79 NEEDS_LIB_ALSA=true
80 else
81 NEEDS_LIB_ALSA=false
82 fi
83
84 # Check if ffi is needed
85 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
86 NEEDS_LIB_FFI=true
87 else
88 NEEDS_LIB_FFI=false
89 fi
90 ])
91
92 ################################################################################
93 # Parse library options, and setup needed libraries
94 ################################################################################
95 AC_DEFUN_ONCE([LIB_SETUP_LIBRARIES],
96 [
97 LIB_SETUP_STD_LIBS
98 LIB_SETUP_X11
99 LIB_SETUP_CUPS
100 LIB_SETUP_FONTCONFIG
101 LIB_SETUP_FREETYPE
102 LIB_SETUP_ALSA
103 LIB_SETUP_LIBFFI
104 LIB_SETUP_BUNDLED_LIBS
105 LIB_SETUP_MISC_LIBS
106 LIB_TESTS_SETUP_GTEST
107
108 BASIC_JDKLIB_LIBS=""
109 if test "x$TOOLCHAIN_TYPE" != xmicrosoft; then
110 BASIC_JDKLIB_LIBS="-ljava -ljvm"
111 fi
112
113 # Math library
114 BASIC_JVM_LIBS="$LIBM"
115
116 # Dynamic loading library
117 if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xaix; then
118 BASIC_JVM_LIBS="$BASIC_JVM_LIBS $LIBDL"
119 fi
120
121 # Threading library
122 if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xaix; then
123 BASIC_JVM_LIBS="$BASIC_JVM_LIBS -lpthread"
124 fi
125
126 # librt for legacy clock_gettime
127 if test "x$OPENJDK_TARGET_OS" = xlinux; then
128 # Hotspot needs to link librt to get the clock_* functions.
129 # But once our supported minimum build and runtime platform
130 # has glibc 2.17, this can be removed as the functions are
131 # in libc.
132 BASIC_JVM_LIBS="$BASIC_JVM_LIBS -lrt"
133 fi
134
135 # Atomic library
136 # 32-bit platforms needs fallback library for 8-byte atomic ops on Zero
137 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
138 if test "x$OPENJDK_TARGET_OS" = xlinux &&
139 (test "x$OPENJDK_TARGET_CPU" = xarm ||
140 test "x$OPENJDK_TARGET_CPU" = xm68k ||
141 test "x$OPENJDK_TARGET_CPU" = xmips ||
142 test "x$OPENJDK_TARGET_CPU" = xmipsel ||
143 test "x$OPENJDK_TARGET_CPU" = xppc ||
144 test "x$OPENJDK_TARGET_CPU" = xsh); then
145 BASIC_JVM_LIBS="$BASIC_JVM_LIBS -latomic"
146 fi
147 fi
148
149 # Because RISC-V only has word-sized atomics, it requries libatomic where
150 # other common architectures do not. So link libatomic by default.
151 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$OPENJDK_TARGET_CPU" = xriscv64; then
152 BASIC_JVM_LIBS="$BASIC_JVM_LIBS -latomic"
153 fi
154
155 # perfstat lib
156 if test "x$OPENJDK_TARGET_OS" = xaix; then
157 BASIC_JVM_LIBS="$BASIC_JVM_LIBS -lperfstat"
158 fi
159
160 if test "x$OPENJDK_TARGET_OS" = xwindows; then
161 BASIC_JVM_LIBS="$BASIC_JVM_LIBS kernel32.lib user32.lib gdi32.lib winspool.lib \
162 comdlg32.lib advapi32.lib shell32.lib ole32.lib oleaut32.lib uuid.lib \
163 wsock32.lib winmm.lib version.lib psapi.lib"
164 fi
165
166 JDKLIB_LIBS="$BASIC_JDKLIB_LIBS"
167 JDKEXE_LIBS=""
168 JVM_LIBS="$BASIC_JVM_LIBS"
169 OPENJDK_BUILD_JDKLIB_LIBS="$BASIC_JDKLIB_LIBS"
170 OPENJDK_BUILD_JVM_LIBS="$BASIC_JVM_LIBS"
171
172 AC_SUBST(JDKLIB_LIBS)
173 AC_SUBST(JDKEXE_LIBS)
174 AC_SUBST(JVM_LIBS)
175 AC_SUBST(OPENJDK_BUILD_JDKLIB_LIBS)
176 AC_SUBST(OPENJDK_BUILD_JVM_LIBS)
177 ])
178
179 ################################################################################
180 # Setup various libraries, typically small system libraries
181 ################################################################################
182 AC_DEFUN_ONCE([LIB_SETUP_MISC_LIBS],
183 [
184 # Setup libm (the maths library)
185 if test "x$OPENJDK_TARGET_OS" != "xwindows"; then
186 AC_CHECK_LIB(m, cos, [], [
187 AC_MSG_NOTICE([Maths library was not found])
188 ])
189 LIBM="-lm"
190 else
191 LIBM=""
192 fi
193 AC_SUBST(LIBM)
194
195 # Setup libdl (for dynamic library loading)
196 save_LIBS="$LIBS"
197 LIBS=""
198 AC_CHECK_LIB(dl, dlopen)
199 LIBDL="$LIBS"
200 AC_SUBST(LIBDL)
201 LIBS="$save_LIBS"
202
203 # Control if libzip can use mmap. Available for purposes of overriding.
204 LIBZIP_CAN_USE_MMAP=true
205 AC_SUBST(LIBZIP_CAN_USE_MMAP)
206 ])