1 #
   2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],
  27 [
  28   ###############################################################################
  29   #
  30   # Check which variant of the JDK that we want to build.
  31   # Currently we have:
  32   #    normal:   standard edition
  33   # but the custom make system may add other variants
  34   #
  35   # Effectively the JDK variant gives a name to a specific set of
  36   # modules to compile into the JDK. In the future, these modules
  37   # might even be Jigsaw modules.
  38   #
  39   AC_MSG_CHECKING([which variant of the JDK to build])
  40   AC_ARG_WITH([jdk-variant], [AS_HELP_STRING([--with-jdk-variant],
  41       [JDK variant to build (normal) @<:@normal@:>@])])
  42 
  43   if test "x$with_jdk_variant" = xnormal || test "x$with_jdk_variant" = x; then
  44     JDK_VARIANT="normal"
  45   else
  46     AC_MSG_ERROR([The available JDK variants are: normal])
  47   fi
  48 
  49   AC_SUBST(JDK_VARIANT)
  50 
  51   AC_MSG_RESULT([$JDK_VARIANT])
  52 ])
  53 
  54 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_INTERPRETER],
  55 [
  56 ###############################################################################
  57 #
  58 # Check which interpreter of the JVM we want to build.
  59 # Currently we have:
  60 #    template: Template interpreter (the default)
  61 #    cpp     : C++ interpreter
  62 AC_MSG_CHECKING([which interpreter of the JVM to build])
  63 AC_ARG_WITH([jvm-interpreter], [AS_HELP_STRING([--with-jvm-interpreter],
  64         [JVM interpreter to build (template, cpp) @<:@template@:>@])])
  65 
  66 if test "x$with_jvm_interpreter" = x; then
  67      with_jvm_interpreter="template"
  68 fi
  69 
  70 JVM_INTERPRETER="$with_jvm_interpreter"
  71 
  72 if test "x$JVM_INTERPRETER" != xtemplate && test "x$JVM_INTERPRETER" != xcpp; then
  73    AC_MSG_ERROR([The available JVM interpreters are: template, cpp])
  74 fi
  75 
  76 AC_SUBST(JVM_INTERPRETER)
  77 
  78 AC_MSG_RESULT([$with_jvm_interpreter])
  79 ])
  80 
  81 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_VARIANTS],
  82 [
  83 
  84   ###############################################################################
  85   #
  86   # Check which variants of the JVM that we want to build.
  87   # Currently we have:
  88   #    server: normal interpreter and a tiered C1/C2 compiler
  89   #    client: normal interpreter and C1 (no C2 compiler) (only 32-bit platforms)
  90   #    minimal1: reduced form of client with optional VM services and features stripped out
  91   #    kernel: kernel footprint JVM that passes the TCK without major performance problems,
  92   #             ie normal interpreter and C1, only the serial GC, kernel jvmti etc
  93   #    zero: no machine code interpreter, no compiler
  94   #    zeroshark: zero interpreter and shark/llvm compiler backend
  95 #    core: interpreter only, no compiler (only works on some platforms)
  96   AC_MSG_CHECKING([which variants of the JVM to build])
  97   AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
  98         [JVM variants (separated by commas) to build (server, client, minimal1, kernel, zero, zeroshark, core) @<:@server@:>@])])
  99 
 100   if test "x$with_jvm_variants" = x; then
 101     with_jvm_variants="server"
 102   fi
 103 
 104   JVM_VARIANTS=",$with_jvm_variants,"
 105   TEST_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,//' -e 's/client,//'  -e 's/minimal1,//' -e 's/kernel,//' -e 's/zero,//' -e 's/zeroshark,//' -e 's/core,//'`
 106 
 107   if test "x$TEST_VARIANTS" != "x,"; then
 108      AC_MSG_ERROR([The available JVM variants are: server, client, minimal1, kernel, zero, zeroshark, core])
 109   fi
 110   AC_MSG_RESULT([$with_jvm_variants])
 111 
 112   JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`
 113   JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`
 114   JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS" | $SED -e '/,minimal1,/!s/.*/false/g' -e '/,minimal1,/s/.*/true/g'`
 115   JVM_VARIANT_KERNEL=`$ECHO "$JVM_VARIANTS" | $SED -e '/,kernel,/!s/.*/false/g' -e '/,kernel,/s/.*/true/g'`
 116   JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`
 117   JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`
 118   JVM_VARIANT_CORE=`$ECHO "$JVM_VARIANTS" | $SED -e '/,core,/!s/.*/false/g' -e '/,core,/s/.*/true/g'`
 119 
 120   if test "x$JVM_VARIANT_CLIENT" = xtrue; then
 121     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 122       AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])
 123     fi
 124   fi
 125   if test "x$JVM_VARIANT_KERNEL" = xtrue; then
 126     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 127       AC_MSG_ERROR([You cannot build a kernel JVM for a 64-bit machine.])
 128     fi
 129   fi
 130   if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
 131     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 132       AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])
 133     fi
 134   fi
 135 
 136   # Replace the commas with AND for use in the build directory name.
 137   ANDED_JVM_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/^,//' -e 's/,$//' -e 's/,/AND/g'`
 138   COUNT_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,/1/' -e 's/client,/1/' -e 's/minimal1,/1/' -e 's/kernel,/1/' -e 's/zero,/1/' -e 's/zeroshark,/1/' -e 's/core,/1/'`
 139   if test "x$COUNT_VARIANTS" != "x,1"; then
 140     BUILDING_MULTIPLE_JVM_VARIANTS=yes
 141   else
 142     BUILDING_MULTIPLE_JVM_VARIANTS=no
 143   fi
 144 
 145   AC_SUBST(JVM_VARIANTS)
 146   AC_SUBST(JVM_VARIANT_SERVER)
 147   AC_SUBST(JVM_VARIANT_CLIENT)
 148   AC_SUBST(JVM_VARIANT_MINIMAL1)
 149   AC_SUBST(JVM_VARIANT_KERNEL)
 150   AC_SUBST(JVM_VARIANT_ZERO)
 151   AC_SUBST(JVM_VARIANT_ZEROSHARK)
 152   AC_SUBST(JVM_VARIANT_CORE)
 153 
 154   INCLUDE_SA=true
 155   if test "x$JVM_VARIANT_ZERO" = xtrue ; then
 156     INCLUDE_SA=false
 157   fi
 158   if test "x$JVM_VARIANT_ZEROSHARK" = xtrue ; then
 159     INCLUDE_SA=false
 160   fi
 161   if test "x$VAR_CPU" = xppc64 -o "x$VAR_CPU" = xppc64le ; then
 162     INCLUDE_SA=false
 163   fi
 164   AC_SUBST(INCLUDE_SA)
 165 
 166   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 167     MACOSX_UNIVERSAL="false"
 168   fi
 169 
 170   AC_SUBST(MACOSX_UNIVERSAL)
 171 ])
 172 
 173 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],
 174 [
 175   ###############################################################################
 176   #
 177   # Set the debug level
 178   #    release: no debug information, all optimizations, no asserts.
 179   #    fastdebug: debug information (-g), all optimizations, all asserts
 180   #    slowdebug: debug information (-g), no optimizations, all asserts
 181   #
 182   DEBUG_LEVEL="release"
 183   AC_MSG_CHECKING([which debug level to use])
 184   AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],
 185       [set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],
 186       [
 187         ENABLE_DEBUG="${enableval}"
 188         DEBUG_LEVEL="fastdebug"
 189       ], [ENABLE_DEBUG="no"])
 190 
 191   AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],
 192       [set the debug level (release, fastdebug, slowdebug) @<:@release@:>@])],
 193       [
 194         DEBUG_LEVEL="${withval}"
 195         if test "x$ENABLE_DEBUG" = xyes; then
 196           AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])
 197         fi
 198       ])
 199   AC_MSG_RESULT([$DEBUG_LEVEL])
 200 
 201   if test "x$DEBUG_LEVEL" != xrelease && \
 202       test "x$DEBUG_LEVEL" != xfastdebug && \
 203       test "x$DEBUG_LEVEL" != xslowdebug; then
 204     AC_MSG_ERROR([Allowed debug levels are: release, fastdebug and slowdebug])
 205   fi
 206 
 207 
 208   ###############################################################################
 209   #
 210   # Setup legacy vars/targets and new vars to deal with different debug levels.
 211   #
 212 
 213   case $DEBUG_LEVEL in
 214     release )
 215       VARIANT="OPT"
 216       FASTDEBUG="false"
 217       DEBUG_CLASSFILES="false"
 218       BUILD_VARIANT_RELEASE=""
 219       HOTSPOT_DEBUG_LEVEL="product"
 220       HOTSPOT_EXPORT="product"
 221       ;;
 222     fastdebug )
 223       VARIANT="DBG"
 224       FASTDEBUG="true"
 225       DEBUG_CLASSFILES="true"
 226       BUILD_VARIANT_RELEASE="-fastdebug"
 227       HOTSPOT_DEBUG_LEVEL="fastdebug"
 228       HOTSPOT_EXPORT="fastdebug"
 229       ;;
 230     slowdebug )
 231       VARIANT="DBG"
 232       FASTDEBUG="false"
 233       DEBUG_CLASSFILES="true"
 234       BUILD_VARIANT_RELEASE="-debug"
 235       HOTSPOT_DEBUG_LEVEL="jvmg"
 236       HOTSPOT_EXPORT="debug"
 237       ;;
 238   esac
 239 
 240   #####
 241   # Generate the legacy makefile targets for hotspot.
 242   # The hotspot api for selecting the build artifacts, really, needs to be improved.
 243   # JDK-7195896 will fix this on the hotspot side by using the JVM_VARIANT_* variables to
 244   # determine what needs to be built. All we will need to set here is all_product, all_fastdebug etc
 245   # But until then ...
 246   HOTSPOT_TARGET=""
 247 
 248   if test "x$JVM_VARIANT_SERVER" = xtrue; then
 249     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "
 250   fi
 251 
 252   if test "x$JVM_VARIANT_CLIENT" = xtrue; then
 253     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "
 254   fi
 255 
 256   if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
 257     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "
 258   fi
 259 
 260   if test "x$JVM_VARIANT_KERNEL" = xtrue; then
 261     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}kernel "
 262   fi
 263 
 264   if test "x$JVM_VARIANT_ZERO" = xtrue; then
 265     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "
 266   fi
 267 
 268   if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
 269     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "
 270   fi
 271 
 272   if test "x$JVM_VARIANT_CORE" = xtrue; then
 273     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}core "
 274   fi
 275 
 276   HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_EXPORT"
 277 
 278   # On Macosx universal binaries are produced, but they only contain
 279   # 64 bit intel. This invalidates control of which jvms are built
 280   # from configure, but only server is valid anyway. Fix this
 281   # when hotspot makefiles are rewritten.
 282   if test "x$MACOSX_UNIVERSAL" = xtrue; then
 283     HOTSPOT_TARGET=universal_${HOTSPOT_EXPORT}
 284   fi
 285 
 286   #####
 287 
 288   AC_SUBST(DEBUG_LEVEL)
 289   AC_SUBST(VARIANT)
 290   AC_SUBST(FASTDEBUG)
 291   AC_SUBST(DEBUG_CLASSFILES)
 292   AC_SUBST(BUILD_VARIANT_RELEASE)
 293 ])
 294 
 295 
 296 ###############################################################################
 297 #
 298 # Should we build only OpenJDK even if closed sources are present?
 299 #
 300 AC_DEFUN_ONCE([JDKOPT_SETUP_OPEN_OR_CUSTOM],
 301 [
 302   AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],
 303       [suppress building custom source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])
 304 
 305   AC_MSG_CHECKING([for presence of closed sources])
 306   if test -d "$SRC_ROOT/jdk/src/closed"; then
 307     CLOSED_SOURCE_PRESENT=yes
 308   else
 309     CLOSED_SOURCE_PRESENT=no
 310   fi
 311   AC_MSG_RESULT([$CLOSED_SOURCE_PRESENT])
 312 
 313   AC_MSG_CHECKING([if closed source is suppressed (openjdk-only)])
 314   SUPPRESS_CLOSED_SOURCE="$enable_openjdk_only"
 315   AC_MSG_RESULT([$SUPPRESS_CLOSED_SOURCE])
 316 
 317   if test "x$CLOSED_SOURCE_PRESENT" = xno; then
 318     OPENJDK=true
 319     if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
 320       AC_MSG_WARN([No closed source present, --enable-openjdk-only makes no sense])
 321     fi
 322   else
 323     if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
 324       OPENJDK=true
 325     else
 326       OPENJDK=false
 327     fi
 328   fi
 329 
 330   if test "x$OPENJDK" = "xtrue"; then
 331     SET_OPENJDK="OPENJDK=true"
 332   fi
 333 
 334   AC_SUBST(SET_OPENJDK)
 335 ])
 336 
 337 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],
 338 [
 339 
 340   ###############################################################################
 341   #
 342   # Should we build a JDK/JVM with headful support (ie a graphical ui)?
 343   # We always build headless support.
 344   #
 345   AC_MSG_CHECKING([headful support])
 346   AC_ARG_ENABLE([headful], [AS_HELP_STRING([--disable-headful],
 347       [disable building headful support (graphical UI support) @<:@enabled@:>@])],
 348       [SUPPORT_HEADFUL=${enable_headful}], [SUPPORT_HEADFUL=yes])
 349 
 350   SUPPORT_HEADLESS=yes
 351   BUILD_HEADLESS="BUILD_HEADLESS:=true"
 352 
 353   if test "x$SUPPORT_HEADFUL" = xyes; then
 354     # We are building both headful and headless.
 355     headful_msg="include support for both headful and headless"
 356   fi
 357 
 358   if test "x$SUPPORT_HEADFUL" = xno; then
 359     # Thus we are building headless only.
 360     BUILD_HEADLESS="BUILD_HEADLESS:=true"
 361     headful_msg="headless only"
 362   fi
 363 
 364   AC_MSG_RESULT([$headful_msg])
 365 
 366   AC_SUBST(SUPPORT_HEADLESS)
 367   AC_SUBST(SUPPORT_HEADFUL)
 368   AC_SUBST(BUILD_HEADLESS)
 369 
 370   # Control wether Hotspot runs Queens test after build.
 371   AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],
 372       [run the Queens test after Hotspot build @<:@disabled@:>@])],,
 373       [enable_hotspot_test_in_build=no])
 374   if test "x$enable_hotspot_test_in_build" = "xyes"; then
 375     TEST_IN_BUILD=true
 376   else
 377     TEST_IN_BUILD=false
 378   fi
 379   AC_SUBST(TEST_IN_BUILD)
 380 
 381   ###############################################################################
 382   #
 383   # Choose cacerts source file
 384   #
 385   AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],
 386       [specify alternative cacerts file])])
 387   if test "x$with_cacerts_file" != x; then
 388     CACERTS_FILE=$with_cacerts_file
 389   fi
 390   AC_SUBST(CACERTS_FILE)
 391 
 392   ###############################################################################
 393   #
 394   # Enable or disable unlimited crypto
 395   #
 396   AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--enable-unlimited-crypto],
 397       [Enable unlimited crypto policy @<:@disabled@:>@])],,
 398       [enable_unlimited_crypto=no])
 399   if test "x$enable_unlimited_crypto" = "xyes"; then
 400     UNLIMITED_CRYPTO=true
 401   else
 402     UNLIMITED_CRYPTO=false
 403   fi
 404   AC_SUBST(UNLIMITED_CRYPTO)
 405 
 406   ###############################################################################
 407   #
 408   # Enable or disable the elliptic curve crypto implementation
 409   #
 410   AC_DEFUN_ONCE([JDKOPT_DETECT_INTREE_EC],
 411   [
 412     AC_MSG_CHECKING([if elliptic curve crypto implementation is present])
 413 
 414     if test -d "${SRC_ROOT}/jdk/src/share/native/sun/security/ec/impl"; then
 415       ENABLE_INTREE_EC=yes
 416       AC_MSG_RESULT([yes])
 417     else
 418       ENABLE_INTREE_EC=no
 419       AC_MSG_RESULT([no])
 420     fi
 421 
 422     AC_SUBST(ENABLE_INTREE_EC)
 423   ])
 424 
 425   ###############################################################################
 426   #
 427   # Compress jars
 428   #
 429   COMPRESS_JARS=false
 430 
 431   AC_SUBST(COMPRESS_JARS)
 432 
 433   ###############################################################################
 434   #
 435   # Enable or disable JFR
 436   #
 437   AC_MSG_CHECKING([whether to build jfr])
 438   AC_ARG_ENABLE(jfr, [AS_HELP_STRING([--enable-jfr],
 439       [Enable Java Flight Recorder support @<:@disabled@:>@])],,
 440       [enable_jfr=auto])
 441   if test "x$enable_jfr" = "xno" -o "x$enable_jfr" = "xauto"; then
 442     ENABLE_JFR=false
 443   elif test "x$enable_jfr" = "xyes" ; then
 444     if test "x$JVM_VARIANT_MINIMAL1" = "xtrue" -o "x$JVM_VARIANT_ZERO" = "xtrue"; then
 445       AC_MSG_ERROR([cannot enable JFR on minimal1 VM or zero build])
 446     elif test "x$OPENJDK_TARGET_OS" = xaix; then
 447       AC_MSG_ERROR([AIX does not support JFR])
 448     else
 449       ENABLE_JFR=true
 450     fi
 451   else
 452     AC_MSG_ERROR([--enable-jfr must either be set to yes or no])
 453   fi
 454   AC_MSG_RESULT([$ENABLE_JFR])
 455   AC_SUBST(ENABLE_JFR)
 456 ])
 457 
 458 ###############################################################################
 459 #
 460 # Setup version numbers
 461 #
 462 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VERSION_NUMBERS],
 463 [
 464   # Source the version numbers
 465   . $AUTOCONF_DIR/version-numbers
 466 
 467   # Get the settings from parameters
 468   AC_ARG_WITH(milestone, [AS_HELP_STRING([--with-milestone],
 469       [Set milestone value for build @<:@internal@:>@])])
 470   if test "x$with_milestone" = xyes; then
 471     AC_MSG_ERROR([Milestone must have a value])
 472   elif test "x$with_milestone" != x; then
 473     MILESTONE="$with_milestone"
 474   fi
 475   if test "x$MILESTONE" = x; then
 476     MILESTONE=internal
 477   fi
 478 
 479   AC_ARG_WITH(update-version, [AS_HELP_STRING([--with-update-version],
 480       [Set update version value for build @<:@b00@:>@])])
 481   if test "x$with_update_version" = xyes; then
 482     AC_MSG_ERROR([Update version must have a value])
 483   elif test "x$with_update_version" != x; then
 484     JDK_UPDATE_VERSION="$with_update_version"
 485     # On macosx 10.7, it's not possible to set --with-update-version=0X due
 486     # to a bug in expr (which reduces it to just X). To work around this, we
 487     # always add a 0 to one digit update versions.
 488     if test "${#JDK_UPDATE_VERSION}" = "1"; then
 489       JDK_UPDATE_VERSION="0${JDK_UPDATE_VERSION}"
 490     fi
 491   fi
 492 
 493   AC_ARG_WITH(user-release-suffix, [AS_HELP_STRING([--with-user-release-suffix],
 494       [Add a custom string to the version string if build number isn't set.@<:@username_builddateb00@:>@])])
 495   if test "x$with_user_release_suffix" = xyes; then
 496     AC_MSG_ERROR([Release suffix must have a value])
 497   elif test "x$with_user_release_suffix" != x; then
 498     USER_RELEASE_SUFFIX="$with_user_release_suffix"
 499   fi
 500 
 501   AC_ARG_WITH(build-number, [AS_HELP_STRING([--with-build-number],
 502       [Set build number value for build @<:@b00@:>@])])
 503   if test "x$with_build_number" = xyes; then
 504     AC_MSG_ERROR([Build number must have a value])
 505   elif test "x$with_build_number" != x; then
 506     JDK_BUILD_NUMBER="$with_build_number"
 507   fi
 508   # Define default USER_RELEASE_SUFFIX if BUILD_NUMBER and USER_RELEASE_SUFFIX are not set
 509   if test "x$JDK_BUILD_NUMBER" = x; then
 510     JDK_BUILD_NUMBER=b00
 511     if test "x$USER_RELEASE_SUFFIX" = x; then
 512       BUILD_DATE=`date '+%Y_%m_%d_%H_%M'`
 513       # Avoid [:alnum:] since it depends on the locale.
 514       CLEAN_USERNAME=`echo "$USER" | $TR -d -c 'abcdefghijklmnopqrstuvqxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789'`
 515       USER_RELEASE_SUFFIX=`echo "${CLEAN_USERNAME}_${BUILD_DATE}" | $TR 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' 'abcdefghijklmnopqrstuvwxyz'`
 516     fi
 517   fi
 518 
 519   # Now set the JDK version, milestone, build number etc.
 520   AC_SUBST(USER_RELEASE_SUFFIX)
 521   AC_SUBST(JDK_MAJOR_VERSION)
 522   AC_SUBST(JDK_MINOR_VERSION)
 523   AC_SUBST(JDK_MICRO_VERSION)
 524   AC_SUBST(JDK_UPDATE_VERSION)
 525   AC_SUBST(JDK_BUILD_NUMBER)
 526   AC_SUBST(MILESTONE)
 527   AC_SUBST(LAUNCHER_NAME)
 528   AC_SUBST(PRODUCT_NAME)
 529   AC_SUBST(PRODUCT_SUFFIX)
 530   AC_SUBST(JDK_RC_PLATFORM_NAME)
 531   AC_SUBST(MACOSX_BUNDLE_NAME_BASE)
 532   AC_SUBST(MACOSX_BUNDLE_ID_BASE)
 533 
 534   # The vendor name, if any
 535   AC_ARG_WITH(vendor-name, [AS_HELP_STRING([--with-vendor-name],
 536       [Set vendor name. Among others, used to set the 'java.vendor'
 537        and 'java.vm.vendor' system properties. @<:@not specified@:>@])])
 538   if test "x$with_vendor_name" = xyes; then
 539     AC_MSG_ERROR([--with-vendor-name must have a value])
 540   elif [ ! [[ $with_vendor_name =~ ^[[:print:]]*$ ]] ]; then
 541     AC_MSG_ERROR([--with-vendor-name contains non-printing characters: $with_vendor_name])
 542   elif test "x$with_vendor_name" != x; then
 543     # Only set COMPANY_NAME if '--with-vendor-name' was used and is not empty.
 544     # Otherwise we will use the value from "version-numbers" included above.
 545     COMPANY_NAME="$with_vendor_name"
 546   fi
 547   AC_SUBST(COMPANY_NAME)
 548 
 549   # The vendor URL, if any
 550   AC_ARG_WITH(vendor-url, [AS_HELP_STRING([--with-vendor-url],
 551       [Set the 'java.vendor.url' system property @<:@not specified@:>@])])
 552   if test "x$with_vendor_url" = xyes; then
 553     AC_MSG_ERROR([--with-vendor-url must have a value])
 554   elif [ ! [[ $with_vendor_url =~ ^[[:print:]]*$ ]] ]; then
 555     AC_MSG_ERROR([--with-vendor-url contains non-printing characters: $with_vendor_url])
 556   else
 557     VENDOR_URL="$with_vendor_url"
 558   fi
 559   AC_SUBST(VENDOR_URL)
 560 
 561   # The vendor bug URL, if any
 562   AC_ARG_WITH(vendor-bug-url, [AS_HELP_STRING([--with-vendor-bug-url],
 563       [Set the 'java.vendor.url.bug' system property @<:@not specified@:>@])])
 564   if test "x$with_vendor_bug_url" = xyes; then
 565     AC_MSG_ERROR([--with-vendor-bug-url must have a value])
 566   elif [ ! [[ $with_vendor_bug_url =~ ^[[:print:]]*$ ]] ]; then
 567     AC_MSG_ERROR([--with-vendor-bug-url contains non-printing characters: $with_vendor_bug_url])
 568   else
 569     VENDOR_URL_BUG="$with_vendor_bug_url"
 570   fi
 571   AC_SUBST(VENDOR_URL_BUG)
 572 
 573   # The vendor VM bug URL, if any
 574   AC_ARG_WITH(vendor-vm-bug-url, [AS_HELP_STRING([--with-vendor-vm-bug-url],
 575       [Sets the bug URL which will be displayed when the VM crashes @<:@not specified@:>@])])
 576   if test "x$with_vendor_vm_bug_url" = xyes; then
 577     AC_MSG_ERROR([--with-vendor-vm-bug-url must have a value])
 578   elif [ ! [[ $with_vendor_vm_bug_url =~ ^[[:print:]]*$ ]] ]; then
 579     AC_MSG_ERROR([--with-vendor-vm-bug-url contains non-printing characters: $with_vendor_vm_bug_url])
 580   else
 581     VENDOR_URL_VM_BUG="$with_vendor_vm_bug_url"
 582   fi
 583   AC_SUBST(VENDOR_URL_VM_BUG)
 584 
 585   AC_ARG_WITH(copyright-year, [AS_HELP_STRING([--with-copyright-year],
 586       [Set copyright year value for build @<:@current year@:>@])])
 587   if test "x$with_copyright_year" = xyes; then
 588     AC_MSG_ERROR([Copyright year must have a value])
 589   elif test "x$with_copyright_year" != x; then
 590     COPYRIGHT_YEAR="$with_copyright_year"
 591   else
 592     COPYRIGHT_YEAR=`date +'%Y'`
 593   fi
 594   AC_SUBST(COPYRIGHT_YEAR)
 595 
 596   if test "x$JDK_UPDATE_VERSION" != x; then
 597     JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}_${JDK_UPDATE_VERSION}"
 598   else
 599     JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}"
 600   fi
 601   AC_SUBST(JDK_VERSION)
 602 
 603   # The cooked update version used to encode trailing letters in the update
 604   # version into a trailing number. That is no longer needed, but need to
 605   # keep the format in 8u for compatibility.
 606   COOKED_JDK_UPDATE_VERSION="${JDK_UPDATE_VERSION}0"
 607   AC_SUBST(COOKED_JDK_UPDATE_VERSION)
 608 
 609   COOKED_BUILD_NUMBER=`$ECHO $JDK_BUILD_NUMBER | $SED -e 's/^b//' -e 's/^0//'`
 610   AC_SUBST(COOKED_BUILD_NUMBER)
 611 ])
 612 
 613 AC_DEFUN_ONCE([JDKOPT_SETUP_BUILD_TWEAKS],
 614 [
 615   HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"
 616   AC_SUBST(HOTSPOT_MAKE_ARGS)
 617 
 618   # The name of the Service Agent jar.
 619   SALIB_NAME="${LIBRARY_PREFIX}saproc${SHARED_LIBRARY_SUFFIX}"
 620   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 621     SALIB_NAME="${LIBRARY_PREFIX}sawindbg${SHARED_LIBRARY_SUFFIX}"
 622   fi
 623   AC_SUBST(SALIB_NAME)
 624 ])
 625 
 626 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],
 627 [
 628   # Backwards compatibility. --with-native-debug-symbols is preferred post JDK-8207234,
 629   # but if somebody does not specify it via configure, we still want to preserve old
 630   # behaviour of --disable-debug-symbols
 631   #
 632   # ENABLE_DEBUG_SYMBOLS
 633   # This must be done after the toolchain is setup, since we're looking at objcopy.
 634   #
 635   AC_ARG_ENABLE([debug-symbols],
 636       [AS_HELP_STRING([--disable-debug-symbols],[disable generation of debug symbols @<:@enabled@:>@])])
 637 
 638   AC_MSG_CHECKING([if we should generate debug symbols])
 639 
 640   if test "x$enable_debug_symbols" = "xyes" && test "x$OBJCOPY" = x; then
 641     # explicit enabling of enable-debug-symbols and can't find objcopy
 642     #   this is an error
 643     AC_MSG_ERROR([Unable to find objcopy, cannot enable debug-symbols])
 644   fi
 645 
 646   if test "x$enable_debug_symbols" = "xyes"; then
 647     ENABLE_DEBUG_SYMBOLS=true
 648   elif test "x$enable_debug_symbols" = "xno"; then
 649     ENABLE_DEBUG_SYMBOLS=false
 650   else
 651     # Default is on if objcopy is found
 652     if test "x$OBJCOPY" != x; then
 653       ENABLE_DEBUG_SYMBOLS=true
 654     # MacOS X and Windows don't use objcopy but default is on for those OSes
 655     elif test "x$OPENJDK_TARGET_OS" = xmacosx || test "x$OPENJDK_TARGET_OS" = xwindows; then
 656       ENABLE_DEBUG_SYMBOLS=true
 657     else
 658       ENABLE_DEBUG_SYMBOLS=false
 659     fi
 660   fi
 661 
 662   AC_MSG_RESULT([$ENABLE_DEBUG_SYMBOLS])
 663 
 664   # Backwards compatibility. --with-native-debug-symbols is preferred post JDK-8207234,
 665   # but if somebody does not specify it via configure, we still want to preserve old
 666   # behaviour of --disable-zip-debug-info.
 667   #
 668   # ZIP_DEBUGINFO_FILES
 669   #
 670   AC_MSG_CHECKING([if we should zip debug-info files])
 671   AC_ARG_ENABLE([zip-debug-info],
 672       [AS_HELP_STRING([--disable-zip-debug-info],[disable zipping of debug-info files @<:@enabled@:>@])],
 673       [enable_zip_debug_info="${enableval}"], [enable_zip_debug_info="yes"])
 674   AC_MSG_RESULT([${enable_zip_debug_info}])
 675 
 676   if test "x${enable_zip_debug_info}" = "xno"; then
 677     ZIP_DEBUGINFO_FILES=false
 678   elif test "x${enable_zip_debug_info}" = "xyes"; then
 679     ZIP_DEBUGINFO_FILES=true
 680   fi
 681 
 682   #
 683   # NATIVE_DEBUG_SYMBOLS
 684   # This must be done after the toolchain is setup, since we're looking at objcopy.
 685   # In addition, this must be done after ENABLE_DEBUG_SYMBOLS and ZIP_DEBUGINFO_FILES
 686   # checking in order to preserve backwards compatibility post JDK-8207234.
 687   #
 688   AC_MSG_CHECKING([what type of native debug symbols to use (this will override previous settings)])
 689   AC_ARG_WITH([native-debug-symbols],
 690       [AS_HELP_STRING([--with-native-debug-symbols],
 691       [set the native debug symbol configuration (none, internal, external, zipped) @<:@varying@:>@])],
 692       [
 693         if test "x$OPENJDK_TARGET_OS" = xaix; then
 694           if test "x$with_native_debug_symbols" = xexternal || test "x$with_native_debug_symbols" = xzipped; then
 695             AC_MSG_ERROR([AIX only supports the parameters 'none' and 'internal' for --with-native-debug-symbols])
 696           fi
 697         fi
 698       ],
 699       [
 700         # Default to unset for backwards compatibility
 701         with_native_debug_symbols=""
 702       ])
 703   NATIVE_DEBUG_SYMBOLS=$with_native_debug_symbols
 704   if test "x$NATIVE_DEBUG_SYMBOLS" = x; then
 705     AC_MSG_RESULT([not specified])
 706   else
 707     AC_MSG_RESULT([$NATIVE_DEBUG_SYMBOLS])
 708   fi
 709   # Default is empty
 710   DEBUG_BINARIES=
 711   # Default is min_strip. Possible values are min_strip, all_strip, no_strip
 712   STRIP_POLICY=min_strip
 713 
 714   if test "x$NATIVE_DEBUG_SYMBOLS" = xzipped; then
 715 
 716     if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
 717       if test "x$OBJCOPY" = x; then
 718         # enabling of enable-debug-symbols and can't find objcopy
 719         # this is an error
 720         AC_MSG_ERROR([Unable to find objcopy, cannot enable native debug symbols])
 721       fi
 722     fi
 723 
 724     ENABLE_DEBUG_SYMBOLS=true
 725     STRIP_POLICY=min_strip
 726     ZIP_DEBUGINFO_FILES=true
 727   elif test "x$NATIVE_DEBUG_SYMBOLS" = xnone; then
 728     ENABLE_DEBUG_SYMBOLS=false
 729     STRIP_POLICY=min_strip
 730     ZIP_DEBUGINFO_FILES=false
 731   elif test "x$NATIVE_DEBUG_SYMBOLS" = xinternal; then
 732     ENABLE_DEBUG_SYMBOLS=true
 733     STRIP_POLICY=no_strip
 734     ZIP_DEBUGINFO_FILES=false
 735     POST_STRIP_CMD=
 736     DEBUG_BINARIES=true
 737   elif test "x$NATIVE_DEBUG_SYMBOLS" = xexternal; then
 738 
 739     if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
 740       if test "x$OBJCOPY" = x; then
 741         # enabling of enable-debug-symbols and can't find objcopy
 742         # this is an error
 743         AC_MSG_ERROR([Unable to find objcopy, cannot enable native debug symbols])
 744       fi
 745     fi
 746 
 747     ENABLE_DEBUG_SYMBOLS=true
 748     STRIP_POLICY=min_strip
 749     ZIP_DEBUGINFO_FILES=false
 750   elif test "x$NATIVE_DEBUG_SYMBOLS" != x; then
 751     AC_MSG_ERROR([Allowed native debug symbols are: none, internal, external, zipped])
 752   else
 753     AC_MSG_NOTICE([--with-native-debug-symbols not specified. Using values from --disable-debug-symbols and --disable-zip-debug-info])
 754   fi
 755 
 756   AC_SUBST(ENABLE_DEBUG_SYMBOLS)
 757   AC_SUBST(STRIP_POLICY)
 758   AC_SUBST(POST_STRIP_CMD)
 759   AC_SUBST(DEBUG_BINARIES)
 760   AC_SUBST(ZIP_DEBUGINFO_FILES)
 761 ])
 762 
 763 # Support for customization of the build process. Some build files
 764 # will include counterparts from this location, if they exist. This allows
 765 # for a degree of customization of the build targets and the rules/recipes
 766 # to create them
 767 AC_ARG_WITH([custom-make-dir], [AS_HELP_STRING([--with-custom-make-dir],
 768 [use this directory for custom build/make files])], [CUSTOM_MAKE_DIR=$with_custom_make_dir])
 769 AC_SUBST(CUSTOM_MAKE_DIR)