1 #
   2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],
  27 [
  28   ###############################################################################
  29   #
  30   # Check which variant of the JDK that we want to build.
  31   # Currently we have:
  32   #    normal:   standard edition
  33   # but the custom make system may add other variants
  34   #
  35   # Effectively the JDK variant gives a name to a specific set of
  36   # modules to compile into the JDK. In the future, these modules
  37   # might even be Jigsaw modules.
  38   #
  39   AC_MSG_CHECKING([which variant of the JDK to build])
  40   AC_ARG_WITH([jdk-variant], [AS_HELP_STRING([--with-jdk-variant],
  41       [JDK variant to build (normal) @<:@normal@:>@])])
  42 
  43   if test "x$with_jdk_variant" = xnormal || test "x$with_jdk_variant" = x; then
  44     JDK_VARIANT="normal"
  45   else
  46     AC_MSG_ERROR([The available JDK variants are: normal])
  47   fi
  48 
  49   AC_SUBST(JDK_VARIANT)
  50 
  51   AC_MSG_RESULT([$JDK_VARIANT])
  52 ])
  53 
  54 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_INTERPRETER],
  55 [
  56 ###############################################################################
  57 #
  58 # Check which interpreter of the JVM we want to build.
  59 # Currently we have:
  60 #    template: Template interpreter (the default)
  61 #    cpp     : C++ interpreter
  62 AC_MSG_CHECKING([which interpreter of the JVM to build])
  63 AC_ARG_WITH([jvm-interpreter], [AS_HELP_STRING([--with-jvm-interpreter],
  64         [JVM interpreter to build (template, cpp) @<:@template@:>@])])
  65 
  66 if test "x$with_jvm_interpreter" = x; then
  67      with_jvm_interpreter="template"
  68 fi
  69 
  70 JVM_INTERPRETER="$with_jvm_interpreter"
  71 
  72 if test "x$JVM_INTERPRETER" != xtemplate && test "x$JVM_INTERPRETER" != xcpp; then
  73    AC_MSG_ERROR([The available JVM interpreters are: template, cpp])
  74 fi
  75 
  76 AC_SUBST(JVM_INTERPRETER)
  77 
  78 AC_MSG_RESULT([$with_jvm_interpreter])
  79 ])
  80 
  81 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_VARIANTS],
  82 [
  83 
  84   ###############################################################################
  85   #
  86   # Check which variants of the JVM that we want to build.
  87   # Currently we have:
  88   #    server: normal interpreter and a tiered C1/C2 compiler
  89   #    client: normal interpreter and C1 (no C2 compiler) (only 32-bit platforms)
  90   #    minimal1: reduced form of client with optional VM services and features stripped out
  91   #    kernel: kernel footprint JVM that passes the TCK without major performance problems,
  92   #             ie normal interpreter and C1, only the serial GC, kernel jvmti etc
  93   #    zero: no machine code interpreter, no compiler
  94   #    zeroshark: zero interpreter and shark/llvm compiler backend
  95 #    core: interpreter only, no compiler (only works on some platforms)
  96   AC_MSG_CHECKING([which variants of the JVM to build])
  97   AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
  98         [JVM variants (separated by commas) to build (server, client, minimal1, kernel, zero, zeroshark, core) @<:@server@:>@])])
  99 
 100   if test "x$with_jvm_variants" = x; then
 101     with_jvm_variants="server"
 102   fi
 103 
 104   JVM_VARIANTS=",$with_jvm_variants,"
 105   TEST_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,//' -e 's/client,//'  -e 's/minimal1,//' -e 's/kernel,//' -e 's/zero,//' -e 's/zeroshark,//' -e 's/core,//'`
 106 
 107   if test "x$TEST_VARIANTS" != "x,"; then
 108      AC_MSG_ERROR([The available JVM variants are: server, client, minimal1, kernel, zero, zeroshark, core])
 109   fi
 110   AC_MSG_RESULT([$with_jvm_variants])
 111 
 112   JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`
 113   JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`
 114   JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS" | $SED -e '/,minimal1,/!s/.*/false/g' -e '/,minimal1,/s/.*/true/g'`
 115   JVM_VARIANT_KERNEL=`$ECHO "$JVM_VARIANTS" | $SED -e '/,kernel,/!s/.*/false/g' -e '/,kernel,/s/.*/true/g'`
 116   JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`
 117   JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`
 118   JVM_VARIANT_CORE=`$ECHO "$JVM_VARIANTS" | $SED -e '/,core,/!s/.*/false/g' -e '/,core,/s/.*/true/g'`
 119 
 120   if test "x$JVM_VARIANT_CLIENT" = xtrue; then
 121     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 122       AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])
 123     fi
 124   fi
 125   if test "x$JVM_VARIANT_KERNEL" = xtrue; then
 126     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 127       AC_MSG_ERROR([You cannot build a kernel JVM for a 64-bit machine.])
 128     fi
 129   fi
 130   if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
 131     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 132       AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])
 133     fi
 134   fi
 135 
 136   # Replace the commas with AND for use in the build directory name.
 137   ANDED_JVM_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/^,//' -e 's/,$//' -e 's/,/AND/g'`
 138   COUNT_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,/1/' -e 's/client,/1/' -e 's/minimal1,/1/' -e 's/kernel,/1/' -e 's/zero,/1/' -e 's/zeroshark,/1/' -e 's/core,/1/'`
 139   if test "x$COUNT_VARIANTS" != "x,1"; then
 140     BUILDING_MULTIPLE_JVM_VARIANTS=yes
 141   else
 142     BUILDING_MULTIPLE_JVM_VARIANTS=no
 143   fi
 144 
 145   AC_SUBST(JVM_VARIANTS)
 146   AC_SUBST(JVM_VARIANT_SERVER)
 147   AC_SUBST(JVM_VARIANT_CLIENT)
 148   AC_SUBST(JVM_VARIANT_MINIMAL1)
 149   AC_SUBST(JVM_VARIANT_KERNEL)
 150   AC_SUBST(JVM_VARIANT_ZERO)
 151   AC_SUBST(JVM_VARIANT_ZEROSHARK)
 152   AC_SUBST(JVM_VARIANT_CORE)
 153 
 154   INCLUDE_SA=true
 155   if test "x$JVM_VARIANT_ZERO" = xtrue ; then
 156     INCLUDE_SA=false
 157   fi
 158   if test "x$JVM_VARIANT_ZEROSHARK" = xtrue ; then
 159     INCLUDE_SA=false
 160   fi
 161   if test "x$VAR_CPU" = xppc64 -o "x$VAR_CPU" = xppc64le ; then
 162     INCLUDE_SA=false
 163   fi
 164   if test "x$OPENJDK_TARGET_CPU" = xaarch64; then
 165     INCLUDE_SA=false
 166   fi
 167   AC_SUBST(INCLUDE_SA)
 168 
 169   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 170     MACOSX_UNIVERSAL="false"
 171   fi
 172 
 173   AC_SUBST(MACOSX_UNIVERSAL)
 174 ])
 175 
 176 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],
 177 [
 178   ###############################################################################
 179   #
 180   # Set the debug level
 181   #    release: no debug information, all optimizations, no asserts.
 182   #    fastdebug: debug information (-g), all optimizations, all asserts
 183   #    slowdebug: debug information (-g), no optimizations, all asserts
 184   #
 185   DEBUG_LEVEL="release"
 186   AC_MSG_CHECKING([which debug level to use])
 187   AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],
 188       [set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],
 189       [
 190         ENABLE_DEBUG="${enableval}"
 191         DEBUG_LEVEL="fastdebug"
 192       ], [ENABLE_DEBUG="no"])
 193 
 194   AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],
 195       [set the debug level (release, fastdebug, slowdebug) @<:@release@:>@])],
 196       [
 197         DEBUG_LEVEL="${withval}"
 198         if test "x$ENABLE_DEBUG" = xyes; then
 199           AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])
 200         fi
 201       ])
 202   AC_MSG_RESULT([$DEBUG_LEVEL])
 203 
 204   if test "x$DEBUG_LEVEL" != xrelease && \
 205       test "x$DEBUG_LEVEL" != xfastdebug && \
 206       test "x$DEBUG_LEVEL" != xslowdebug; then
 207     AC_MSG_ERROR([Allowed debug levels are: release, fastdebug and slowdebug])
 208   fi
 209 
 210 
 211   ###############################################################################
 212   #
 213   # Setup legacy vars/targets and new vars to deal with different debug levels.
 214   #
 215 
 216   case $DEBUG_LEVEL in
 217     release )
 218       VARIANT="OPT"
 219       FASTDEBUG="false"
 220       DEBUG_CLASSFILES="false"
 221       BUILD_VARIANT_RELEASE=""
 222       HOTSPOT_DEBUG_LEVEL="product"
 223       HOTSPOT_EXPORT="product"
 224       ;;
 225     fastdebug )
 226       VARIANT="DBG"
 227       FASTDEBUG="true"
 228       DEBUG_CLASSFILES="true"
 229       BUILD_VARIANT_RELEASE="-fastdebug"
 230       HOTSPOT_DEBUG_LEVEL="fastdebug"
 231       HOTSPOT_EXPORT="fastdebug"
 232       ;;
 233     slowdebug )
 234       VARIANT="DBG"
 235       FASTDEBUG="false"
 236       DEBUG_CLASSFILES="true"
 237       BUILD_VARIANT_RELEASE="-debug"
 238       HOTSPOT_DEBUG_LEVEL="jvmg"
 239       HOTSPOT_EXPORT="debug"
 240       ;;
 241   esac
 242 
 243   #####
 244   # Generate the legacy makefile targets for hotspot.
 245   # The hotspot api for selecting the build artifacts, really, needs to be improved.
 246   # JDK-7195896 will fix this on the hotspot side by using the JVM_VARIANT_* variables to
 247   # determine what needs to be built. All we will need to set here is all_product, all_fastdebug etc
 248   # But until then ...
 249   HOTSPOT_TARGET=""
 250 
 251   if test "x$JVM_VARIANT_SERVER" = xtrue; then
 252     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "
 253   fi
 254 
 255   if test "x$JVM_VARIANT_CLIENT" = xtrue; then
 256     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "
 257   fi
 258 
 259   if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
 260     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "
 261   fi
 262 
 263   if test "x$JVM_VARIANT_KERNEL" = xtrue; then
 264     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}kernel "
 265   fi
 266 
 267   if test "x$JVM_VARIANT_ZERO" = xtrue; then
 268     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "
 269   fi
 270 
 271   if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
 272     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "
 273   fi
 274 
 275   if test "x$JVM_VARIANT_CORE" = xtrue; then
 276     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}core "
 277   fi
 278 
 279   HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_EXPORT"
 280 
 281   # On Macosx universal binaries are produced, but they only contain
 282   # 64 bit intel. This invalidates control of which jvms are built
 283   # from configure, but only server is valid anyway. Fix this
 284   # when hotspot makefiles are rewritten.
 285   if test "x$MACOSX_UNIVERSAL" = xtrue; then
 286     HOTSPOT_TARGET=universal_${HOTSPOT_EXPORT}
 287   fi
 288 
 289   #####
 290 
 291   AC_SUBST(DEBUG_LEVEL)
 292   AC_SUBST(VARIANT)
 293   AC_SUBST(FASTDEBUG)
 294   AC_SUBST(DEBUG_CLASSFILES)
 295   AC_SUBST(BUILD_VARIANT_RELEASE)
 296 ])
 297 
 298 
 299 ###############################################################################
 300 #
 301 # Should we build only OpenJDK even if closed sources are present?
 302 #
 303 AC_DEFUN_ONCE([JDKOPT_SETUP_OPEN_OR_CUSTOM],
 304 [
 305   AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],
 306       [suppress building custom source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])
 307 
 308   AC_MSG_CHECKING([for presence of closed sources])
 309   if test -d "$SRC_ROOT/jdk/src/closed"; then
 310     CLOSED_SOURCE_PRESENT=yes
 311   else
 312     CLOSED_SOURCE_PRESENT=no
 313   fi
 314   AC_MSG_RESULT([$CLOSED_SOURCE_PRESENT])
 315 
 316   AC_MSG_CHECKING([if closed source is suppressed (openjdk-only)])
 317   SUPPRESS_CLOSED_SOURCE="$enable_openjdk_only"
 318   AC_MSG_RESULT([$SUPPRESS_CLOSED_SOURCE])
 319 
 320   if test "x$CLOSED_SOURCE_PRESENT" = xno; then
 321     OPENJDK=true
 322     if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
 323       AC_MSG_WARN([No closed source present, --enable-openjdk-only makes no sense])
 324     fi
 325   else
 326     if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
 327       OPENJDK=true
 328     else
 329       OPENJDK=false
 330     fi
 331   fi
 332 
 333   if test "x$OPENJDK" = "xtrue"; then
 334     SET_OPENJDK="OPENJDK=true"
 335   fi
 336 
 337   AC_SUBST(SET_OPENJDK)
 338 ])
 339 
 340 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],
 341 [
 342 
 343   ###############################################################################
 344   #
 345   # Should we build a JDK/JVM with headful support (ie a graphical ui)?
 346   # We always build headless support.
 347   #
 348   AC_MSG_CHECKING([headful support])
 349   AC_ARG_ENABLE([headful], [AS_HELP_STRING([--disable-headful],
 350       [disable building headful support (graphical UI support) @<:@enabled@:>@])],
 351       [SUPPORT_HEADFUL=${enable_headful}], [SUPPORT_HEADFUL=yes])
 352 
 353   SUPPORT_HEADLESS=yes
 354   BUILD_HEADLESS="BUILD_HEADLESS:=true"
 355 
 356   if test "x$SUPPORT_HEADFUL" = xyes; then
 357     # We are building both headful and headless.
 358     headful_msg="include support for both headful and headless"
 359   fi
 360 
 361   if test "x$SUPPORT_HEADFUL" = xno; then
 362     # Thus we are building headless only.
 363     BUILD_HEADLESS="BUILD_HEADLESS:=true"
 364     headful_msg="headless only"
 365   fi
 366 
 367   AC_MSG_RESULT([$headful_msg])
 368 
 369   AC_SUBST(SUPPORT_HEADLESS)
 370   AC_SUBST(SUPPORT_HEADFUL)
 371   AC_SUBST(BUILD_HEADLESS)
 372 
 373   # Control wether Hotspot runs Queens test after build.
 374   AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],
 375       [run the Queens test after Hotspot build @<:@disabled@:>@])],,
 376       [enable_hotspot_test_in_build=no])
 377   if test "x$enable_hotspot_test_in_build" = "xyes"; then
 378     TEST_IN_BUILD=true
 379   else
 380     TEST_IN_BUILD=false
 381   fi
 382   AC_SUBST(TEST_IN_BUILD)
 383 
 384   ###############################################################################
 385   #
 386   # Choose cacerts source file
 387   #
 388   AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],
 389       [specify alternative cacerts file])])
 390   if test "x$with_cacerts_file" != x; then
 391     CACERTS_FILE=$with_cacerts_file
 392   fi
 393   AC_SUBST(CACERTS_FILE)
 394 
 395   ###############################################################################
 396   #
 397   # Enable or disable unlimited crypto
 398   #
 399   AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--enable-unlimited-crypto],
 400       [Enable unlimited crypto policy @<:@disabled@:>@])],,
 401       [enable_unlimited_crypto=no])
 402   if test "x$enable_unlimited_crypto" = "xyes"; then
 403     UNLIMITED_CRYPTO=true
 404   else
 405     UNLIMITED_CRYPTO=false
 406   fi
 407   AC_SUBST(UNLIMITED_CRYPTO)
 408 
 409   ###############################################################################
 410   #
 411   # Enable or disable the elliptic curve crypto implementation
 412   #
 413   AC_DEFUN_ONCE([JDKOPT_DETECT_INTREE_EC],
 414   [
 415     AC_MSG_CHECKING([if elliptic curve crypto implementation is present])
 416 
 417     if test -d "${SRC_ROOT}/jdk/src/share/native/sun/security/ec/impl"; then
 418       ENABLE_INTREE_EC=yes
 419       AC_MSG_RESULT([yes])
 420     else
 421       ENABLE_INTREE_EC=no
 422       AC_MSG_RESULT([no])
 423     fi
 424 
 425     AC_SUBST(ENABLE_INTREE_EC)
 426   ])
 427 
 428   ###############################################################################
 429   #
 430   # Compress jars
 431   #
 432   COMPRESS_JARS=false
 433 
 434   AC_SUBST(COMPRESS_JARS)
 435 
 436   ###############################################################################
 437   #
 438   # Enable or disable JFR
 439   #
 440   AC_MSG_CHECKING([whether to build jfr])
 441   AC_ARG_ENABLE(jfr, [AS_HELP_STRING([--enable-jfr],
 442       [Enable Java Flight Recorder support @<:@disabled@:>@])],,
 443       [enable_jfr=auto])
 444   if test "x$enable_jfr" = "xno" -o "x$enable_jfr" = "xauto"; then
 445     ENABLE_JFR=false
 446   elif test "x$enable_jfr" = "xyes" ; then
 447     if test "x$JVM_VARIANT_MINIMAL1" = "xtrue" -o "x$JVM_VARIANT_ZERO" = "xtrue"; then
 448       AC_MSG_ERROR([cannot enable JFR on minimal1 VM or zero build])
 449     elif test "x$OPENJDK_TARGET_OS" = xaix; then
 450       AC_MSG_ERROR([AIX does not support JFR])
 451     else
 452       ENABLE_JFR=true
 453     fi
 454   else
 455     AC_MSG_ERROR([--enable-jfr must either be set to yes or no])
 456   fi
 457   AC_MSG_RESULT([$ENABLE_JFR])
 458   AC_SUBST(ENABLE_JFR)
 459 ])
 460 
 461 ###############################################################################
 462 #
 463 # Setup version numbers
 464 #
 465 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VERSION_NUMBERS],
 466 [
 467   # Source the version numbers
 468   . $AUTOCONF_DIR/version-numbers
 469 
 470   # Get the settings from parameters
 471   AC_ARG_WITH(milestone, [AS_HELP_STRING([--with-milestone],
 472       [Set milestone value for build @<:@internal@:>@])])
 473   if test "x$with_milestone" = xyes; then
 474     AC_MSG_ERROR([Milestone must have a value])
 475   elif test "x$with_milestone" != x; then
 476     MILESTONE="$with_milestone"
 477   fi
 478   if test "x$MILESTONE" = x; then
 479     MILESTONE=internal
 480   fi
 481 
 482   AC_ARG_WITH(update-version, [AS_HELP_STRING([--with-update-version],
 483       [Set update version value for build @<:@b00@:>@])])
 484   if test "x$with_update_version" = xyes; then
 485     AC_MSG_ERROR([Update version must have a value])
 486   elif test "x$with_update_version" != x; then
 487     JDK_UPDATE_VERSION="$with_update_version"
 488     # On macosx 10.7, it's not possible to set --with-update-version=0X due
 489     # to a bug in expr (which reduces it to just X). To work around this, we
 490     # always add a 0 to one digit update versions.
 491     if test "${#JDK_UPDATE_VERSION}" = "1"; then
 492       JDK_UPDATE_VERSION="0${JDK_UPDATE_VERSION}"
 493     fi
 494   fi
 495 
 496   AC_ARG_WITH(user-release-suffix, [AS_HELP_STRING([--with-user-release-suffix],
 497       [Add a custom string to the version string if build number isn't set.@<:@username_builddateb00@:>@])])
 498   if test "x$with_user_release_suffix" = xyes; then
 499     AC_MSG_ERROR([Release suffix must have a value])
 500   elif test "x$with_user_release_suffix" != x; then
 501     USER_RELEASE_SUFFIX="$with_user_release_suffix"
 502   fi
 503 
 504   AC_ARG_WITH(build-number, [AS_HELP_STRING([--with-build-number],
 505       [Set build number value for build @<:@b00@:>@])])
 506   if test "x$with_build_number" = xyes; then
 507     AC_MSG_ERROR([Build number must have a value])
 508   elif test "x$with_build_number" != x; then
 509     JDK_BUILD_NUMBER="$with_build_number"
 510   fi
 511   # Define default USER_RELEASE_SUFFIX if BUILD_NUMBER and USER_RELEASE_SUFFIX are not set
 512   if test "x$JDK_BUILD_NUMBER" = x; then
 513     JDK_BUILD_NUMBER=b00
 514     if test "x$USER_RELEASE_SUFFIX" = x; then
 515       BUILD_DATE=`date '+%Y_%m_%d_%H_%M'`
 516       # Avoid [:alnum:] since it depends on the locale.
 517       CLEAN_USERNAME=`echo "$USER" | $TR -d -c 'abcdefghijklmnopqrstuvqxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789'`
 518       USER_RELEASE_SUFFIX=`echo "${CLEAN_USERNAME}_${BUILD_DATE}" | $TR 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' 'abcdefghijklmnopqrstuvwxyz'`
 519     fi
 520   fi
 521 
 522   # Now set the JDK version, milestone, build number etc.
 523   AC_SUBST(USER_RELEASE_SUFFIX)
 524   AC_SUBST(JDK_MAJOR_VERSION)
 525   AC_SUBST(JDK_MINOR_VERSION)
 526   AC_SUBST(JDK_MICRO_VERSION)
 527   AC_SUBST(JDK_UPDATE_VERSION)
 528   AC_SUBST(JDK_BUILD_NUMBER)
 529   AC_SUBST(MILESTONE)
 530   AC_SUBST(LAUNCHER_NAME)
 531   AC_SUBST(PRODUCT_NAME)
 532   AC_SUBST(PRODUCT_SUFFIX)
 533   AC_SUBST(JDK_RC_PLATFORM_NAME)
 534   AC_SUBST(MACOSX_BUNDLE_NAME_BASE)
 535   AC_SUBST(MACOSX_BUNDLE_ID_BASE)
 536 
 537   # The vendor name, if any
 538   AC_ARG_WITH(vendor-name, [AS_HELP_STRING([--with-vendor-name],
 539       [Set vendor name. Among others, used to set the 'java.vendor'
 540        and 'java.vm.vendor' system properties. @<:@not specified@:>@])])
 541   if test "x$with_vendor_name" = xyes; then
 542     AC_MSG_ERROR([--with-vendor-name must have a value])
 543   elif [ ! [[ $with_vendor_name =~ ^[[:print:]]*$ ]] ]; then
 544     AC_MSG_ERROR([--with-vendor-name contains non-printing characters: $with_vendor_name])
 545   elif test "x$with_vendor_name" != x; then
 546     # Only set COMPANY_NAME if '--with-vendor-name' was used and is not empty.
 547     # Otherwise we will use the value from "version-numbers" included above.
 548     COMPANY_NAME="$with_vendor_name"
 549   fi
 550   AC_SUBST(COMPANY_NAME)
 551 
 552   # The vendor URL, if any
 553   AC_ARG_WITH(vendor-url, [AS_HELP_STRING([--with-vendor-url],
 554       [Set the 'java.vendor.url' system property @<:@not specified@:>@])])
 555   if test "x$with_vendor_url" = xyes; then
 556     AC_MSG_ERROR([--with-vendor-url must have a value])
 557   elif [ ! [[ $with_vendor_url =~ ^[[:print:]]*$ ]] ]; then
 558     AC_MSG_ERROR([--with-vendor-url contains non-printing characters: $with_vendor_url])
 559   else
 560     VENDOR_URL="$with_vendor_url"
 561   fi
 562   AC_SUBST(VENDOR_URL)
 563 
 564   # The vendor bug URL, if any
 565   AC_ARG_WITH(vendor-bug-url, [AS_HELP_STRING([--with-vendor-bug-url],
 566       [Set the 'java.vendor.url.bug' system property @<:@not specified@:>@])])
 567   if test "x$with_vendor_bug_url" = xyes; then
 568     AC_MSG_ERROR([--with-vendor-bug-url must have a value])
 569   elif [ ! [[ $with_vendor_bug_url =~ ^[[:print:]]*$ ]] ]; then
 570     AC_MSG_ERROR([--with-vendor-bug-url contains non-printing characters: $with_vendor_bug_url])
 571   else
 572     VENDOR_URL_BUG="$with_vendor_bug_url"
 573   fi
 574   AC_SUBST(VENDOR_URL_BUG)
 575 
 576   # The vendor VM bug URL, if any
 577   AC_ARG_WITH(vendor-vm-bug-url, [AS_HELP_STRING([--with-vendor-vm-bug-url],
 578       [Sets the bug URL which will be displayed when the VM crashes @<:@not specified@:>@])])
 579   if test "x$with_vendor_vm_bug_url" = xyes; then
 580     AC_MSG_ERROR([--with-vendor-vm-bug-url must have a value])
 581   elif [ ! [[ $with_vendor_vm_bug_url =~ ^[[:print:]]*$ ]] ]; then
 582     AC_MSG_ERROR([--with-vendor-vm-bug-url contains non-printing characters: $with_vendor_vm_bug_url])
 583   else
 584     VENDOR_URL_VM_BUG="$with_vendor_vm_bug_url"
 585   fi
 586   AC_SUBST(VENDOR_URL_VM_BUG)
 587 
 588   AC_ARG_WITH(copyright-year, [AS_HELP_STRING([--with-copyright-year],
 589       [Set copyright year value for build @<:@current year@:>@])])
 590   if test "x$with_copyright_year" = xyes; then
 591     AC_MSG_ERROR([Copyright year must have a value])
 592   elif test "x$with_copyright_year" != x; then
 593     COPYRIGHT_YEAR="$with_copyright_year"
 594   else
 595     COPYRIGHT_YEAR=`date +'%Y'`
 596   fi
 597   AC_SUBST(COPYRIGHT_YEAR)
 598 
 599   if test "x$JDK_UPDATE_VERSION" != x; then
 600     JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}_${JDK_UPDATE_VERSION}"
 601   else
 602     JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}"
 603   fi
 604   AC_SUBST(JDK_VERSION)
 605 
 606   # The cooked update version used to encode trailing letters in the update
 607   # version into a trailing number. That is no longer needed, but need to
 608   # keep the format in 8u for compatibility.
 609   COOKED_JDK_UPDATE_VERSION="${JDK_UPDATE_VERSION}0"
 610   AC_SUBST(COOKED_JDK_UPDATE_VERSION)
 611 
 612   COOKED_BUILD_NUMBER=`$ECHO $JDK_BUILD_NUMBER | $SED -e 's/^b//' -e 's/^0//'`
 613   AC_SUBST(COOKED_BUILD_NUMBER)
 614 ])
 615 
 616 AC_DEFUN_ONCE([JDKOPT_SETUP_BUILD_TWEAKS],
 617 [
 618   HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"
 619   AC_SUBST(HOTSPOT_MAKE_ARGS)
 620 
 621   # The name of the Service Agent jar.
 622   SALIB_NAME="${LIBRARY_PREFIX}saproc${SHARED_LIBRARY_SUFFIX}"
 623   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 624     SALIB_NAME="${LIBRARY_PREFIX}sawindbg${SHARED_LIBRARY_SUFFIX}"
 625   fi
 626   AC_SUBST(SALIB_NAME)
 627 ])
 628 
 629 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],
 630 [
 631   # Backwards compatibility. --with-native-debug-symbols is preferred post JDK-8207234,
 632   # but if somebody does not specify it via configure, we still want to preserve old
 633   # behaviour of --disable-debug-symbols
 634   #
 635   # ENABLE_DEBUG_SYMBOLS
 636   # This must be done after the toolchain is setup, since we're looking at objcopy.
 637   #
 638   AC_ARG_ENABLE([debug-symbols],
 639       [AS_HELP_STRING([--disable-debug-symbols],[disable generation of debug symbols @<:@enabled@:>@])])
 640 
 641   AC_MSG_CHECKING([if we should generate debug symbols])
 642 
 643   if test "x$enable_debug_symbols" = "xyes" && test "x$OBJCOPY" = x; then
 644     # explicit enabling of enable-debug-symbols and can't find objcopy
 645     #   this is an error
 646     AC_MSG_ERROR([Unable to find objcopy, cannot enable debug-symbols])
 647   fi
 648 
 649   if test "x$enable_debug_symbols" = "xyes"; then
 650     ENABLE_DEBUG_SYMBOLS=true
 651   elif test "x$enable_debug_symbols" = "xno"; then
 652     ENABLE_DEBUG_SYMBOLS=false
 653   else
 654     # Default is on if objcopy is found
 655     if test "x$OBJCOPY" != x; then
 656       ENABLE_DEBUG_SYMBOLS=true
 657     # MacOS X and Windows don't use objcopy but default is on for those OSes
 658     elif test "x$OPENJDK_TARGET_OS" = xmacosx || test "x$OPENJDK_TARGET_OS" = xwindows; then
 659       ENABLE_DEBUG_SYMBOLS=true
 660     else
 661       ENABLE_DEBUG_SYMBOLS=false
 662     fi
 663   fi
 664 
 665   AC_MSG_RESULT([$ENABLE_DEBUG_SYMBOLS])
 666 
 667   # Backwards compatibility. --with-native-debug-symbols is preferred post JDK-8207234,
 668   # but if somebody does not specify it via configure, we still want to preserve old
 669   # behaviour of --disable-zip-debug-info.
 670   #
 671   # ZIP_DEBUGINFO_FILES
 672   #
 673   AC_MSG_CHECKING([if we should zip debug-info files])
 674   AC_ARG_ENABLE([zip-debug-info],
 675       [AS_HELP_STRING([--disable-zip-debug-info],[disable zipping of debug-info files @<:@enabled@:>@])],
 676       [enable_zip_debug_info="${enableval}"], [enable_zip_debug_info="yes"])
 677   AC_MSG_RESULT([${enable_zip_debug_info}])
 678 
 679   if test "x${enable_zip_debug_info}" = "xno"; then
 680     ZIP_DEBUGINFO_FILES=false
 681   elif test "x${enable_zip_debug_info}" = "xyes"; then
 682     ZIP_DEBUGINFO_FILES=true
 683   fi
 684 
 685   #
 686   # NATIVE_DEBUG_SYMBOLS
 687   # This must be done after the toolchain is setup, since we're looking at objcopy.
 688   # In addition, this must be done after ENABLE_DEBUG_SYMBOLS and ZIP_DEBUGINFO_FILES
 689   # checking in order to preserve backwards compatibility post JDK-8207234.
 690   #
 691   AC_MSG_CHECKING([what type of native debug symbols to use (this will override previous settings)])
 692   AC_ARG_WITH([native-debug-symbols],
 693       [AS_HELP_STRING([--with-native-debug-symbols],
 694       [set the native debug symbol configuration (none, internal, external, zipped) @<:@varying@:>@])],
 695       [
 696         if test "x$OPENJDK_TARGET_OS" = xaix; then
 697           if test "x$with_native_debug_symbols" = xexternal || test "x$with_native_debug_symbols" = xzipped; then
 698             AC_MSG_ERROR([AIX only supports the parameters 'none' and 'internal' for --with-native-debug-symbols])
 699           fi
 700         fi
 701       ],
 702       [
 703         # Default to unset for backwards compatibility
 704         with_native_debug_symbols=""
 705       ])
 706   NATIVE_DEBUG_SYMBOLS=$with_native_debug_symbols
 707   if test "x$NATIVE_DEBUG_SYMBOLS" = x; then
 708     AC_MSG_RESULT([not specified])
 709   else
 710     AC_MSG_RESULT([$NATIVE_DEBUG_SYMBOLS])
 711   fi
 712   # Default is empty
 713   DEBUG_BINARIES=
 714   # Default is min_strip. Possible values are min_strip, all_strip, no_strip
 715   STRIP_POLICY=min_strip
 716 
 717   if test "x$NATIVE_DEBUG_SYMBOLS" = xzipped; then
 718 
 719     if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
 720       if test "x$OBJCOPY" = x; then
 721         # enabling of enable-debug-symbols and can't find objcopy
 722         # this is an error
 723         AC_MSG_ERROR([Unable to find objcopy, cannot enable native debug symbols])
 724       fi
 725     fi
 726 
 727     ENABLE_DEBUG_SYMBOLS=true
 728     STRIP_POLICY=min_strip
 729     ZIP_DEBUGINFO_FILES=true
 730   elif test "x$NATIVE_DEBUG_SYMBOLS" = xnone; then
 731     ENABLE_DEBUG_SYMBOLS=false
 732     STRIP_POLICY=min_strip
 733     ZIP_DEBUGINFO_FILES=false
 734   elif test "x$NATIVE_DEBUG_SYMBOLS" = xinternal; then
 735     ENABLE_DEBUG_SYMBOLS=true
 736     STRIP_POLICY=no_strip
 737     ZIP_DEBUGINFO_FILES=false
 738     POST_STRIP_CMD=
 739     DEBUG_BINARIES=true
 740   elif test "x$NATIVE_DEBUG_SYMBOLS" = xexternal; then
 741 
 742     if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
 743       if test "x$OBJCOPY" = x; then
 744         # enabling of enable-debug-symbols and can't find objcopy
 745         # this is an error
 746         AC_MSG_ERROR([Unable to find objcopy, cannot enable native debug symbols])
 747       fi
 748     fi
 749 
 750     ENABLE_DEBUG_SYMBOLS=true
 751     STRIP_POLICY=min_strip
 752     ZIP_DEBUGINFO_FILES=false
 753   elif test "x$NATIVE_DEBUG_SYMBOLS" != x; then
 754     AC_MSG_ERROR([Allowed native debug symbols are: none, internal, external, zipped])
 755   else
 756     AC_MSG_NOTICE([--with-native-debug-symbols not specified. Using values from --disable-debug-symbols and --disable-zip-debug-info])
 757   fi
 758 
 759   AC_SUBST(ENABLE_DEBUG_SYMBOLS)
 760   AC_SUBST(STRIP_POLICY)
 761   AC_SUBST(POST_STRIP_CMD)
 762   AC_SUBST(DEBUG_BINARIES)
 763   AC_SUBST(ZIP_DEBUGINFO_FILES)
 764 ])
 765 
 766 # Support for customization of the build process. Some build files
 767 # will include counterparts from this location, if they exist. This allows
 768 # for a degree of customization of the build targets and the rules/recipes
 769 # to create them
 770 AC_ARG_WITH([custom-make-dir], [AS_HELP_STRING([--with-custom-make-dir],
 771 [use this directory for custom build/make files])], [CUSTOM_MAKE_DIR=$with_custom_make_dir])
 772 AC_SUBST(CUSTOM_MAKE_DIR)