1 #
  2 # Copyright (c) 2011, 2021, Oracle and/or its affiliates. All rights reserved.
  3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
  4 #
  5 # This code is free software; you can redistribute it and/or modify it
  6 # under the terms of the GNU General Public License version 2 only, as
  7 # published by the Free Software Foundation.  Oracle designates this
  8 # particular file as subject to the "Classpath" exception as provided
  9 # by Oracle in the LICENSE file that accompanied this code.
 10 #
 11 # This code is distributed in the hope that it will be useful, but WITHOUT
 12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
 13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
 14 # version 2 for more details (a copy is included in the LICENSE file that
 15 # accompanied this code).
 16 #
 17 # You should have received a copy of the GNU General Public License version
 18 # 2 along with this work; if not, write to the Free Software Foundation,
 19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
 20 #
 21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
 22 # or visit www.oracle.com if you need additional information or have any
 23 # questions.
 24 #
 25 
 26 ###############################################################################
 27 # Terminology used in this file:
 28 #
 29 # Valid features      == All possible features that the JVM knows about.
 30 # Deprecated features == Previously known features (not considered valid).
 31 # Available features  == Features that are possible to use in this configuration.
 32 # Default features    == Features that are on by default in this configuration.
 33 # Enabled features    == Features requested by the user to be present.
 34 # Disabled features   == Features excluded from being used by the user.
 35 # Active features     == The exact set of features to be used for a JVM variant.
 36 #
 37 # All valid features are considered available, unless listed as unavailable.
 38 # All available features will be turned on as default, unless listed in a filter.
 39 ###############################################################################
 40 
 41 # We need these as m4 defines to be able to loop over them using m4 later on.
 42 
 43 # All valid JVM features, regardless of platform
 44 m4_define(jvm_features_valid, m4_normalize( \
 45     ifdef([custom_jvm_features_valid], custom_jvm_features_valid) \
 46     \
 47     cds compiler1 compiler2 dtrace epsilongc g1gc jfr jni-check \
 48     jvmci jvmti link-time-opt management minimal nmt opt-size parallelgc \
 49     serialgc services shenandoahgc static-build vm-structs zero zgc \
 50 ))
 51 
 52 # Deprecated JVM features (these are ignored, but with a warning)
 53 m4_define(jvm_features_deprecated, m4_normalize(
 54     cmsgc trace \
 55 ))
 56 
 57 # Feature descriptions
 58 m4_define(jvm_feature_desc_cds, [enable class data sharing (CDS)])
 59 m4_define(jvm_feature_desc_compiler1, [enable hotspot compiler C1])
 60 m4_define(jvm_feature_desc_compiler2, [enable hotspot compiler C2])
 61 m4_define(jvm_feature_desc_dtrace, [enable dtrace support])
 62 m4_define(jvm_feature_desc_epsilongc, [include the epsilon (no-op) garbage collector])
 63 m4_define(jvm_feature_desc_g1gc, [include the G1 garbage collector])
 64 m4_define(jvm_feature_desc_jfr, [enable JDK Flight Recorder (JFR)])
 65 m4_define(jvm_feature_desc_jni_check, [enable -Xcheck:jni support])
 66 m4_define(jvm_feature_desc_jvmci, [enable JVM Compiler Interface (JVMCI)])
 67 m4_define(jvm_feature_desc_jvmti, [enable Java Virtual Machine Tool Interface (JVM TI)])
 68 m4_define(jvm_feature_desc_link_time_opt, [enable link time optimization])
 69 m4_define(jvm_feature_desc_management, [enable java.lang.management API support])
 70 m4_define(jvm_feature_desc_minimal, [support building variant 'minimal'])
 71 m4_define(jvm_feature_desc_nmt, [include native memory tracking (NMT)])
 72 m4_define(jvm_feature_desc_opt_size, [optimize the JVM library for size])
 73 m4_define(jvm_feature_desc_parallelgc, [include the parallel garbage collector])
 74 m4_define(jvm_feature_desc_serialgc, [include the serial garbage collector])
 75 m4_define(jvm_feature_desc_services, [enable diagnostic services and client attaching])
 76 m4_define(jvm_feature_desc_shenandoahgc, [include the Shenandoah garbage collector])
 77 m4_define(jvm_feature_desc_static_build, [build static library instead of dynamic])
 78 m4_define(jvm_feature_desc_vm_structs, [export JVM structures to the Serviceablility Agent])
 79 m4_define(jvm_feature_desc_zero, [support building variant 'zero'])
 80 m4_define(jvm_feature_desc_zgc, [include the Z garbage collector])
 81 
 82 ###############################################################################
 83 # Parse command line options for JVM feature selection. After this function
 84 # has run $JVM_FEATURES_ENABLED, $JVM_FEATURES_DISABLED and $JVM_FEATURES_VALID
 85 # can be used.
 86 #
 87 AC_DEFUN_ONCE([JVM_FEATURES_PARSE_OPTIONS],
 88 [
 89   # Setup shell variables from the m4 lists
 90   UTIL_SORT_LIST(JVM_FEATURES_VALID, "jvm_features_valid")
 91   UTIL_SORT_LIST(JVM_FEATURES_DEPRECATED, "jvm_features_deprecated")
 92 
 93   # For historical reasons, some jvm features have their own, shorter names.
 94   # Keep those as aliases for the --enable-jvm-feature-* style arguments.
 95   UTIL_ALIASED_ARG_ENABLE(cds, --enable-jvm-feature-cds)
 96   UTIL_ALIASED_ARG_ENABLE(dtrace, --enable-jvm-feature-dtrace)
 97 
 98   # First check for features using the
 99   # --with-jvm-features="<[-]feature>[,<[-]feature> ...]" syntax.
100   AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
101       [JVM features to enable (foo) or disable (-foo), separated by comma. Use
102       '--help' to show possible values @<:@none@:>@])])
103   if test "x$with_jvm_features" != x; then
104     # Replace ","  with " ".
105     user_jvm_feature_list=${with_jvm_features//,/ }
106     JVM_FEATURES_ENABLED=`$ECHO $user_jvm_feature_list | \
107         $AWK '{ for (i=1; i<=NF; i++) if (!match($i, /^-.*/)) printf("%s ", $i) }'`
108     JVM_FEATURES_DISABLED=`$ECHO $user_jvm_feature_list | \
109         $AWK '{ for (i=1; i<=NF; i++) if (match($i, /^-.*/)) printf("%s ", substr($i, 2))}'`
110 
111     # Verify that the user has provided only valid (or deprecated) features
112     UTIL_GET_NON_MATCHING_VALUES(invalid_features, $JVM_FEATURES_ENABLED \
113         $JVM_FEATURES_DISABLED, $JVM_FEATURES_VALID $JVM_FEATURES_DEPRECATED)
114     if test "x$invalid_features" != x; then
115       AC_MSG_NOTICE([Unknown JVM features specified: '$invalid_features'])
116       AC_MSG_NOTICE([The available JVM features are: '$JVM_FEATURES_VALID'])
117       AC_MSG_ERROR([Cannot continue])
118     fi
119 
120     # Check if the user has provided deprecated features
121     UTIL_GET_MATCHING_VALUES(deprecated_features, $JVM_FEATURES_ENABLED \
122         $JVM_FEATURES_DISABLED, $JVM_FEATURES_DEPRECATED)
123     if test "x$deprecated_features" != x; then
124       AC_MSG_WARN([Deprecated JVM features specified (will be ignored): '$deprecated_features'])
125       # Filter out deprecated features
126       UTIL_GET_NON_MATCHING_VALUES(JVM_FEATURES_ENABLED, \
127           $JVM_FEATURES_ENABLED, $deprecated_features)
128       UTIL_GET_NON_MATCHING_VALUES(JVM_FEATURES_DISABLED, \
129           $JVM_FEATURES_DISABLED, $deprecated_features)
130     fi
131   fi
132 
133   # Then check for features using the "--enable-jvm-feature-<feature>" syntax.
134   # Using m4, loop over all features with the variable FEATURE.
135   m4_foreach(FEATURE, m4_split(jvm_features_valid), [
136     # Create an m4 variable containing a shell variable name (like
137     # "enable_jvm_feature_static_build"), and the description.
138     m4_define(FEATURE_SHELL, [enable_jvm_feature_]m4_translit(FEATURE, -, _))
139     m4_define(FEATURE_DESCRIPTION, [jvm_feature_desc_]m4_translit(FEATURE, -, _))
140 
141     AC_ARG_ENABLE(jvm-feature-FEATURE, AS_HELP_STRING(
142         [--enable-jvm-feature-FEATURE], [enable jvm feature 'FEATURE' (FEATURE_DESCRIPTION)]))
143 
144     if test "x$FEATURE_SHELL" = xyes; then
145       JVM_FEATURES_ENABLED="$JVM_FEATURES_ENABLED FEATURE"
146     elif test "x$FEATURE_SHELL" = xno; then
147       JVM_FEATURES_DISABLED="$JVM_FEATURES_DISABLED FEATURE"
148     elif test "x$FEATURE_SHELL" != x; then
149       AC_MSG_ERROR([Invalid value for --enable-jvm-feature-FEATURE: '$FEATURE_SHELL'])
150     fi
151 
152     m4_undefine([FEATURE_SHELL])
153     m4_undefine([FEATURE_DESCRIPTION])
154   ])
155 
156   # Likewise, check for deprecated arguments.
157   m4_foreach(FEATURE, m4_split(jvm_features_deprecated), [
158     AC_ARG_ENABLE(jvm-feature-FEATURE, AS_HELP_STRING(
159         [--enable-jvm-feature-FEATURE],
160         [Deprecated. Option is kept for backwards compatibility and is ignored]))
161 
162     m4_define(FEATURE_SHELL, [enable_jvm_feature_]m4_translit(FEATURE, -, _))
163 
164     if test "x$FEATURE_SHELL" != x; then
165       AC_MSG_WARN([Deprecated JVM feature, will be ignored: --enable-jvm-feature-FEATURE])
166     fi
167 
168     m4_undefine([FEATURE_SHELL])
169   ])
170 
171   # Check if the user has both enabled and disabled a feature
172   UTIL_GET_MATCHING_VALUES(enabled_and_disabled, $JVM_FEATURES_ENABLED, \
173       $JVM_FEATURES_DISABLED)
174   if test "x$enabled_and_disabled" != x; then
175     AC_MSG_NOTICE([These feature are both enabled and disabled: '$enabled_and_disabled'])
176     AC_MSG_NOTICE([This can happen if you mix --with-jvm-features and --enable-jvm-feature-*])
177     AC_MSG_NOTICE([The recommendation is to only use --enable-jvm-feature-*])
178     AC_MSG_ERROR([Cannot continue])
179   fi
180 
181   # Clean up lists and announce results to user
182   UTIL_SORT_LIST(JVM_FEATURES_ENABLED, $JVM_FEATURES_ENABLED)
183   AC_MSG_CHECKING([for JVM features enabled by the user])
184   if test "x$JVM_FEATURES_ENABLED" != x; then
185     AC_MSG_RESULT(['$JVM_FEATURES_ENABLED'])
186   else
187     AC_MSG_RESULT([none])
188   fi
189 
190   UTIL_SORT_LIST(JVM_FEATURES_DISABLED, $JVM_FEATURES_DISABLED)
191   AC_MSG_CHECKING([for JVM features disabled by the user])
192   if test "x$JVM_FEATURES_DISABLED" != x; then
193     AC_MSG_RESULT(['$JVM_FEATURES_DISABLED'])
194   else
195     AC_MSG_RESULT([none])
196   fi
197 
198   # Makefiles use VALID_JVM_FEATURES in check-jvm-feature to verify correctness.
199   VALID_JVM_FEATURES="$JVM_FEATURES_VALID"
200   AC_SUBST(VALID_JVM_FEATURES)
201 ])
202 
203 ###############################################################################
204 # Helper function for the JVM_FEATURES_CHECK_* suite.
205 # The code in the code block should assign 'false' to the variable AVAILABLE
206 # if the feature is not available, and this function will handle everything
207 # else that is needed.
208 #
209 # arg 1: The name of the feature to test
210 # arg 2: The code block to execute
211 #
212 AC_DEFUN([JVM_FEATURES_CHECK_AVAILABILITY],
213 [
214   # Assume that feature is available
215   AVAILABLE=true
216 
217   # Execute feature test block
218   $2
219 
220   AC_MSG_CHECKING([if JVM feature '$1' is available])
221   if test "x$AVAILABLE" = "xtrue"; then
222     AC_MSG_RESULT([yes])
223   else
224     AC_MSG_RESULT([no])
225     JVM_FEATURES_PLATFORM_UNAVAILABLE="$JVM_FEATURES_PLATFORM_UNAVAILABLE $1"
226   fi
227 ])
228 
229 ###############################################################################
230 # Check if the feature 'cds' is available on this platform.
231 #
232 AC_DEFUN_ONCE([JVM_FEATURES_CHECK_CDS],
233 [
234   JVM_FEATURES_CHECK_AVAILABILITY(cds, [
235     AC_MSG_CHECKING([if platform is supported by CDS])
236     if test "x$OPENJDK_TARGET_OS" = xaix; then
237       AC_MSG_RESULT([no, $OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
238       AVAILABLE=false
239     else
240       AC_MSG_RESULT([yes])
241     fi
242   ])
243 ])
244 
245 ###############################################################################
246 # Check if the feature 'dtrace' is available on this platform.
247 #
248 AC_DEFUN_ONCE([JVM_FEATURES_CHECK_DTRACE],
249 [
250   JVM_FEATURES_CHECK_AVAILABILITY(dtrace, [
251     AC_MSG_CHECKING([for dtrace tool])
252     if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
253       AC_MSG_RESULT([$DTRACE])
254     else
255       AC_MSG_RESULT([no])
256       AVAILABLE=false
257     fi
258 
259     AC_CHECK_HEADERS([sys/sdt.h], [dtrace_headers_ok=true])
260     if test "x$dtrace_headers_ok" != "xtrue"; then
261       HELP_MSG_MISSING_DEPENDENCY([dtrace])
262       AC_MSG_NOTICE([Cannot enable dtrace with missing dependencies. See above.])
263       AVAILABLE=false
264     fi
265   ])
266 ])
267 
268 ###############################################################################
269 # Check if the feature 'jfr' is available on this platform.
270 #
271 AC_DEFUN_ONCE([JVM_FEATURES_CHECK_JFR],
272 [
273   JVM_FEATURES_CHECK_AVAILABILITY(jfr, [
274     AC_MSG_CHECKING([if platform is supported by JFR])
275     if test "x$OPENJDK_TARGET_OS" = xaix; then
276       AC_MSG_RESULT([no, $OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
277       AVAILABLE=false
278     else
279       AC_MSG_RESULT([yes])
280     fi
281   ])
282 ])
283 
284 ###############################################################################
285 # Check if the feature 'jvmci' is available on this platform.
286 #
287 AC_DEFUN_ONCE([JVM_FEATURES_CHECK_JVMCI],
288 [
289   JVM_FEATURES_CHECK_AVAILABILITY(jvmci, [
290     AC_MSG_CHECKING([if platform is supported by JVMCI])
291     if test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
292       AC_MSG_RESULT([yes])
293     elif test "x$OPENJDK_TARGET_CPU" = "xaarch64"; then
294       AC_MSG_RESULT([yes])
295     else
296       AC_MSG_RESULT([no, $OPENJDK_TARGET_CPU])
297       AVAILABLE=false
298     fi
299   ])
300 ])
301 
302 ###############################################################################
303 # Check if the feature 'shenandoahgc' is available on this platform.
304 #
305 AC_DEFUN_ONCE([JVM_FEATURES_CHECK_SHENANDOAHGC],
306 [
307   JVM_FEATURES_CHECK_AVAILABILITY(shenandoahgc, [
308     AC_MSG_CHECKING([if platform is supported by Shenandoah])
309     if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86" || \
310         test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
311       AC_MSG_RESULT([yes])
312     else
313       AC_MSG_RESULT([no, $OPENJDK_TARGET_CPU])
314       AVAILABLE=false
315     fi
316   ])
317 ])
318 
319 ###############################################################################
320 # Check if the feature 'static-build' is available on this platform.
321 #
322 AC_DEFUN_ONCE([JVM_FEATURES_CHECK_STATIC_BUILD],
323 [
324   JVM_FEATURES_CHECK_AVAILABILITY(static-build, [
325     AC_MSG_CHECKING([if static-build is enabled in configure])
326     if test "x$STATIC_BUILD" = "xtrue"; then
327       AC_MSG_RESULT([yes])
328     else
329       AC_MSG_RESULT([no, use --enable-static-build to enable static build.])
330       AVAILABLE=false
331     fi
332   ])
333 ])
334 
335 ###############################################################################
336 # Check if the feature 'zgc' is available on this platform.
337 #
338 AC_DEFUN_ONCE([JVM_FEATURES_CHECK_ZGC],
339 [
340   JVM_FEATURES_CHECK_AVAILABILITY(zgc, [
341     AC_MSG_CHECKING([if platform is supported by ZGC])
342     if test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
343       if test "x$OPENJDK_TARGET_OS" = "xlinux" || \
344           test "x$OPENJDK_TARGET_OS" = "xwindows" || \
345           test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
346         AC_MSG_RESULT([yes])
347       else
348         AC_MSG_RESULT([no, $OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
349         AVAILABLE=false
350       fi
351     elif test "x$OPENJDK_TARGET_CPU" = "xaarch64"; then
352       if test "x$OPENJDK_TARGET_OS" = "xlinux" || \
353           test "x$OPENJDK_TARGET_OS" = "xwindows" || \
354           test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
355         AC_MSG_RESULT([yes])
356       else
357         AC_MSG_RESULT([no, $OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
358         AVAILABLE=false
359       fi
360     elif test "x$OPENJDK_TARGET_CPU" = "xppc64le"; then
361       if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
362         AC_MSG_RESULT([yes])
363       else
364         AC_MSG_RESULT([no, $OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
365         AVAILABLE=false
366       fi
367     else
368       AC_MSG_RESULT([no, $OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
369       AVAILABLE=false
370     fi
371 
372     if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
373       AC_MSG_CHECKING([if Windows APIs required for ZGC is present])
374       AC_COMPILE_IFELSE(
375         [AC_LANG_PROGRAM([[#include <windows.h>]],
376           [[struct MEM_EXTENDED_PARAMETER x;]])
377         ],
378         [
379           AC_MSG_RESULT([yes])
380         ],
381         [
382           AC_MSG_RESULT([no, missing required APIs])
383           AVAILABLE=false
384         ]
385       )
386     fi
387   ])
388 ])
389 
390 ###############################################################################
391 # Setup JVM_FEATURES_PLATFORM_UNAVAILABLE and JVM_FEATURES_PLATFORM_FILTER
392 # to contain those features that are unavailable, or should be off by default,
393 # for this platform, regardless of JVM variant.
394 #
395 AC_DEFUN_ONCE([JVM_FEATURES_PREPARE_PLATFORM],
396 [
397   # The checks below should add unavailable features to
398   # JVM_FEATURES_PLATFORM_UNAVAILABLE.
399 
400   JVM_FEATURES_CHECK_CDS
401   JVM_FEATURES_CHECK_DTRACE
402   JVM_FEATURES_CHECK_JFR
403   JVM_FEATURES_CHECK_JVMCI
404   JVM_FEATURES_CHECK_SHENANDOAHGC
405   JVM_FEATURES_CHECK_STATIC_BUILD
406   JVM_FEATURES_CHECK_ZGC
407 
408   # Filter out features by default for all variants on certain platforms.
409   # Make sure to just add to JVM_FEATURES_PLATFORM_FILTER, since it could
410   # have a value already from custom extensions.
411   if test "x$OPENJDK_TARGET_OS" = xaix; then
412     JVM_FEATURES_PLATFORM_FILTER="$JVM_FEATURES_PLATFORM_FILTER jfr"
413   fi
414 ])
415 
416 ###############################################################################
417 # Setup JVM_FEATURES_VARIANT_UNAVAILABLE and JVM_FEATURES_VARIANT_FILTER
418 # to contain those features that are unavailable, or should be off by default,
419 # for this particular JVM variant.
420 #
421 # arg 1: JVM variant
422 #
423 AC_DEFUN([JVM_FEATURES_PREPARE_VARIANT],
424 [
425   variant=$1
426 
427   # Check which features are unavailable for this JVM variant.
428   # This means that is not possible to build these features for this variant.
429   if test "x$variant" = "xminimal"; then
430     JVM_FEATURES_VARIANT_UNAVAILABLE="cds zero"
431   elif test "x$variant" = "xcore"; then
432     JVM_FEATURES_VARIANT_UNAVAILABLE="cds minimal zero"
433   elif test "x$variant" = "xzero"; then
434     JVM_FEATURES_VARIANT_UNAVAILABLE="cds compiler1 compiler2 \
435         jvmci minimal zgc"
436   else
437     JVM_FEATURES_VARIANT_UNAVAILABLE="minimal zero"
438   fi
439 
440   # Check which features should be off by default for this JVM variant.
441   if test "x$variant" = "xclient"; then
442     JVM_FEATURES_VARIANT_FILTER="compiler2 jvmci link-time-opt opt-size"
443   elif test "x$variant" = "xminimal"; then
444     JVM_FEATURES_VARIANT_FILTER="cds compiler2 dtrace epsilongc g1gc \
445         jfr jni-check jvmci jvmti management nmt parallelgc services \
446         shenandoahgc vm-structs zgc"
447     if test "x$OPENJDK_TARGET_CPU" = xarm ; then
448       JVM_FEATURES_VARIANT_FILTER="$JVM_FEATURES_VARIANT_FILTER opt-size"
449     else
450       # Only arm-32 should have link-time-opt enabled as default.
451       JVM_FEATURES_VARIANT_FILTER="$JVM_FEATURES_VARIANT_FILTER \
452           link-time-opt"
453     fi
454   elif test "x$variant" = "xcore"; then
455     JVM_FEATURES_VARIANT_FILTER="compiler1 compiler2 jvmci \
456         link-time-opt opt-size"
457   elif test "x$variant" = "xzero"; then
458     JVM_FEATURES_VARIANT_FILTER="jfr link-time-opt opt-size"
459   else
460     JVM_FEATURES_VARIANT_FILTER="link-time-opt opt-size"
461   fi
462 ])
463 
464 ###############################################################################
465 # Calculate the actual set of active JVM features for this JVM variant. Store
466 # the result in JVM_FEATURES_ACTIVE.
467 #
468 # arg 1: JVM variant
469 #
470 AC_DEFUN([JVM_FEATURES_CALCULATE_ACTIVE],
471 [
472   variant=$1
473 
474   # The default is set to all valid features except those unavailable or listed
475   # in a filter.
476   if test "x$variant" != xcustom; then
477     UTIL_GET_NON_MATCHING_VALUES(default_for_variant, $JVM_FEATURES_VALID, \
478         $JVM_FEATURES_PLATFORM_UNAVAILABLE $JVM_FEATURES_VARIANT_UNAVAILABLE \
479         $JVM_FEATURES_PLATFORM_FILTER $JVM_FEATURES_VARIANT_FILTER)
480   else
481     # Except for the 'custom' variant, where the default is to start with an
482     # empty set.
483     default_for_variant=""
484   fi
485 
486   # Verify that explicitly enabled features are available
487   UTIL_GET_MATCHING_VALUES(enabled_but_unavailable, $JVM_FEATURES_ENABLED, \
488       $JVM_FEATURES_PLATFORM_UNAVAILABLE $JVM_FEATURES_VARIANT_UNAVAILABLE)
489   if test "x$enabled_but_unavailable" != x; then
490     AC_MSG_NOTICE([ERROR: Unavailable JVM features explicitly enabled for '$variant': '$enabled_but_unavailable'])
491     AC_MSG_ERROR([Cannot continue])
492   fi
493 
494   # Notify the user if their command line options has no real effect
495   UTIL_GET_MATCHING_VALUES(enabled_but_default, $JVM_FEATURES_ENABLED, \
496       $default_for_variant)
497   if test "x$enabled_but_default" != x; then
498     AC_MSG_NOTICE([Default JVM features explicitly enabled for '$variant': '$enabled_but_default'])
499   fi
500   UTIL_GET_MATCHING_VALUES(disabled_but_unavailable, $JVM_FEATURES_DISABLED, \
501       $JVM_FEATURES_PLATFORM_UNAVAILABLE $JVM_FEATURES_VARIANT_UNAVAILABLE)
502   if test "x$disabled_but_unavailable" != x; then
503     AC_MSG_NOTICE([Unavailable JVM features explicitly disabled for '$variant': '$disabled_but_unavailable'])
504   fi
505 
506   # JVM_FEATURES_ACTIVE is the set of all default features and all explicitly
507   # enabled features, with the explicitly disabled features filtered out.
508   UTIL_GET_NON_MATCHING_VALUES(JVM_FEATURES_ACTIVE, $default_for_variant \
509       $JVM_FEATURES_ENABLED, $JVM_FEATURES_DISABLED)
510 ])
511 
512 ###############################################################################
513 # Helper function for JVM_FEATURES_VERIFY. Check if the specified JVM
514 # feature is active. To be used in shell if constructs, like this:
515 # 'if JVM_FEATURES_IS_ACTIVE(jvmti); then'
516 #
517 # Definition kept in one line to allow inlining in if statements.
518 # Additional [] needed to keep m4 from mangling shell constructs.
519 AC_DEFUN([JVM_FEATURES_IS_ACTIVE],
520 [ [ [[ " $JVM_FEATURES_ACTIVE " =~ ' '$1' ' ]] ] ])
521 
522 ###############################################################################
523 # Verify that the resulting set of features is consistent and legal.
524 #
525 # arg 1: JVM variant
526 #
527 AC_DEFUN([JVM_FEATURES_VERIFY],
528 [
529   variant=$1
530 
531   if JVM_FEATURES_IS_ACTIVE(jvmci) && ! (JVM_FEATURES_IS_ACTIVE(compiler1) || \
532       JVM_FEATURES_IS_ACTIVE(compiler2)); then
533     AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1' for variant '$variant'])
534   fi
535 
536   if JVM_FEATURES_IS_ACTIVE(jvmti) && ! JVM_FEATURES_IS_ACTIVE(services); then
537     AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services' for variant '$variant'])
538   fi
539 
540   if JVM_FEATURES_IS_ACTIVE(management) && ! JVM_FEATURES_IS_ACTIVE(nmt); then
541     AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt' for variant '$variant'])
542   fi
543 
544   # For backwards compatibility, disable a feature "globally" if one variant
545   # is missing the feature.
546   if ! JVM_FEATURES_IS_ACTIVE(cds); then
547     ENABLE_CDS="false"
548   fi
549   if ! JVM_FEATURES_IS_ACTIVE(jvmci); then
550     INCLUDE_JVMCI="false"
551   fi
552   if JVM_FEATURES_IS_ACTIVE(compiler2); then
553     INCLUDE_COMPILER2="true"
554   fi
555 
556   # Verify that we have at least one gc selected (i.e., feature named "*gc").
557   if ! JVM_FEATURES_IS_ACTIVE(.*gc); then
558       AC_MSG_NOTICE([At least one gc needed for variant '$variant'.])
559       AC_MSG_NOTICE([Specified features: '$JVM_FEATURES_ACTIVE'])
560       AC_MSG_ERROR([Cannot continue])
561   fi
562 ])
563 
564 ###############################################################################
565 # Set up all JVM features for each enabled JVM variant. Requires that
566 # JVM_FEATURES_PARSE_OPTIONS has been called.
567 #
568 AC_DEFUN_ONCE([JVM_FEATURES_SETUP],
569 [
570   # Set up variant-independent factors
571   JVM_FEATURES_PREPARE_PLATFORM
572 
573   # For backwards compatibility, tentatively enable these features "globally",
574   # and disable them in JVM_FEATURES_VERIFY if a variant is found that are
575   # missing any of them.
576   ENABLE_CDS="true"
577   INCLUDE_JVMCI="true"
578   INCLUDE_COMPILER2="false"
579 
580   for variant in $JVM_VARIANTS; do
581     # Figure out if any features are unavailable, or should be filtered out
582     # by default, for this variant.
583     # Store the result in JVM_FEATURES_VARIANT_UNAVAILABLE and
584     # JVM_FEATURES_VARIANT_FILTER.
585     JVM_FEATURES_PREPARE_VARIANT($variant)
586 
587     # Calculate the resulting set of enabled features for this variant.
588     # The result is stored in JVM_FEATURES_ACTIVE.
589     JVM_FEATURES_CALCULATE_ACTIVE($variant)
590 
591     # Verify consistency for JVM_FEATURES_ACTIVE.
592     JVM_FEATURES_VERIFY($variant)
593 
594     # Keep feature list sorted and free of duplicates
595     UTIL_SORT_LIST(JVM_FEATURES_ACTIVE, $JVM_FEATURES_ACTIVE)
596     AC_MSG_CHECKING([JVM features to use for variant '$variant'])
597     AC_MSG_RESULT(['$JVM_FEATURES_ACTIVE'])
598 
599     # Save this as e.g. JVM_FEATURES_server, using indirect variable
600     # referencing.
601     features_var_name=JVM_FEATURES_$variant
602     eval $features_var_name=\"$JVM_FEATURES_ACTIVE\"
603   done
604 
605   # Unfortunately AC_SUBST does not work with non-literally named variables,
606   # so list all variants here.
607   AC_SUBST(JVM_FEATURES_server)
608   AC_SUBST(JVM_FEATURES_client)
609   AC_SUBST(JVM_FEATURES_minimal)
610   AC_SUBST(JVM_FEATURES_core)
611   AC_SUBST(JVM_FEATURES_zero)
612   AC_SUBST(JVM_FEATURES_custom)
613 
614   AC_SUBST(INCLUDE_JVMCI)
615   AC_SUBST(INCLUDE_COMPILER2)
616 
617 ])