1 #
2 # Copyright (c) 2011, 2022, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Major library component reside in separate files.
27 m4_include([lib-alsa.m4])
28 m4_include([lib-bundled.m4])
29 m4_include([lib-cups.m4])
30 m4_include([lib-ffi.m4])
31 m4_include([lib-fontconfig.m4])
32 m4_include([lib-freetype.m4])
33 m4_include([lib-hsdis.m4])
34 m4_include([lib-std.m4])
35 m4_include([lib-x11.m4])
36
37 m4_include([lib-tests.m4])
38
39 ################################################################################
40 # Determine which libraries are needed for this configuration
41 ################################################################################
42 AC_DEFUN_ONCE([LIB_DETERMINE_DEPENDENCIES],
43 [
44 # Check if X11 is needed
45 if test "x$OPENJDK_TARGET_OS" = xwindows || test "x$OPENJDK_TARGET_OS" = xmacosx; then
46 # No X11 support on windows or macosx
47 NEEDS_LIB_X11=false
48 else
49 # All other instances need X11, even if building headless only, libawt still
50 # needs X11 headers.
51 NEEDS_LIB_X11=true
52 fi
53
54 # Check if fontconfig is needed
55 if test "x$OPENJDK_TARGET_OS" = xwindows || test "x$OPENJDK_TARGET_OS" = xmacosx; then
56 # No fontconfig support on windows or macosx
57 NEEDS_LIB_FONTCONFIG=false
58 else
59 # All other instances need fontconfig, even if building headless only,
60 # libawt still needs fontconfig headers.
61 NEEDS_LIB_FONTCONFIG=true
62 fi
63
64 # Check if cups is needed
65 if test "x$OPENJDK_TARGET_OS" = xwindows; then
66 # Windows have a separate print system
67 NEEDS_LIB_CUPS=false
68 else
69 NEEDS_LIB_CUPS=true
70 fi
71
72 # A custom hook may have set this already
73 if test "x$NEEDS_LIB_FREETYPE" = "x"; then
74 NEEDS_LIB_FREETYPE=true
75 fi
76
77 # Check if alsa is needed
78 if test "x$OPENJDK_TARGET_OS" = xlinux; then
79 NEEDS_LIB_ALSA=true
80 else
81 NEEDS_LIB_ALSA=false
82 fi
83
84 # Check if ffi is needed
85 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
86 NEEDS_LIB_FFI=true
87 else
88 NEEDS_LIB_FFI=false
89 fi
90 ])
91
92 ################################################################################
93 # Parse library options, and setup needed libraries
94 ################################################################################
95 AC_DEFUN_ONCE([LIB_SETUP_LIBRARIES],
96 [
97 LIB_SETUP_STD_LIBS
98
99 LIB_SETUP_ALSA
100 LIB_SETUP_BUNDLED_LIBS
101 LIB_SETUP_CUPS
102 LIB_SETUP_FONTCONFIG
103 LIB_SETUP_FREETYPE
104 LIB_SETUP_HSDIS
105 LIB_SETUP_LIBFFI
106 LIB_SETUP_MISC_LIBS
107 LIB_SETUP_X11
108
109 LIB_TESTS_SETUP_GTEST
110
111 BASIC_JDKLIB_LIBS=""
112 if test "x$TOOLCHAIN_TYPE" != xmicrosoft; then
113 BASIC_JDKLIB_LIBS="-ljava -ljvm"
114 fi
115
116 # Math library
117 BASIC_JVM_LIBS="$LIBM"
118
119 # Dynamic loading library
120 if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xaix; then
121 BASIC_JVM_LIBS="$BASIC_JVM_LIBS $LIBDL"
122 fi
123
124 # Threading library
125 if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xaix; then
126 BASIC_JVM_LIBS="$BASIC_JVM_LIBS -lpthread"
127 fi
128
129 # librt for legacy clock_gettime
130 if test "x$OPENJDK_TARGET_OS" = xlinux; then
131 # Hotspot needs to link librt to get the clock_* functions.
132 # But once our supported minimum build and runtime platform
133 # has glibc 2.17, this can be removed as the functions are
134 # in libc.
135 BASIC_JVM_LIBS="$BASIC_JVM_LIBS -lrt"
136 fi
137
138 # Atomic library
139 # 32-bit platforms needs fallback library for 8-byte atomic ops on Zero
140 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
141 if test "x$OPENJDK_TARGET_OS" = xlinux &&
142 (test "x$OPENJDK_TARGET_CPU" = xarm ||
143 test "x$OPENJDK_TARGET_CPU" = xm68k ||
144 test "x$OPENJDK_TARGET_CPU" = xmips ||
145 test "x$OPENJDK_TARGET_CPU" = xmipsel ||
146 test "x$OPENJDK_TARGET_CPU" = xppc ||
147 test "x$OPENJDK_TARGET_CPU" = xsh); then
148 BASIC_JVM_LIBS="$BASIC_JVM_LIBS -latomic"
149 fi
150 fi
151
152 # Because RISC-V only has word-sized atomics, it requries libatomic where
153 # other common architectures do not. So link libatomic by default.
154 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$OPENJDK_TARGET_CPU" = xriscv64; then
155 BASIC_JVM_LIBS="$BASIC_JVM_LIBS -latomic"
156 fi
157
158 # perfstat lib
159 if test "x$OPENJDK_TARGET_OS" = xaix; then
160 BASIC_JVM_LIBS="$BASIC_JVM_LIBS -lperfstat"
161 fi
162
163 if test "x$OPENJDK_TARGET_OS" = xwindows; then
164 BASIC_JVM_LIBS="$BASIC_JVM_LIBS kernel32.lib user32.lib gdi32.lib winspool.lib \
165 comdlg32.lib advapi32.lib shell32.lib ole32.lib oleaut32.lib uuid.lib \
166 wsock32.lib winmm.lib version.lib psapi.lib"
167 fi
168
169 JDKLIB_LIBS="$BASIC_JDKLIB_LIBS"
170 JDKEXE_LIBS=""
171 JVM_LIBS="$BASIC_JVM_LIBS"
172 OPENJDK_BUILD_JDKLIB_LIBS="$BASIC_JDKLIB_LIBS"
173 OPENJDK_BUILD_JVM_LIBS="$BASIC_JVM_LIBS"
174
175 AC_SUBST(JDKLIB_LIBS)
176 AC_SUBST(JDKEXE_LIBS)
177 AC_SUBST(JVM_LIBS)
178 AC_SUBST(OPENJDK_BUILD_JDKLIB_LIBS)
179 AC_SUBST(OPENJDK_BUILD_JVM_LIBS)
180 ])
181
182 ################################################################################
183 # Setup various libraries, typically small system libraries
184 ################################################################################
185 AC_DEFUN_ONCE([LIB_SETUP_MISC_LIBS],
186 [
187 # Setup libm (the maths library)
188 if test "x$OPENJDK_TARGET_OS" != "xwindows"; then
189 AC_CHECK_LIB(m, cos, [], [
190 AC_MSG_NOTICE([Maths library was not found])
191 ])
192 LIBM="-lm"
193 else
194 LIBM=""
195 fi
196 AC_SUBST(LIBM)
197
198 # Setup libdl (for dynamic library loading)
199 save_LIBS="$LIBS"
200 LIBS=""
201 AC_CHECK_LIB(dl, dlopen)
202 LIBDL="$LIBS"
203 AC_SUBST(LIBDL)
204 LIBS="$save_LIBS"
205
206 # Control if libzip can use mmap. Available for purposes of overriding.
207 LIBZIP_CAN_USE_MMAP=true
208 AC_SUBST(LIBZIP_CAN_USE_MMAP)
209 ])